Obtain folder pathname from BrowseForFolder interface 2

[jasonp45]

Running a VBScript on my XP machine (not associated with any Web stuff) this works fine in bringing up a folder-browser and reporting the folder's title:

Dim oAppShell 'as Shell.Application
Dim oFolder 'as Folder
Set oAppShell = CreateObject("Shell.Application")
Set oFolder = oAppShell.BrowseForFolder(0,"Test",0)
MsgBox oFolder.Title

However what I need is the folder's _path_, and I can't seem to find a way to do this. (

http://msdn.microsoft.com/en-us/library/bb787802(VS.85).aspx)

The Folder object doesn't implement a 'Name' property...the FolderItem object does, and I could probably work from that, but for this project the selected folder is likely to be empty and the FolderItem(s) doesn't seem to work in that case.

 

[EBGreen]

Try this:

Dim oAppShell 'as Shell.Application
Dim oFolder 'as Folder
Dim oParent
Dim oFI
Set oAppShell = CreateObject("Shell.Application")
Set oFolder = oAppShell.BrowseForFolder(0,"Test",0)
MsgBox oFolder.Title
Set oParent = oFolder.ParentFolder
Set oFI = oParent.ParseName(oFolder.Title)
MsgBox oFI.Path

[red]"... isn't sanity really just a one trick pony anyway?! I mean, all you get is one trick, rational thinking, but when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick[/red]

 

[PHV]

...
Set oFolder = oAppShell.BrowseForFolder(0,"Test",0)
If (Not oFolder Is Nothing) Then
  MsgBox oFolder.Items.Item.Path
End If
...

Hope This Helps, PH.
FAQ219-2884
FAQ181-2886

 

[EBGreen]

Nice. I knew there must be a way to do it with the initial object I just got tired of looking for it.

[red]"... isn't sanity really just a one trick pony anyway?! I mean, all you get is one trick, rational thinking, but when you are good and crazy, oooh, oooh, oooh, the sky is the limit!" - The Tick[/red]

 

[jasonp45]

Thanks very much - works like a charm! I needed to be able to allow drives to be selected as well which doesn't work with the Parent object...below is the final code I came up with:

Private Sub User_SetTargetFolder()
  Dim oAppShell 'as Shell.Application
  Dim oFolder 'as Folder
  Dim oParent 'as Folder.Parent
  Dim oFolderItem 'as FolderItem
  Set oAppShell = CreateObject("Shell.Application")
  Set oFolder = oAppShell.BrowseForFolder(0, "Select Target Drive or Folder", 0)
  If InStr(oFolder.Title, ":") > 0 Then 'Drive selected rather than folder
    Target = Mid(oFolder.Title, InStr(oFolder.Title, ":") - 1, 2) & "\" 
  Else
    Set oParent = oFolder.ParentFolder
    Set oFolderItem = oParent.ParseName(oFolder.Title)
    Target = oFolderItem.Path & "\"
  End If
  MsgBox Target    
End Sub
[\code]

 

[jasonp45]

Wow even simpler PH - thanks!