paramarray from one function to a next

[christhedonstar]

Hi,

I'm looking at code which uses the paramarray keyword.

Here is an example

public function FirstFunction(ParamArray args()) as long

debug.print ubound(args)
FirstFunction = SecondFunction(args())

end function

public function SecondFunction(ParamArray argS()) as long

debug.print ubound(args)

end function

I get in the immediate window:
1
0

Any idea why this happens?

Thanks,

Chris

 

[SkipVought]

Hi,

What are you supplying to the functions as arguments?

Skip,

_{Just traded in my old subtlety...
for a NUANCE!}

 

[christhedonstar]

=FirstFunction(B6:B6,B7:C7)

Where B6 = "MyValue1"
B7 = "MyValue2"
C7 = "MyValue3

 

[SkipVought]

You're getting the Upper bound index.

Skip,

_{Just traded in my old subtlety...
for a NUANCE!}

 

[CautionMP]

christhedonstar,
I think what Skip is getting at is by passing an array to an array argument your getting an array of arrays.

Said another way [tt]argS()[/tt] in [tt]SecondFunction[/tt] contains a 1 dimensional array that contains a 3 dimensional array.

Hopefully the output from this sample helps to clarify.

Public Function FirstFunction(ParamArray argS()) As Long
  Dim lngOuter As Long
  Debug.Print "FirstFunction"
  For lngOuter = LBound(argS) To UBound(argS)
    Debug.Print "  argS("; CStr(lngOuter); ") = "; argS(lngOuter)
  Next lngOuter
  Debug.Print
  FirstFunction = SecondFunction(argS())
End Function

Public Function SecondFunction(ParamArray argS()) As Long
  Dim varBuffer As Variant
  Dim lngInner As Long, lngOuter As Long
  Debug.Print "SecondFunction"
  For lngOuter = LBound(argS) To UBound(argS)
    varBuffer = argS(lngOuter)
    For lngInner = LBound(varBuffer) To UBound(varBuffer)
      Debug.Print "  argS("; CStr(lngOuter); ","; CStr(lngInner); ") = "; varBuffer(lngInner)
    Next lngInner
  Next lngOuter
End Function

Hope this helps,
CMP

[small]For the best results do what I'm thinking, not what I'm saying.[/small]
(GMT-07:00) Mountain Time (US & Canada)