How to run a Dos command through vb and pass parameters to it ?

[cyberdyne]

Hi all,

I wanna know how do i run a dos command through my vb code and want to pass parameters to it.

I want to run the command by giving a button and when user clicks it the command runs with parameter.

Also I want to popup a message when command procedure is over.

How do i achive this ?

Please help.

Thanks

I can be contacted at apoo1972@rediffmail.com

 

[sunaj]

Hi Cyberdyne

Calling a DOS program with command is easy, you can use the shell command : shell("notepad c:\test.txt",vbNormalFocus).

If you what the vb program to check when the shell is finished, you'll have to use the API. I've tried several versions where the vb program are allowed to run while the shell is still running, but none of them worked very well.
The code pasted below waits for the shell to finish before returning to the vb program, which seems to be the wisest thing to do...

You can use the code like:
Private Sub Command1_Click()
Dim retval As Long
retval = ExecCmd("notepad.exe&quot
MsgBox "Process Finished, Exit Code " & retval
End Sub

good luck,
Sunaj
-----------------------------------------------------------
'Put this code in a module
'Downloaded from

http://support.microsoft.com/support/kb/articles/Q129/7/96.ASP

Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type

Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessID As Long
dwThreadID As Long
End Type

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
hHandle As Long, ByVal dwMilliseconds As Long) As Long

Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
lpApplicationName As String, ByVal lpCommandLine As String, ByVal _
lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As String, _
lpStartupInfo As STARTUPINFO, lpProcessInformation As _
PROCESS_INFORMATION) As Long

Private Declare Function CloseHandle Lib "kernel32" _
(ByVal hObject As Long) As Long

Private Declare Function GetExitCodeProcess Lib "kernel32" _
(ByVal hProcess As Long, lpExitCode As Long) As Long

Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const INFINITE = -1&

Public Function ExecCmd(cmdline$)
Dim proc As PROCESS_INFORMATION
Dim start As STARTUPINFO
Dim ret As Long

' Initialize the STARTUPINFO structure:
start.cb = Len(start)

' Start the shelled application:
ret& = CreateProcessA(vbNullString, cmdline$, 0&, 0&, 1&, _
NORMAL_PRIORITY_CLASS, 0&, vbNullString, start, proc)

' Wait for the shelled application to finish:
ret& = WaitForSingleObject(proc.hProcess, INFINITE)
Call GetExitCodeProcess(proc.hProcess, ret&)
Call CloseHandle(proc.hThread)
Call CloseHandle(proc.hProcess)
ExecCmd = ret&
End Function

 

[cyberdyne]

Thank you Sunaj for your helpfull reply
I will try it on and will let you know.

Apoorva