Problem w/Skillset out of Svc treatment whan all agents Nready 1

[lilabell]

Hello Good folks of the forum. My script giving the out of service treatment when all agents are not ready. I want the out of svc. treatment to only execute if there are no agents logged in. Otherwise I want it to proceed to the day treatment condition provided none of the other conditions have been meet (Meeting, Holiday etc. - see below) Please advise how I should modify this script to achieve this? I was thinking of something along the following lines:

If LOGGED AGENT COUNT Console < 1
Then execute Out_Of_Svs_Treatment

I have pasted the script in its current state below.
Any help you can provide would be greatly appreciated.

Thank you,

Lilabell



/*Console Script 9/18/06 Symposium 5*/

If DATE = Hol_GV
Then Execute Holiday_Treatment
End if
/*Holiday Greeting*/

If DATE = Pre_Hol_GV and TIME OF DAY = 15:00..23:59
Then Execute Holiday_Treatment
End if
/*Holiday Greeting*/

If DATE = Pre_Hol_GV and DAY OF WEEK= monday..friday
and TIME OF DAY = 08:30..15:00
Then Execute Pre_Holiday_Treatment
End if
/*Pre Holiday Greeting*/

If Date = Noon_Closure and time of day = 12:00..23:59
Then Execute Holiday_Treatment
End if
/*Holiday Greeting*/

If DAY OF WEEK = monday..friday and TIME OF DAY = 17:30..08:30
Then execute Night_Treatment
End if
/*Regular Night Greeting*/

If DAY OF WEEK = saturday..sunday
Then execute Night_Treatment
End if
/*Regular Night Greeting*/

If LOGGED AGENT COUNT Snow_Day > 0
Then execute Snow_Treatment
End if
/*Snow Closure Greeting*/

If LOGGED AGENT COUNT Console_Meeting > 0
Then execute Meeting_Treatment
End if
/*Meeting Closure Greeting*/

Section Day_Treatment

If OUT OF SERVICE Console
Then execute Out_Of_Svs_Treatment
Else Queue to skillset Console
Wait 2

Give ivr INTERRUPTIBLE 2998 with treatment 1016
/*Initial Day Greeting*/

End if

Give Music 10

Wait 15


Section Loop_Treatment
Wait 20

Give ivr INTERRUPTIBLE 2998 with treatment 1017
/*Wait Greeting*/

If AGE OF CALL > 90
then give ivr 2998 with treatment 1018

/*Give Transfer to vm greeting and Transfer to VM*/

Else Execute Loop_Treatment
End if
Quit

Section Night_Treatment
Route Call 4000
Quit

Section Holiday_Treatment
Route Call 4000
quit

Section Pre_Holiday_Treatment
Give ivr 2998 with treatment 1030
Execute Day_Treatment
Quit

Section Snow_Treatment
Give ivr 2998 with treatment 1020
Quit

Section Meeting_Treatment
/*Give ivr 2998 with treatment y*/
Quit

Section Out_Of_Svs_Treatment
Route call 4000
Quit

 

[nortelinsd]

You have this "If LOGGED AGENT COUNT Console < 1
Then execute Out_Of_Svs_Treatment"

You could use this "If LOGGED AGNET COUNT = 0
Then execute Out_Of_Svs_Treatment"

The prompt < 1 would be false if there were more than 1 agents logged in to that queue.

So if there are not agents logged in then the customer will get the out of service message.

If a tree hugger falls in the woods...who cares?

 

[lilabell]

Perfect! Thank you so much!

Lilabell

 

[DancingDave]

Or...

IF NOT OUT OF SERVICE Console THEN
QUEUE TO SKILLSET Console WITH PRIORITY 3
WAIT 2
ELSE
EXECUTE Out_Of_Svs_Treatment
END IF

If Console is more likely to be in service than not, it would be better to have this first as Symposium has less lines to go through.

DD