Inseert new 'blank' page after every 3rd page MSWord 2003 1

[aarondewberry]

Hi all

I have a word document that is around 200 pages long. Due to duplexing issues whilst printing, after page 3, I need to insert a new blank page. I need to do this after every third page. So basically I will end up with a new blank page 4,8,12,16 etc...
Note, I want to keep the original page 4, 8, 12 etc... They will just move up a page and become 5, 9, 13 etc..
Hope i'm making sense!
Can this be done...? I am stuck!

 

[aarondewberry]

More info: The word document is split into sections. There are 3 pages in every section. So I just need to add a page break to the last page in every section.

Thanks

 

[macropod]

Hi aarondewberry,

Is there a reason you can't simply print the document in blocks of 3 pages? This would have the same effect on the printout as inserting extra pages, but without the need to modify the document. A macro you could use to automate this is:

Sub PrintMe()
Dim i As Integer
With ActiveDocument
  For i = 1 To .ComputeStatistics(wdStatisticPages)
    If i Mod 3 = 0 Then .PrintOut Pages:=i - 2 & "-" & i, Copies:=1
  Next
  If .ComputeStatistics(wdStatisticPages) Mod 3 <> 0 Then
  i = Int(.ComputeStatistics(wdStatisticPages) / 3) * 3 + 1
    .PrintOut Pages:=i & "-" & .ComputeStatistics(wdStatisticPages), Copies:=1
  End If
End With
End Sub

Of course, if your document already has Section breaks every 3rd page (as would be the case if the document is the result of a letter mailmerge), you could use:

Sub PrintMe()
Dim i As Integer
With ActiveDocument
  For i = 1 To .Sections.Count
    .PrintOut Pages:="s" & i, Copies:=1
  Next
End With
End Sub

Cheers
[MS MVP - Word]

 

[SkipVought]

StartPage = (Section - 1) * 3 + 1
EndPage = StartPage + 2

Skip,
[sub]
Just traded in my old subtlety...
for a NUANCE![/sub]

 

[fumei]

While the above solutions do indeed (possibly) solve your issue in terms of printing, if you still actually wish to do what you asked -

I need to insert a new blank page. I need to do this after every third page.

AND the following is totally accurate -

There are 3 pages in every section. So I just need to add a page break to the last page in every section.

the following does that. It adds a page break at the end of every Section.

Sub AddPageEachSection()
Dim r As Range
Dim oSection As Section
For Each oSection In ActiveDocument.Sections
   Set r = oSection.Range
   With r
      .Collapse 0
      .Move Unit:=wdCharacter, Count:=-1
      .InsertBreak Type:=wdPageBreak
   End With
Next
End Sub

"A little piece of heaven
without that awkward dying part."

advertisment for Reese's Peanut Butter Cups (a chocolate/peanut butter confection)

Gerry

 

[macropod]

Hi Gerry,

Somewhat more efficiently:

Sub AddPageEachSection()
Dim oSection As Section
For Each oSection In ActiveDocument.Sections
   oSection.Range.Characters.Last.InsertBefore Chr(12)
Next
End Sub

Cheers
[MS MVP - Word]

 

[fumei]

Hoo-hoo!

Indeed. I like it. I always like code to be more efficient. A star to you sir.

Gerry

 

[fumei]

To macropod, BTW, are you attending the MVP-fest in February? It would be good to meet you.

Gerry

 

[macropod]

Hi Gerry,

No, I won't be there - there's no way I could justify the expense.


Cheers
[MS MVP - Word]

 

[fumei]

I understand. It is a lot easier for me, as I am only a fairly short drive away.

Gerry