New to VB, getting Run-time error '6': Overflow

[nshenry03]

Getting Run-time error '6': Overflow
Error is near the end of my code

looked up online and it looks like I need to use something bigger than a double (is there a data type that is bigger than a double in VB that allows for decimals?, I didn't really see one)

my other thought was that I might be going outside the bounds of the array, but I've looked over the code and I don't think that I am.

N is a const declared outside the code
I'm passing in a 2D double array as a()
and a vector array as l()

Sub Gauss(ByRef a() As Double, ByRef l() As Integer)
Dim s(1 To N) As Double
Dim r, rmax, smax, xmult As Double
Dim z As Integer
Dim intswap As Integer

For i = 1 To N
l(i) = i
smax = 0
For j = 1 To N
If Abs(a(i, j)) > smax Then smax = Abs(a(i, j))
Next j
s(i) = smax
Worksheets("smax").Cells(i, 1).Value = s(i)
Next i

For k = 1 To (N - 1)
rmax = 0
For i = k To N
r = Abs(a(l(i), k)) / s(l(i))
If r > rmax Then
rmax = r
z = i
End If
Next i

intswap = l(z)
l(z) = l(k)
l(k) = intswap

For i = (k + 1) To N
xmult = a(l(i), k) / s(l(i))
a(l(i), k) = xmult
For j = k + 1 To N
a(l(i), j) = a(l(i), j) - xmult * a(l(k), j) 'HERE IS WHERE I GET THE ERROR
Next j
Next i
Next k
End Sub

 

[nshenry03]

found it , it should be

...
For i = k + 1 To N
xmult = a(l(i), k) / a(l(k), k)
a(l(i), k) = xmult
For j = k + 1 To N
a(l(i), j) = a(l(i), j) - ((xmult) * a(l(k), j))
Next j
Next i
...

 

[gmmastros]

I'm glad you found your problem. I have a suggestion for you, though.

When you declare variables like this...

[tt][blue] Dim r, rmax, smax, xmult As Double[/blue][/tt]

Only the last variable has the double data type. The other variables have a data type of variant. You can verfy this for yourself with the following code.

Dim r, rmax, smax, xmult As Double

MsgBox TypeName(r)
MsgBox TypeName(rmax)
MsgBox TypeName(smax)
MsgBox TypeName(xmult)

I also noticed that you are using i and j as variables, but I don't see you declare them anywhere. At the beginning of every code module, you should put:

[tt][blue]Option Explicit[/blue][/tt]

This will require that every variable being used is formally declared.

I hope my suggestions are helpful.

-George

Strong and bitter words indicate a weak cause. - Fortune cookie wisdom