Moving picture box 1

[JohnBoy2005]

I've got a picture box that holds a menu that moves in and out of view as and when required.

When it's moving back, its leaving a black trail.

Any reasons...

Heres the code, it's a bit crude, but works well, apart from the black trail. Its on a command button click


If strMenu = "In" Then
For m = -2400 To 120
picPopOut.Left = m
picPopOut.Refresh
Next m
strMenu = "Out"
Else
For m = 120 To -2400 Step -0.2
picPopOut.Left = m
picPopOut.Refresh
Next m
strMenu = "In"
End If

Cheers

John

 

[Andrzejek]

Try:

If strMenu = "In" Then
    For m = [blue](picPopOut.Width * -1)[/blue] To 120
        picPopOut.Left = m
        [blue]Me[/blue].Refresh
    Next m
    strMenu = "Out"
Else
    For m = 120 To [blue](picPopOut.Width * -1)[/blue] Step -0.2
        picPopOut.Left = m
        [blue]Me[/blue].Refresh
    Next m
    strMenu = "In"
End If

Have fun.

---- Andy

 

[genomon]

Sometimes .Repaint gets rid of rendering problems. Not sure if that is the case here or not, as I have no experience with this control.

"Don't be irreplaceable. If you can't be replaced, you can't be promoted."

 

[JohnBoy2005]

Thanks Andrzejek

Works great.

Cheers

John

 

[Andrzejek]

You are welcome

BTW, string comparisons are expencive. Since you have just 2 stages, "In" and "Out" for your strMenu, consider using a Boolean instead:

Dim blnShowMenu As Boolean

...

If blnShowMenu Then
    For m = (picPopOut.Width * -1) To 120
        picPopOut.Left = m
        Me.Refresh
    Next m
Else
    For m = 120 To (picPopOut.Width * -1) Step -0.2
        picPopOut.Left = m
        Me.Refresh
    Next m
End If
blnShowMenu = Not(blnShowMenu)

Have fun.

---- Andy

 

[strongm]

Or you could use AnimateWindow ...

 

[strongm]

...
So here's an example. You'll need a form with two picture boxes and a command button. Picture2 should be Sent to Back (oh, and under Vista you'll need to "disable desktop composition"):

[blue]Option Explicit
Private Declare Function AnimateWindow Lib "user32" (ByVal hwnd As Long, ByVal dwTime As Long, ByVal dwFlags As Long) As Boolean
Private Const AW_HOR_POSITIVE = &H1
Private Const AW_HOR_NEGATIVE = &H2
Private Const AW_VER_POSITIVE = &H4
Private Const AW_VER_NEGATIVE = &H8
Private Const AW_CENTER = &H10
Private Const AW_HIDE = &H10000
Private Const AW_ACTIVATE = &H20000
Private Const AW_SLIDE = &H40000
Private Const AW_BLEND = &H80000
Private Const AW_DURATION_DEFAULT = 200

Private Sub cmdMenu_Click()
    Static blnShowMenu As Boolean
    If blnShowMenu Then
        AnimateWindow Picture1.hwnd, AW_DURATION_DEFAULT, AW_HOR_POSITIVE
    Else
        AnimateWindow Picture1.hwnd, AW_DURATION_DEFAULT, AW_HIDE Or AW_HOR_NEGATIVE
    End If
    blnShowMenu = Not blnShowMenu
End Sub

Private Sub Form_Load()
    ' I'm doing a menu via a list box
    ' SO this is just our setup
    List1.Appearance = 0
    List1.AddItem "Menu item 1"
    List1.AddItem "Menu item 2"
    List1.AddItem "Menu item 3"
    List1.AddItem "Menu item 4"
    List1.Top = 0
    List1.Left = 0
    List1.Width = Picture1.Width
    List1.Height = Picture1.Height ' ensure IntegralHeight=0 for best results
    Picture1.Left = -15
    Picture1.BorderStyle = 0
    
    ' Picture2 is just there to give us a little visible tab when window is collapsed
    ' since AnimateWindow actually hides the window it is working on
    Picture2.Appearance = 0
    Picture2.Top = Picture1.Top
    Picture2.Left = Picture1.Left
    Picture2.Width = 120
End Sub

' Allows us to click on the tab to get menu to reappear
Private Sub Picture2_Click()
    cmdMenu_Click
End Sub

' Just for fun
Private Sub Form_Unload(Cancel As Integer)
    AnimateWindow Form1.hwnd, AW_DURATION_DEFAULT, AW_HIDE Or AW_HOR_POSITIVE Or AW_SLIDE
End Sub[/blue]

 

[Andrzejek]

strongm, since I like to try examples like yours, so I did. But "need a form with two picture boxes, [blue]a listbox,[/blue] and a command button [blue]named cmdMenu[/blue]" eventually got it to compile, but ... what was supposed to happen? It runs, but just display a few items in the list box, but command button does nothing :-(


Have fun.

---- Andy

 

[strongm]

ah, the listbox should be placed in the picturebox rather than the form. Sorry, should have said that.

 

[strongm]

Did that fix things enough for you, Andy?

 

[Andrzejek]

Yes, thanks. Pretty fancy

But honestly, I like JohnBoy2005's way better, it is easier to follow and a lot less code.

Have fun.

---- Andy

 

[strongm]

Whilst I'm not advocating my solution as better (it won't work under W2000 or earlier, for example, and has some compositing restrictions under Vista), I'd have to argue with your conclusion that the other way is easier to follow or that it has less code. The example I provide is a full example, the alternative is simply an extract. The equivalent extract from my example would be (renaming my picture to match that used originally):

[blue]    Static blnShowMenu As Boolean
    If blnShowMenu Then
        AnimateWindow picPopOut.hwnd, AW_DURATION_DEFAULT, AW_HOR_POSITIVE
    Else
        AnimateWindow picPopOut.hwnd, AW_DURATION_DEFAULT, AW_HIDE Or AW_HOR_NEGATIVE
    End If
    blnShowMenu = Not blnShowMenu[/blue]

which looks shorter to me - and at least as clear in what it is doing (to me, anyway). And if it isn't clear enough ... well our 'magic' numbers can easily be redefined (although, to maintain the 'extract only' presentation I'm deliberately not including the definitions here ...), which might give you:

[blue]    Static blnShowMenu As Boolean
    If blnShowMenu Then
        AnimateWindow picPopOut.hwnd, AnimationLasts200ms, WindowShow + SlideWindowToTheRight
    Else
        AnimateWindow picPopOut.hwnd, AnimationLasts200ms, WindowHide + SlideWindowtoTheLeft
    End If
    blnShowMenu = Not blnShowMenu[/blue]