Previous month date range?

[montypython1]

Greetings,

How to set dates to the first day and the last day of PREVIOUS month? (I am able to set dates to the first day and the current day of CURRENT month).

Thank you,
Dave

 

[Mike Lewis]

Dave,

Try this:

ldLastOfPrevMonth = DATE() - DAY(DATE())

ldFirstofPrevMonth = ;
  ldLastofPrevMonth - DAY(ldLastofPrevMonth) + 1

Mike



__________________________________
Mike Lewis (Edinburgh, Scotland)

My Visual FoxPro site: www.ml-consult.co.uk

 

[dgrewe]

Here are a few date functions for you if you need more

*-------------------------
FUNCTION ISLEAPYR
*-------------------------
PARAMETER tdDate
tdDate = ChkParm(tdDate)
RETURN DAY(GOMONTH(tdDate +29 - DAY(tdDate), 2-MONTH(tdDate))) = 29

*-----------------------
FUNCTION DAYSINMO
*-----------------------
PARAMETER tdDate
tdDate = ChkParm(tdDate)
RETURN DAY(GOMONTH(tdDate+1 - DAY(tdDate),1) - 1)

*----------------------
FUNCTION LastDay
*----------------------
PARAMETER tdDate
tdDate = ChkParm(tdDate)
RETURN GOMONTH(tdDate +1 - DAY(tdDate),1) -1

*-------------------------
FUNCTION FirstDay
*-------------------------
PARAMETER tdDate
tdDate = ChkParm(tdDate)
return CTOD(ALLTRIM(STR(MONTH(tdDate))) + "/01/" + ALLTRIM(STR(YEAR(tdDate))))

*-----------------------
FUNCTION ChkParm
*----------------------
PARAMETER tdDate
return iif(vartype(tdDate) = 'D' AND !empty(tdDate),tdDate,date())

David W. Grewe Dave

 

[Mike Lewis]

Dave,

I like your IsLeapYear(). For what it's worth, here's my version:

LPARAMETER lnYear
RETURN NOT EMPTY(DATE(lnYear, 2, 29))

Mike


__________________________________
Mike Lewis (Edinburgh, Scotland)

My Visual FoxPro site: www.ml-consult.co.uk

 

[dgrewe]

One nice thing about VFP, there is always more then one way to skin a cat.


David W. Grewe Dave

 

[Stella740pl]

Mike, and I like your leap year function.
I love short readable solutions.

 

[bborissov]

Dave,
Use DATE() function when you want to convert something to DATE. What would happen if I have SET DATE GERMAN (like almost all East Europe has) and execute yourL

SET DATE GERMAN
? FirstDay(Date(2007,12,31)) && 12/31/2007 - Result: 01/12/2007


FUNCTION FirstDay
*-------------------------
PARAMETER tdDate
tdDate = ChkParm(tdDate)
return CTOD(ALLTRIM(STR(MONTH(tdDate))) + "/01/" + ALLTRIM(STR(YEAR(tdDate))))

But if you change it to:

FUNCTION FirstDay
*-------------------------
PARAMETER tdDate
tdDate = ChkParm(tdDate)
return DATE(YEAR(tdDate), MONTH(tdDate),1)

No matter what the date format is that function will return the right value.

Borislav Borissov
VFP9 SP1, SQL Server 2000/2005.
Microsoft MVP VFP

 

[dgrewe]

Thanks Borislav, None of my program ever run outside the USA so I never thought of it. Well on second Thought, I have some running in England and Australia.

David W. Grewe Dave

 

[montypython1]

Thank you all!

Your suggestions worked perfectly!

Thanks,
Dave Higgins

 

[NasibKalsi]

Hi Dave:

"Thank you all!

Your suggestions worked perfectly!"


I think it is important that you issue a *, when solution is accepted or helped you get through the problem. It will help the readers to know that the problem is solved, and solution is available.

Also, it is not a good idea to issue a star when there is no solution, so others MVP could try to help solve the issue.

Thanks,



Nasib Kalsi