How to Insert File into Word Header / Footer from Access 2

[Accel45]

I am using the code below to create a Document and it works fine.
I would like to be able to create a Header and a Footer using two different files that are inserted into the Header and Footer of the document that is created.

Explanation:
When the new document is created I want File “LetterHead_Top.doc” to be inserted into the Header of the new document.
When the new document is created I want File “LetterHead_Bottom.doc” to be inserted into the Footer of the new document.

Initially, I created MailMerge documents that included the Header and Footer with links to LetterHead_Top and LetterHead_Bottom. However the Links did not update appropriately and the prospect of having to manually update links for nearly 100 letters at some point in the future did not seem like a good idea.

Can anyone help me modify this code to accomplish inserting the above files into the Header and Footer of the newly created document.

Private Sub Command27_Click()
Me.txtDBLocation = DLookup("[DBLocation]", "tblDBLocation", "[DBID] = 1")

Dim objWord As Word.Document
Set objWord = GetObject([txtOpenLocation], "Word.Document")
objWord.Application.Visible = True
objWord.MailMerge.OpenDataSource _
Name:=[txtDBLocation], _
LinkToSource:=True, _
Connection:="TABLE tblForMerge", _
SQLStatement:="SELECT * FROM [tblForMerge]"
objWord.MailMerge.Execute
objWord.Save
objWord.Close SaveChanges:=-1 '-1 = wdSaveChanges

Set objWord = Nothing
End Sub

 

[fumei]

Command27, that is a very informative name.

Assumptions:

1. The header and footer are going into Section 1.
2. There is only Primary active for the header/footer - that is, you do not have DifferentFirstPage, or DifferentOddEven

objWord.Sections(1).Headers(wdHeaderFooterPrimary).Range _
     .InsertFile FileName:="[i]full path and filename[/i]"
objWord.Sections(1).Footers(wdHeaderFooterPrimary).Range _
     .InsertFile FileName:="[i]full path and filename[/i]"

NOTE! Inserting as a file will add a hard carriage return at the end of the file contents.

You may want to consider using Autotext instead, OR using INCLUDETEXT pointing to a bookmark into the files.


Gerry
My paintings and sculpture

 

[PHV]

...
objWord.Sections(1).Headers(1).Range.InsertFile "LetterHead_Top.doc"
objWord.Sections(1).Footers(1).Range.InsertFile "LetterHead_Bottom.doc"
objWord.MailMerge.Execute
...


Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ181-2886

 

[Accel45]

Thank you Gerry,
That worked fine.
I will do some testing with Autotext and INCLUDETEXT.

Thank you for your help.

accel45