I stink @ arrays 1

[RonRepp]

Hi all:

I'm trying to add to an array and I keep getting an "Index out of bounds error".

Set FSO = CreateObject("Scripting.FileSystemObject")
Set F = FSO.OpenTextFile(strFilePathName, 1, False)
i = 0

Do While F.AtEndOfStream <> True
    RetString = F.ReadLine
     Replace RetString, vbCrLf, ""
    FileArray(i) = RetString
Loop
F.Close

Any help will be greatly appreciated.

Ron Repp

If gray hair is a sign of wisdom, then I'm a genius.

My newest novel: Wooden Warriors

http://www.repproductions.net

 

[Jasen]

An array needs to be dimensioned--given a size--before you can access an index inside of it. They start out empty if you declare it like such:

Dim FileArray() as String

Or you can declare it with a fixed size if you know exactly how many indexes you need:

Dim FileArray(10) as String

If you don't know how large you'll need it to be, you declare it empty to start with, and then use ReDim to resize it as you add to it.
I also suggest in your example above to add a reference to the "Microsoft Scripting Runtime" to your project, and ditch the CreateObject statement.

    Dim FileArray() As String
    Dim fso As Scripting.FileSystemObject
    Dim F As TextStream
    Dim i As Integer
    Dim RetString As String
    
    Set fso = New Scripting.FileSystemObject
    Set F = fso.OpenTextFile(strFilename, 1, False)
    
    i = 0
    Do While Not F.AtEndOfStream
        ReDim Preserve FileArray(i)
        RetString = Replace(F.ReadLine, vbCrLf, "")
        FileArray(i) = RetString
        i = i + 1
    Loop
    F.Close