List subfolders 1

[ccoll23]

Does anyone know how to list the following to a text file?

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder("C:\FSO")
Set colSubfolders = objFolder.Subfolders

For Each objSubfolder in colSubfolders
Wscript.Echo objSubfolder.Name, objSubfolder.Size
Next

Thanks for any input,

ccoll23

 

[PHV]

Have a look here:

http://msdn.microsoft.com/library/en-us/script56/html/0fd59100-adcf-441d-8fa5-5e0800ad34d6.asp

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ181-2886

 

[mrmovie]

not sure what PHV thread says but you can write to a text file or you could cheat and run your script from a cmdline

cscript.exe myscript.vbs > c:\results.txt

 

[ccoll23]

mrmovie,

Thanks, but how would I write that to file? That's what I'm having trouble with. How would I change the "Wscript.Echo" to write the results to a txt file?

Thanks,

ccoll23

 

[PHV]

how would I write that to file?
This is explained in the link I gave you ...

 

[BenChristian]

You could do it without using vbscript if you wanted to by doing running this from a command prompt:

c:
cd\FSO
dir *. /B > c:\folderlist.txt


If you want to use vbscript, here is how:

'Set the ForWriting constant for when you open the textfile (you want to write to the text file, not read or append)
Const ForWriting = 2

'Define the output filename here
strOutputFileName = "c:\folderlist.txt"

'Define FSO
Set objFSO = CreateObject("Scripting.FileSystemObject")

'Create the text file and open it
Set objFile = objFSO.CreateTextFile(strOutputFileName)
Set objFile = Nothing
Set objOutputTxtFile = objFSO.OpenTextFile(strOutputFileName,ForWriting)

'Your existing code get the folder that you want to work with
Set objFolder = objFSO.GetFolder("C:\FSO")
Set colSubfolders = objFolder.Subfolders

For Each objSubfolder in colSubfolders
'Rather than using wscript.echo, you use the write line method
objOutputTxtFile.WriteLine(objSubfolder.Name & "," & objSubfolder.Size)
Next

'Close the text file
objOutputTxtFile.Close

Hope that helps.

http://www.benchristian.com

 

[ccoll23]

That's it!!..Thanks benchristian for the help!!!...