MINT Script for MSO660 2

[BEM]

Looking for a MINT Script to load info for MSO660. Anybody?

Regards,
BEM

 

[notaguru]

Happy Minting.....

JOB 660UPL 'Upload Projects'

DEFINE DATA_FILE 'C:\tmp\660UPL.CSV'
DEFINE BACKUP_FILE 'c:\tmp\660UPL.BAK'
DEFINE ERROR_FILE 'c:\tmp\660UPL.ERR'


/* 660A
DEFINE PROJECT_NO1I CSV_2

/* 660B
DEFINE AUTHSD_BY2I CSV_3
DEFINE AUTHSD_DATE2I CSV_4
DEFINE PROJ_DESC2I CSV_6
DEFINE ORIGINATOR_ID2I CSV_7
DEFINE ASSIGN_PERSON2I CSV_8
DEFINE ACCOUNT_CODE2I CSV_9

/* 660C
DEFINE CUSTOMER_NO3I CSV_10
DEFINE QUOTE_VALUE3I CSV_11
/* FIXED 660C
DEFINE BILLABLE_IND3I 'Y'
DEFINE RLOC_METHOD3I 'BP'


SUBROUTINE ENABLE_ALL
ENABLE MSM660A
ENABLE MSM660B
ENABLE MSM660C
RETURN

SUBROUTINE DISABLE_ALL
DISABLE MSM660A
DISABLE MSM660B
DISABLE MSM660C
RETURN

SUBROUTINE IMPORT_NEXT_RECORD
IMPORT FILE DATA_FILE FORMAT CSV EXTRACT
SET 'ATTEMPT_CNT=' (ATTEMPT_CNT + '1')
ABORT IF CSV_1
SET 'ATTEMPT_CNT=' (ATTEMPT_CNT - '1')
SET 'EOF=' 'TRUE'
RETURN



SUBROUTINE LOG_ERROR
SET 'ERROR_COUNT=' (ERROR_COUNT + '1')
EXPORT FILE ERROR_FILE FORMAT RAW APPEND
. 'Error in Screen : ' SCREEN_NUMBER '' "\r\n"
. 'Message : ' ERROR_MESSAGE '' "\r\n"
. CSV_1 ',' CSV_2 ',' CSV_3 ',' CSV_4 ',' CSV_5 ',' &
CSV_6 ',' CSV_7 ',' CSV_8 ',' CSV_9 ',' CSV_10 ',' &
CSV_11 ',' CSV_12 ',' CSV_13 ',' CSV_14 ',' CSV_15 ',' &
CSV_16 ',' CSV_17 ',' CSV_18 ',' CSV_19 ',' CSV_20 ',' &
CSV_21 "\r\n"
. ' ' "\r\n"
RETURN

SUBROUTINE FINISH
ABORT IF NOT EOF
PERFORM DISABLE_ALL
SYSTEM 'ECHO ' ERROR_COUNT ' Errors, ' SUCCESS_CNT ' Successes.'
RETURN

SUBROUTINE INIT
SET 'SUCCESS_CNT=' '0'
SET 'ERROR_COUNT=' '0'
SET 'ATTEMPT_CNT=' '0'
PERFORM ENABLE_ALL
RETURN

SUBROUTINE F3_IF_2ND
ABORT IF (BCOUNT = '0')
KEY !F3
RETURN

MANUAL MSM660A
PERFORM INIT
TRIGGER @ERRMESS1I
. VALUE ' '
. PERFORM IMPORT_NEXT_RECORD
. PERFORM FINISH
. ABORT IF EOF
. KEY
. . !ENTER '1' !TO @OPTION1I
. . !ENTER PROJECT_NO1I !TO @PROJECT_NO1I
. . !SEND
. VALUE ''
. SET 'SCREEN_NUMBER=' 'MSM660A'
. SET 'ERROR_MESSAGE=' @ERRMESS1I
. SYSTEM 'ECHO Error in screen ' SCREEN_NUMBER '. ' ERROR_MESSAGE
. PERFORM LOG_ERROR
. KEY !F3

DYNAMIC MSM660A
SET 'BCOUNT=' '0'
TRIGGER @ERRMESS1I
. VALUE ' '
. PERFORM IMPORT_NEXT_RECORD
. PERFORM FINISH
. ABORT IF EOF
. KEY
. . !ENTER '1' !TO @OPTION1I
. . !ENTER PROJECT_NO1I !TO @PROJECT_NO1I
. . !SEND
. VALUE ''
. SET 'SCREEN_NUMBER=' 'MSM660A'
. SET 'ERROR_MESSAGE=' @ERRMESS1I
. SYSTEM 'ECHO Error in screen ' SCREEN_NUMBER '. ' ERROR_MESSAGE
. PERFORM LOG_ERROR
. KEY !F3

DYNAMIC MSM660B
TRIGGER @ERRMESS2I
. VALUE ' '
. TRIGGER @FKEYS2I
. . VALUE 'XMIT-Validate'
. . PERFORM F3_IF_2ND
. . ABORT IF (BCOUNT = '1')
. . KEY
. . . !ENTER AUTHSD_BY2I !TO @AUTHSD_BY2I
. . . !ENTER AUTHSD_DATE2I !TO @AUTHSD_DATE2I
. . . !ENTER PROJ_DESC2I !TO @PROJ_DESC2I
. . . !ENTER ORIGINATOR_ID2I !TO @ORIGINATOR_ID2I
. . . !ENTER ASSIGN_PERSON2I !TO @ASSIGN_PERSON2I
. . . !ENTER ACCOUNT_CODE2I !TO @ACCOUNT_CODE2I
. . . !SEND
. . VALUE 'XMIT-Confirm'
. . SET 'BCOUNT=' '1'
. . KEY !SEND
. VALUE ''
. SET 'SCREEN_NUMBER=' 'MSM660B'
. SET 'ERROR_MESSAGE=' @ERRMESS2I
. SYSTEM 'ECHO Error in screen ' SCREEN_NUMBER '. ' ERROR_MESSAGE
. PERFORM LOG_ERROR
. KEY !F3

DYNAMIC MSM660C
TRIGGER @ERRMESS3I
. VALUE ' '
. TRIGGER @FKEYS3I
. . VALUE 'XMIT-Validate'
. . KEY
. . . !ENTER BILLABLE_IND3I !TO @BILLABLE_IND3I
. . . !ENTER CUSTOMER_NO3I !TO @CUSTOMER_NO3I
. . . !ENTER RLOC_METHOD3I !TO @RLOC_METHOD3I
. . . !ENTER QUOTE_VALUE3I !TO @QUOTE_VALUE3I
. . . !SEND
. . VALUE 'XMIT-Confirm'
. . SET 'SUCCESS_CNT=' (SUCCESS_CNT + '1')
. . SYSTEM 'ECHO Successfully loaded Project ' PROJECT_NO1I
. . KEY !SEND
. . VALUE 'XMIT-Validate'
. . KEY !F3
. VALUE ''
. SET 'SCREEN_NUMBER=' 'MSM660C'
. SET 'ERROR_MESSAGE=' @ERRMESS3I
. SYSTEM 'ECHO Error in screen ' SCREEN_NUMBER '. ' ERROR_MESSAGE
. PERFORM LOG_ERROR
. KEY !F3

END 660UPL

 

[BEM]

I hope so.
Thank a lot.

 

[lmel]

BEM,
Kindly send me the steps for executing a MINT script. I have installed the software but got stack on the next steps, where to place the script, how to comiple it and finally run it.

send your ifor to lewis.mambwe@kcm.co.zm