Hyphenated Names and Apostrophes 2

[DougInCanada]

I have a script for creating user accounts which makes the first letter of a name uppercase and the rest lowercase:

intLastName = Len(strLastName)
strFirstLetter = UCase(Left(strLastName, 1))
strRemainingLetters = LCase(Right(strLastName, intLastName - 1))
strLastName = strFirstLetter & strRemainingLetters

However, we actually have a situation where a user has not only a hypenated name, but that hypenated name also contains an apostrophe

(lastname = Hoffa-O'Reilly)

I'm looking to add code to my script that will allow me to not only change the 'H' to an uppercase, but also the letters before and after the apostrophe ('O' & 'R') and I'm not quite sure how to go about it....

 

[Geates]

Get the chunk of text starting the character before and after the apostrophe. Then replace that chunk in strLastName with the ucase() of the chunk.

[s][/s]
intPos = inStr(strLastName, "'")
if (intPos) then
   strChunck = mid(strLastName, intPos -1, 3)
   strLastName = replace(strLastName, strChunck, ucase(strChunck))
end if

-Geates

 

[DougInCanada]

Thanks, Geates, works great!

Just to make it a little more challenging, how can I change it to detect more than one apostrophe in a hyphenated name (ie: O'Reilly-O'Shea)?

 

[strongm]

Here's a solution using RegExp (actually using quite an obscure feature of RegExp: the ability to use a custom replacer function). As you can see it can capitalise multiple names in one go:

[blue]Dim myReplacer 
 
Set myReplacer = getRef("ReplacerFunction") 

strLastName="hoffa-o'reilly" & vbcrlf &  "wood-robinson" 

With Createobject("vbscript.regexp")
    .Global = True
	.Multiline = True
	.pattern="(^|-|')(\w{1})"
    MsgBox .Replace(strLastName, myReplacer)
End With

	
Public Function ReplacerFunction(wholematchstring,match1,match2,matchpos,source) ',c,d) As String
	ReplacerFunction = match1 + ucase(match2)
End Function[/blue]

 

[Geates]

how can I change it to detect more than one apostrophe in a hyphenated name

Loop it?

strLastName = "henry-o'rielly-o'brian"

intPos = inStr(strLastName, "'")
do while (intPos)
   strChunck = mid(strLastName, intPos -1, 3)
   strLastName = replace(strLastName, strChunck, ucase(strChunck))
   intPos = inStr(intPos + 1, strLastName, "'")
loop

msgbox strLastName

-Geates

 

[strongm]

>more than one apostrophe in a hyphenated name

The regexp solution already handles that ...

 

[DougInCanada]

Thanks to you both, each solution works really well.

strongm, that's really interesting, it's my first encounter with regexp, seems like lots of useful opportunites, but how do I actually replace strLastName with the .replace results, rather than just display them in a message box?

Cheers to you both!

 

[strongm]

strLastName = .Replace(strLastName, myReplacer)

 

[DougInCanada]

thanks, strongm.

Now I just have to try to figure out how to use regexp to capture Mc and Mac (ie: McDuff and MacDonald)....

 

[PHV]

I'd try this:

.pattern="(^|-|'|Mc|Mac)(\w{1})"

Hope This Helps, PH.
FAQ219-2884
FAQ181-2886

 

[strongm]

I wouldn't

I'd try:

[blue].pattern = "(^mc|^mac|^|-|')(\w{1})[/blue]

and modify the replace function as:

[blue]Public Function ReplacerFunction(wholematchstring,match1,match2,matchpos,source) 
	[b]if len(match1)>1 then [green]'deal with inconvenient fact that the Mcs and Macs are longer than one char[/green]
		match1=ucase(left(match1,1)) & trim(right(match1 & " ", len(match1)))
	end if[/b]	ReplacerFunction = match1 & ucase(match2)
End Function[/blue]

 

[Geates]

Note: for multiple considerations multiple times with multiple objects, the regex solution is WAY more simple and efficient.

-Geates

 

[DougInCanada]

Phenomenal, completely changes how I can deal with strings containing patterns! No, if I can just get a handle on the pattern syntax...found this site:

[link ]

http://www.regular-expressions.info/reference.html

[/url]

Seems to be quite good for explaining patterns, as well as the other syntax.

Hope others find this as useful as I did.

Nicely done, StrongM and thanks, Geates!