my formula wont let me create a summary on it

[daveinuk]

Hi All.

I have this formula that I have written and it works in the details section, however when i try to create a summary on it it is greyed out and just will not let me do it any way i try...I just need to create a summary in one of the group headings...any ideas?

Thanks

David.



tonumber (if ({@suggestion work out} <> "remove from iarp"

and {@suggestion work out} <> "already changed" and {@suggestion work out} <> ""

and {units.colheight} <=6)

then tonumber (3) else

if ({@suggestion work out} <> "remove from iarp"

and {@suggestion work out} <> "already changed" and {@suggestion work out} <> ""

and {units.colheight} >=7)

then tonumber (4) else

if ({@suggestion work out} = "iarp 50% rule" and {units.colheight} <=6) then tonumber (3)

else

if ({@suggestion work out} = "iarp 50% rule" and {units.colheight} >=7) then tonumber (4)

else 0)

 

[BobSuruncle]

David,
Please post the contents of the formula {@suggestion work out} .
It seems like it may be a second-pass formula, and is therefore forcing this formula to the second pass too.
Second-pass formulas cannot be summarized by crystal.

You'd need to use variables to accumulate the values.


Bob Suruncle

 

[daveinuk]

Hi, thanks for the quick response...here it is....

if {@concrete iarp age} = true then "iarp concrete AGE" else

if {@steel iarp age} = true then "IARP steel AGE" else

if {@col cond picker} = "3" then "iarp CONDITION" else

if {@50% rule} = true then "iarp 50% rule" else

if ({units.x_renewal} = "IARP" and {units.x_complete} > date (1900,12,12) and {units.x_reason} <> "MERC")

then "already changed" else

if {units.x_renewal} = "IARP" then "remove from iarp" else

""

 

[BobSuruncle]

Same problem, David. You're referencing other formulas that we don't know about.
Can you share their contents, too?
Thanks.


Bob Suruncle

 

[daveinuk]

ok here are all the other formulas that you need:

//@concrete iarp age
if ({units.column} in ["CS","CD"]) and {@age} >=45 then true else false

//@steel iarp age
if (not({units.column} in ["CS","CD"]) and {@age} >=40)then true else false

//@col cond picker
left ({units.colcond} , 1)

//@ 50% rule
if ({@concrete iarp age} = false and {@percentage} >=50) or ({@steel iarp age} = false and {@percentage} >=50) then true else false


any ideas?

Thanks. David.

 

[BobSuruncle]

We're getting closer. . . . What's the content of the @Percentage formula?


Bob Suruncle

 

[daveinuk]

ok its

({@total units changed in iarp period} / (Count ({units.unitno}, {streets.street}))) *100

and before you ask here is the @total units changed in IARP period..

Sum ({@changed in pfi}, {streets.street}) + Sum ({@number to be done}, {streets.street})

and @changed in pfi

if {@installed date} >= date (2003,05,19) then +1 else 0

and @installed date

if {units.colchange} <> date (1899,12,30) then {units.colchange} else {units.installed}

hope this helps..

D.

 

[BobSuruncle]

There's your problem. Your referencing a couple of summaries in this formula.
Count ({units.unitno}, {streets.street})
and
Sum ({@number to be done}, {streets.street})
among others.
Because these fields are already summarized, you can't re-summarize.
If you want to be able to add these formulas, you'll need to use the 3 formula method with variables that's been described throughout this forum.

Basically, the procedure is as follows:
1.) Create a formula to reset the variable(s)
- This would go in the Group Header section, and would likely be suppressed.
- @Reset

WhilePrintingRecords ;
If NOT InRepeatedGroupHeader then
(
NumberVar YourFirstVariableName := 0 ;
NumberVar YourSecondVariableName := 0 ;
NumberVar YourThirdVariableName := 0 ;
//etc. for all vars to be reset
)

2.) Create a formula to accumulate the values
- This formula would likely go into the Details section, and would also be suppressed.
- @Accum

WhilePrintingRecords ;
NumberVar YourFirstVariableName ;
If (some Condition) then 
YourFirstVariableName := YourFirstVariableName + (SomeValue)

3.) Create a formula to show the value of the variable.
-This formula would likely go into the Group Footer section to display the result of the calculations.
- @ShowTheValue

WhilePrintingRecords ;
NumberVar YourFirstVariableName

I think you get the idea.
Good luck.

Bob Suruncle