Put VB-application on hold

[KVink]

I'm building a VB-application in which an external program is used (Paint Shop Pro in my case). It's called using the shell-command. I want to put the VB-application on hold as long as the user is busy in PSP. Is ther a way to do this (Do/While loop??)?

 

[Collin]

Suspending VB is the easy part, determining when the shelled application has ended is the hard part. There is a good FAQ on that subject (4.c), or do a seach for the WaitforSingleObject API

Collin

 

[swilliams]

I think this will do the trick. Paste the code below into a module and then instead of doing:

Shell ("...&quot

do

ExecCmd ("...&quot

Module Code:
' ------------------------------------
' Wait for Shelled Process to complete
' ------------------------------------
Option Explicit

Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type

Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessID As Long
dwThreadID As Long
End Type

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
hHandle As Long, ByVal dwMilliseconds As Long) As Long

Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
lpApplicationName As Long, ByVal lpCommandLine As String, ByVal _
lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, _
lpStartupInfo As STARTUPINFO, lpProcessInformation As _
PROCESS_INFORMATION) As Long

Private Declare Function CloseHandle Lib "kernel32" _
(ByVal hObject As Long) As Long

Private Declare Function GetExitCodeProcess Lib "kernel32" _
(ByVal hProcess As Long, lpExitCode As Long) As Long

Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const INFINITE = -1&
Public Function ExecCmd(ByVal sCmdline As String) As Variant
' --------------------------------------------
' Execute command line and wait for completion
' --------------------------------------------

Dim proc As PROCESS_INFORMATION
Dim start As STARTUPINFO
Dim lReturn As Long

' Initialize the STARTUPINFO structure
start.cb = Len(start)

' Start the shelled application
lReturn = CreateProcessA(0&, sCmdline, 0&, 0&, 1&, NORMAL_PRIORITY_CLASS, 0&, 0&, start, proc)

' Wait for the shelled application to finish
lReturn = WaitForSingleObject(proc.hProcess, INFINITE)
GetExitCodeProcess proc.hProcess, lReturn
CloseHandle proc.hProcess
ExecCmd = lReturn

End Function

Simon

 

[linus42]

Thanks. Helped me a lot.