Reference Application title in VBA 2

[JoeMicro]

Hi,

is there any way to get the application title from another file (for instence my database file) in a msgbox or txtbox?

thanks,
joe

 

[FancyPrairie]

This function will return the title shown on the window title bar:

Option Compare Database
Option Explicit

Public Declare Function MMC_apiGetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lbString As String, ByVal cch As Long) As Long

Public Function MMC_GetWindowText(Optional varWHandle As Variant) As String

    Dim lngWHandle As Long
    Dim lngNoChars As Long
    Dim strText As String
    
    strText = Space(255)
    
    If (IsMissing(varWHandle)) Then
        lngWHandle = hWndAccessApp
    Else
        lngWHandle = varWHandle
    End If
    
    lngNoChars = MMC_apiGetWindowText(lngWHandle, strText, Len(strText) - 1)
    MMC_GetWindowText = Left(strText, lngNoChars)

End Function

 

[JoeMicro]

Thanks FancyPrairie,

this works great with my running file,

now how do i get the same thing from another file.

like the application title of the file to which the tables in the current file are linked?

Joe

 

[Remou]

The title is a property of the database.

Public Sub ListAppTitle()
    '6 = linked tables
    strSQL = "SELECT Database, Name FROM MsysObjects WHERE Type=6"
    Set rs = CurrentDb.OpenRecordset(strSQL)
    
    Do While Not rs.EOF
    Set db = OpenDatabase(rs!Database)
    On Error Resume Next
    prpTitle = db.properties("AppTitle")
    If Err.Number <> 0 Then
        prpTitle = "N/A"
        Err.Clear
    End If
    
    Debug.Print rs!Name; "  "; prpTitle
    
    rs.MoveNext
    Loop

End Sub

 

[JoeMicro]

thanks guys

thet did the job

thanks again

Joe