Numeric comparisson with AWK 4

[robdon]

Hi,

I'm having a problem with awk (running on Tru64 5.1)

I have the following 'example' script

{
val3 = 16.775 * 100;

print "val3:" val3;

if (val3 == 1677.5)
print "match";

}

Now for some reason, I never get the 'match' text printed out.

Even though I know that val3 is 1677.5, the IF statement at the end does not seem to be true for some reason.

If I put in 'var3 = 1677.5' before the IF statement, then the IF works.

Can anyone explain what is going on , and why the IF statement does not return true?

Thanks for any help,

Rob Donovan


ProIV Resource Centre <a href='

http://www.proivrc.com'>www.proivrc.com</a>

 

[Salem]

http://en.wikipedia.org/wiki/Floating_point

Floating point numbers are approximations, which usually end up with rounding errors of one sort or another.

Which basically means that computed answers differ in some way from mathematical answers.

$ awk 'BEGIN { a=16.775; a=a*100; print a, a==1677.5 ; printf("%30.15f\n",a) }'
1677.5 0
          1677.499999999999773

Sure, the answer is close, but not close enough to satisfy an == test.

--

 

[robdon]

Hi,

Thanks for the explination, that helps

Rob D.

ProIV Resource Centre

http://www.proivrc.com

 

[p5wizard]

So a solution is to check how close the values match:

{
epsilon = 0.000000001

val3 = 16.775 * 100;

print "val3:" val3;

if (abs(val3 - 1677.5) <= epsilon)
print "match";

}

you probably need to define function abs() yourself:

function abs(val)
{
if (val > 0)
return val;
else
return -val;
}



HTH,

p5wizard

 

[futurelet]

function abs(val)
{
if (val > 0)
return val;
else
return -val;
}

function abs( v )
{ return v > 0  ?  v  :  -v
}

 

[Salem]

You could force awk to perform a string comparision

$ awk 'BEGIN { a=16.775; a=a*100; print a, a==1677.5, a""=="1677.5" }'
1677.5 0 1

The functional approach is going to be better in the long run.
Combining previous answers...

function abs( v )
{
  return v >= 0  ?  v  :  -v
}
function approxEqual( x, y )
{
  epsilon = 0.000000001
  return abs(x-y) <= epsilon
}

So you would then have

{
val3 = 16.775 * 100;

print "val3:" val3;

if ( approxEqual(val3,1677.5) )
  print "match";
}

--