how to dynamically assign unique id's to buttons 1

[BluesmanUK]

Hi there, I wonder if anyone can answer a question thats been bugging me for a while. All i want to do is create a bunch of buttons, each passing a unique id to a function when clicked. Something like this:

function createButtons() {

for (var i=0; i<buttonArray.length; i++) {
_root.attachMovie("button_mc", "button"+i, i);

// some code to position the buttons
_root["button"+i]._x = 0;
_root["button"+i]._y = (_root["button"+i]._height)*i;


_root["button"+i].onRelease = function() {
// here is where i get a bit confused
trace("button " + i + " was clicked");
}
// this doesnt work either
// _root["button"+i].onRelease = doClick(i);

}

}

im sure theres a really easy answer, Im probably not following best practice for actionscript coding , so any advice would be most welcome!
cheers,
James

 

[kennethkawamoto]

Try something like:

function createButtons() {
	for (var i = 0; i<buttonArray.length; i++) {
		_root.attachMovie("button_mc", "button"+i, i);
		// some code to position the buttons
		_root["button"+i]._x = 0;
		_root["button"+i]._y = (_root["button"+i]._height)*i;
		[b]_root["button"+i]["id"] = i;[/b]
		_root["button"+i].onRelease = function() {
			//  here is where i get a bit confused
			[b]trace(this._name);[/b]
			trace("button "+[b]this.id[/b]+" was clicked");
		};
	}
}

Kenneth Kawamoto

http://www.materiaprima.co.uk

 

[oldnewbie]

_root["button"+i]["id"] = i;

Think that should be...

_root["button"+i].id = i;

Regards. Web Hosting - Web Design
03/13/05 -> OLDNEWBIE VS FLASHKIT

 

[kennethkawamoto]

_root["button"+i]["id"] = i;

Think that should be...

_root["button"+i].id = i;

Not really.

In this particular case, these two are interchangeable. But if you do Object.Property instead of Object[Property] to create a property dynamically in a non-dynamic Class definition you'll run into a trouble.

For example, this Class creates a dynamic property with dot operator:

class Test{
	function Test(){
		this.aProperty = "boo";
		trace(this.aProperty);
	}
}

[tt]
// Output
**Error** Test.as: Line 3: There is no property with the name 'aProperty'.
this.aProperty = "boo";
[/tt]
But with "[]" (Array Access Operator):

class Test{
	function Test(){
		this["aProperty"] = "boo";
		trace(this["aProperty"]);
	}
}

[tt]
// Output
boo
[/tt]
So they are almost the same but in a way "[]" is more powerful because of the above.

Kenneth Kawamoto

http://www.materiaprima.co.uk

 

[BluesmanUK]

cheers ken that worked a treat