If file exists, load it, else insert library item

[Leozack]

I've googled around for a while tonight for things like "actionscript 1 check file exists" and so on, and the best I find is people saying to check if a file exists, do this

fileExists=new LoadVars();
fileExits._parent=this;
fileExists.onLoad=function(success)
{
//success is true if the file exists, false if it doesnt
if(success)
{
//the file exists
var nm=this._parent.createEmptyMovieClip("swfHolder",1); //so create a movieclip
nm.loadMovie("myfile.swf"); //and load our .swf file into it
}
}
fileExists.load("myfile.swf") //initiate the test

The problem is while that may itself work, I can't put all that in for every image load, and I can't make it into any kind of function because the function will always return false when called because the image doesn't load until later. And I can't pass the function what to do when it loads etc. So yeah I've tried all sorts. The code I'm really trying to come up with would make this possible

If (DoesFileExist(filename)) { ShowImage(clip,filename); }
Else { clip.attachMovieClip("libitem","libitem",1); }

or maybe

var didItWork = ShowImage(clip,filename);
if (!didItWork) { clip.attachMovieClip("libitem","libitem",1); }

That way I can simply load images if they're there and if now I can load a library item that is a 'image not found' symbol. But frankly I can't for the life of me do it -_-

_________________________________
Leozack

MakeUniverse($infinity,1,42);

 

[kennethkawamoto]

In AS3 AIR there is "File.exists" property does just that.

But for online project you'd use PHP or something to pass the list of files to Flash.

Kenneth Kawamoto

http://www.materiaprima.co.uk

 

[Leozack]

Someone else suggested something like this

function checkFileExists(i_file:String, i_functionName:String)
{
    fileExists = new LoadVars();
    thisVal = this;
    fileExists.onLoad = function(success)
    {
        //success is true if the file exists, false if it doesnt
        if (success)
        {
            //the file exists
            //call back
            thisVal[i_functionName](i_file);
        }
    };
    fileExists.load(i_file);
}
//
function doSomethingWithImageItExists(i_file:String)
{
    trace("lets load now it exists!  " + i_file);
}
//
checkFileExists("test.swf", "doSomethingWithImageItExists");

But I've not yet got it to work :/ Great to know the feature is finally in CS3 but when such a basic feature isn't available in earlier ones people had to get by somehow didn't they? Did people just not check if a file exists before trying to use it or whatever? Hmmm.

I don't want ot use php's fileexists as that would be an extra requirement of php on a server purely for the purpose of that 1 function

_________________________________
Leozack

MakeUniverse($infinity,1,42);

 

[Leozack]

Ok so after removing the strong typing typecasts on the above functions, it worked Maybe AS1 doesn't like them or something but once I removed those it worked.
However - whilst I can now fire off a function if the imagefile exists and loads successfully - I can't find a way to load an alternate error message image or perform some other code if it doesn't. And I can't find a way to load the error image into a clip and then use this stuff to check if a real image exists and if so laod it into the clip instead of the error image, acheiving the same result as loading images if they exist and getting an error image if they don't. I'm trying various code here but gonna have to stop for the night

_________________________________
Leozack

MakeUniverse($infinity,1,42);

 

[kennethkawamoto]

There is no type casting in AS1.

This is how I'd do it:

function checkFileExists(i_file, successFunction, fallBackFunction) {
	fileExists = new LoadVars();
	fileExists.onData = function(src) {
		if (src != undefined) {
			successFunction(i_file);
		} else {
			fallBackFunction(i_file);
		}
	};
	fileExists.load(i_file);
}
// success function
function doSomethingWithImageItExists(i_file) {
	trace("lets load now it exists!  "+i_file);
}
// fallback function
function doSomethingIfNot(i_file) {
	trace(i_file+" does not exist :(");
}
//
checkFileExists("test.swf",doSomethingWithImageItExists,doSomethingIfNot);

Kenneth Kawamoto

http://www.materiaprima.co.uk

 

[Leozack]

It didn't like your direct insersion of variables for function names - using the previous syntax of myVal = this and myVal[functionname](args) worked ok though. So I've rounded it off with the ability to pass arguments to those functions in an array, eg

// Checking Function
function checkFileExists(i_file, successFunction, failFunction, functionArgs) {
    fileExists = new LoadVars();
	thisVal = this;
    fileExists.onData = function(src) {
        if (src != undefined) {
            thisVal[successFunction](functionArgs);
        } else {
            thisVal[failFunction](functionArgs);
        }
    };
    fileExists.load(i_file);
}
// Success Function
function fileFound(argumentArray) {
	for (i=0; i < argumentArray.length; i++) {
		trace("Success!  Arguments passed : " + i + " - " + argumentArray[i]);
	}
}
// Fail Function
function fileNotFound(argumentArray) {
	for (i=0; i < argumentArray.length; i++) {
		trace("Failiure!  Arguments passed : " + i + " - " + argumentArray[i]);
	}
}
// Code Body
testArr = new Array(imgHolderMC,imgWidth,imgHeight,imgFilename,imgMaskMC);  // Just a bunch of variables
checkFileExists(thisFile, "fileFound", "fileNotFound", testArr);

_________________________________
Leozack

MakeUniverse($infinity,1,42);

 

[kennethkawamoto]

Well, I prefer less typing But it's up to you of course.

Kenneth Kawamoto

http://www.materiaprima.co.uk

 

[Leozack]

I didn't say I didn't like the direct variables as function names, I said IT didn't, aka flash It didn't work untilI changed them to the thisvariable[functionname] style but there ya go

_________________________________
Leozack

MakeUniverse($infinity,1,42);

 

[kennethkawamoto]

That may be to do with your version of Flash, since both method works fine with CS3 using both AS1 and AS2 export settings.

Kenneth Kawamoto

http://www.materiaprima.co.uk

 

[Leozack]

Maybe it's a flash6mx thing then. You live and learn!

_________________________________
Leozack

MakeUniverse($infinity,1,42);