Peak Time report??

[Johnthephoneguy]

We have a call center with lets say 280 IVR ports. Is there a report I can run in symposium that will show the peak hour of those IVR ports?

if there is not a report in symposium how can i get that data?

JohnThePhoneGuy

"If I can't fix it, it's not broke!

 

[telebub]

I see an IVR Port Statistics report in CCM 6. I ran an interval report for yesterday and was able to see when the ports were most active. Maybe that will give you what you need.

War Eagle!!

 

[captaingadget]

I agree with telebub, there isn't a report that gives you the info directly. You could output the report in CSV format and filter the appropriate cells to give you a graph. The CSV output looks mighty strange if you have not seen one before but you will soon realise that there is logic to it and the values you are interested in will always be in the same cells.

 

[mte0910]

Symposium assumes that you will have more calls than agents and that the excess will be queued, so all of the reporting tell you how you serviced callers in queue. An IVR should have more ports than callers, thus what you are looking for (I Think) is a definative number of calls. We call this our High Water Mark (HWM). The IVR report telebub is talking about is not IVR in terms of an Interactive Voice Response System. The IVR report in Symposium is a report based on callers receiving IVR. In my case, I have actual IVR's and each port of the IVR is a Symposium agent. What I needed to know was the greatest number of concurrent callers in my IVR's, so I came up with the code below to capture that information.

/********************************* START HWM *********************************/
/* SECTION hwm_1 */
WHERE TIME OF DAY EQUALS
VALUE x_TIME_1_gv: EXECUTE hwm_2
VALUE x_TIME_2_gv: EXECUTE hwm_3
VALUE x_TIME_3_gv: EXECUTE hwm_4
DEFAULT: EXECUTE sec_one
END WHERE


EXECUTE sec_one
/**** END OF SECTION hwm_1 ****/



/**** CHECK HWM & RECORD ****/
SECTION hwm_2
ASSIGN IVR_sk TO b_Skill1_cv
ASSIGN (LOGGED AGENT COUNT b_Skill1_cv - IDLE AGENT COUNT b_Skill1_cv) TO b_INT_01_cv


READVAR x_IVR_HWM_wcv
IF
b_INT_01_cv > x_IVR_HWM_wcv
THEN
ASSIGN b_INT_01_cv TO x_IVR_HWM_wcv
END IF
SAVEVAR


EXECUTE sec_one
/**** END OF SECTION hwm_2 ****/



/**** WRITE HWM TO DB ****/
SECTION hwm_3
READVAR x_Counter_wcv
ASSIGN (1 + x_Counter_wcv) TO x_Counter_wcv
SAVEVAR


IF
x_Counter_wcv = 5
THEN
READVAR x_IVR_HWM_wcv
SAVEVAR
ASSIGN 1 TO x_SQL_Statement_cv
SEND INFO x_Provider_ID2_gv x_SQL_Statement_cv,
x_IVR_HWM_wcv
END IF


EXECUTE sec_one
/**** END OF SECTION hwm_3 ****/



/**** RESET VALUES OF ALL COUNTERS ****/
SECTION hwm_4
READVAR x_IVR_HWM_wcv
ASSIGN 0 TO x_IVR_HWM_wcv
SAVEVAR


READVAR x_Counter_wcv
ASSIGN 0 TO x_Counter_wcv
SAVEVAR


EXECUTE sec_one
/**** END OF SECTION hwm_4 ****/
/********************************** END HWM **********************************/

What this does in essence is to capture the number of callers currently in the IVR and record that information in a "bucket". If the number of callers (HWM) is less than the number in the bucket, it is discarded, otherwise it is set as the new value of the bucket. At the end of the day, the value in the bucket is written to a database so that I can track my daily high water mark.

Let me know if I need to expound, and if this isn't applicable, then disregard.