Micros - Sim - BOGOF

[JaiSpencer]

Hi all, as we have many different versions of Res in our estate, and with that the discounts section of Res is very limited.

To the point:
We have sims that offer BOGOF, but these discount the cheapest pizza.
We want to use a SIM to create a BOGOF, but to discount the 2nd pizza added, even if it costs more.

Is this possible?

 

[Moregelen]

The discounts in micros can easily handle this. I don't understand why you are using a SIM.

Screenshot of a basic bogo which you can even run by family group, major group, individual menu items... you can make it apply automatically, or make them actually hit a button to do it. The discounts are actually quite versatile.

https://www.dropbox.com/s/bnfqic3zh76j5dm/Bogo_Screenshot.PNG

 

[JaiSpencer]

Hi, as i put in the first line, we have many different versions of res in our estate, 3.2 -> 4.11.
This means our EM server only has 3 tabs under the discounts area:
General
Options
Discount

So, SIM it is until our estate is fully on 4.11 later this year.

Ideally i would like it to be something like:


Event inq: #
if ( menu item = 1153 or 1155)
infomessage "Order needs to have a BigT Pizza to use"
exitcontinue
else

And then discount the 2nd pizza on the order to £0.00

Thanks

 

[Moregelen]

OK - the reason this is a bit tricksy is because what if I ring in the first pizza, send the order, and then come back to ring in the second pizza. Still get the BOGO? I'm assuming that is a yes. Can you get the BOGO twice? Lets say that's a yes. So you have to be able to account for if you've already discounted the second pizza, and track if they are ringing in a third, fifth, etc. Do your pizza's have forced modifiers? That will affect things too. Assuming just a basic setup where the pizza doesn't have forced modifiers, and the BOGO is unlimited on the check.. something like this might work... setup the discount as an item discount at 100%, make it so its not in a SLU so that servers can't get to it. It will apply to every even pizza entered.. so pizza #2, #4, #6, etc...

var pizza_family : N9 = 10 //set this to the object number of the pizza family group
var pizza_discount : N9 = 218 //set this to the 100% discount the pizza BOGO should use

var i : N9

event mi:

	if @dtl_famgrp_objnum[@numdtlt] <> pizza_family or @dtl_type[@numdtlt] <> "M"
		exitcontinue
	endif

	var count : N9 = 0 //count how many of the pizza's we already have
	for i = 1 To @numdtlt
		if @dtl_famgrp_objnum[i] = pizza_family AND @dtl_type[i] = "M"
			count = count + 1
		endif
	endfor

	var modu : N1 = count % 2
	if modu = 1 //its an odd numbered pizza; assuming everything is working correctly the discount for the previous BOGO, if it exists, was already applied
		exitcontinue
	endif

	//if we get here, its an even numbered pizza so we need to apply the BOGO discount
	loadkybdmacro key(5, pizza_discount)

endevent

 

[Moregelen]

And sorry - I had assumed when you said different versions you meant within RES 4 - RES 5 given that most people have already left RES 3 for PCI reasons.

 

[JaiSpencer]

Sssh! We still have res 3 out there! :/

Lol.

thank you for this format, i will test it over the weekend and give you some feedback!

Thanks again, have a great wkend.