How to trap return code of a job in rexx program

[gpinaki]

Hi,
I have a rexx program that submits a Jcl. After completion it throws a panel with outputs. Now I want to trap the return code of that job in my rexx program and wants to show in the output panel .Please tell me how to trap that return code.

 

[KarlheinzWittemann]

where is your log? IOF, SDSF, LDMS?

with all of them you can deal with rexx but you have to look at teh right manual.

Heinz

 

[rocky4u]

Hi KarlheinzWittemann ,


I have the same problem & I have log in SDSF ..so can u please tell me which manual to look for ?

Thanks in advance,
RAkesh

 

[rvemuri]

In the REXX program use the OUTTRAP facility to trap the error complete message along with the return code. I don't know if this will work out or not but try it once.

Thanks
Rajesh Vemuri

 

[dorkie]

I'm not sure outtrap would work here...
try using sdsf in
REXX

 

[KiwiREXXDude]

I think there is a rather brutal way of doing this on the mainframe. You need to do the following;

1) sumbit the job and trap the jobname and number
2) put the REXX into a loop, turn on an output trap and issue the TSO command &quot;STATUS <jobname>(JOB<number>)&quot;
3) check the resulting IKJnnnnnI message until you get an indication the job is complete (note: these messages may be enough)
4) turn on another trap and issue the &quot;OUT <jobname>(JOB<number>) KEEP&quot; (note: not sure of this syntax) which will put the contents of the output to your trap

I suggest you look up STATUS, OUT, and maybe IKJ5619* through help or QuickRef.

Of course if your site are using a spool writer you are either totally stuffed or you have to work out an interface to it...

 

[Darkwing99]

If you use SDSF I have a REXX that my be helpful:

Run this script in a loop until
return ^= &quot;XXMAXRC> JobId empty&quot;

/* REXX */                                                                    
/* Receive MAXRC out of SDSF                                    
                                                                              
   Parameter:
   jobname      -   JobName of the submitted job
   jobid        -   JobID of the submitted job
*/


arg jobname jobid 


address TSO                                 

if(jobname = "")                            
then do                                     
  return "XXMAXRC> JobId empty"   
end                                         
if(jobid = "")                              
then do                                     
  return "XXMAXRC> JobId empty"   
end                                         

maxrc = ""                                  


/* write SDSF Commands to QUEUE */    
queue "SET CONFIRM OFF"                  
queue "OWNER *"                                               
queue "PREFIX *"                                              
queue "H"                                                     
queue "SELECT "jobname jobid                                  
queue "AFD REFRESH"                                           
queue "FIND "jobname                                          
queue "END"                                                   
queue ""                                                      

/* allocate in-/out-dataset */                         
"alloc dd(isfin)  new reuse unit(vioda)",                     
       "recfm(f,b) lrecl(80) blksize(27920) space(1) tracks"  
"alloc dd(isfout) new reuse unit(vioda)",                     
       "recfm(f,b,a) lrecl(301) blksize(27993) space(1) cyl"  

/* write input-dataset from QUEUE */                       
"execio * diskw isfin (finis"                                 

/* SDSF-Call */                                             
PARM = "/ ++20,400"                                           
address LINKPGM "SDSF PARM"                                   

/* read isfout in out. */                
"execio * diskr isfout (stem out. finis"              
"free dd(isfin,isfout)"                               

do i=1 to out.0 by 1
  if(pos(jobname,out.i) ^= 0 & pos(jobid,out.i) ^= 0)
  then do
    maxrc = substr(out.i,276)
    leave
  end
end

/*                                            */       
/*    Alter ReturnCodes                       */       
/*                                            */       
if(maxrc = "")
then do
   maxrc = "XXMAXRC> JobId empty"   
end
else do

/*   Returncode = 'CC 0000'     ===> 'R0000'  */
   if(left(maxrc,2) = "CC")
                then maxrc = "R"!!SUBSTR(maxrc,4,4)

/*   Returncode = 'ABENDU3501'  ===> 'U3501'   */
   if(left(maxrc,6) = "ABENDU")
                then maxrc = "U"!!SUBSTR(maxrc,7,4)

/*   Returncode = 'ABEND S0C7'  ===> 'S0C7 '   */
   if(left(maxrc,7) = "ABEND S")
                then maxrc = SUBSTR(maxrc,7,4)

/*   other RCs (=HighRC)        ===> 'X'RC        */
/*   z.B.                                         */
/*   Returncode = 'CANCEL'      ===> 'XCANCEL'    */
/*   Returncode = 'JCL ERROR'   ===> 'XJCL ERROR' */
   if(left(maxrc,1) ^= "R" & left(maxrc,1) ^= "U" & left(maxrc,1) ^= "S")
                then maxrc = 'X'!!maxrc
end

return maxrc