How to set startup option "Allow Default Shortcut Menus" via VBA? 1

[sudakov]

Hi everybody,
does anybody know how to set startup option "Allow Default Shortcut Menus" via VBA?

I tried the following:

Application.SetOption "AllowDefaultShortcutMenus"), False

and

CurrentDb.Properties("AllowDefaultShortcutMenus") = False

No success for now.

Does anybody can help?

sudakov

 

[Remou]

  'Usage: Setprop "AllowShortcutMenus",False,dbBoolean
   
  Public Sub SetProp(PropName As String, PropVal As Variant, Optional PropType = dbText)
     Dim db As Object
     Dim prp As Object
     Dim strTitle As String
   
     Const PROPERTY_NOT_FOUND As Integer = 3270
   
     On Error GoTo ErrorHandler
   
     Set db = CurrentDb
   
     ' Try to set the property. If it fails, the property does not exist.
     db.Properties(PropName) = PropVal
   
  ExitLine:
     db.Close
     Set db = Nothing
     Set prp = Nothing
     Exit Sub
   
  ErrorHandler:
     If Err.Number = PROPERTY_NOT_FOUND Then
        ' Create the new property.
        Set prp = db.CreateProperty(PropName, PropType, PropVal)
        db.Properties.Append prp
        Resume Next
     Else
        Resume ExitLine
     End If
   
  End Sub

From:

http://wiki.lessthandot.com/index.php/Setting_Start-Up_Options_Using_VBA

http://lessthandot.com

 

[sudakov]

Remou,
it works!
Thank you very much.

sudakov