How pass a variable inside a function to other function?

[Gti]

Public Sub ScanFonteFicheiro(Ficheiro As String, DirDestino As String)

Dim fichsaida As String

ConstroiNomeSaida(Ficheiro, DirDestino)

Exit Sub
End Sub

---------------

Public Sub ConstroiNomeSaida(Ficheiro As String, DisDestino As String)

Dim NomeFichTmp, NomeFichHtm, DirHtm As String
Dim TotalChar, TiraExtensao As Integer

TotalChar = Len(Ficheiro)
TiraExtensao = TotalChar - 3
NomeFichTmp = Left(Ficheiro, TiraExtensao)
NomeFichHtm = NomeFichTmp & "htm"
DirHtm = DisDestino & "\" & NomeFichHtm

Exit Sub
End Sub

---------------------------------------------------------

What i want to pass is the DirHtm variable for the first function... How can i do this?

 

[madlarry]

Change your ConstroiNomeSaida procedure to be a function (then you can return the value you require)


Public Sub ScanFonteFicheiro(Ficheiro As String, DirDestino As String)

Dim fichsaida As String

Dim strReturn As String

strReturn = ConstroiNomeSaida(Ficheiro, DirDestino)

Exit Sub
End Sub

---------------

Public Function ConstroiNomeSaida(Ficheiro As String, DisDestino As String) as String

Dim NomeFichTmp, NomeFichHtm, DirHtm As String
Dim TotalChar, TiraExtensao As Integer

TotalChar = Len(Ficheiro)
TiraExtensao = TotalChar - 3
NomeFichTmp = Left(Ficheiro, TiraExtensao)
NomeFichHtm = NomeFichTmp & "htm"
DirHtm = DisDestino & "\" & NomeFichHtm

ConstroiNomeSaida = DirHtm

Exit Function
End Function

Cheers

Madlarry

 

[bluenote]

This is just the first thing that came to me:

DirHtm = DisDestino & "\" & NomeFichHtm 'under this line try
Call ScanFonteFicheiro(NomeFichHtm , DirHtm) 'again! :o)

bluenote@uyuyuy.com
(excuse my english)

 

[Gti]

It gives me an error of "Expected function or variable"...

What happened? I have done everything like you said!

 

[madlarry]

Which line gives you the error???

Also, the following line:

Dim NomeFichTmp, NomeFichHtm, DirHtm As String

Will only delare DirHtm as a string, the other two variables NomeFichTmp and NomeFichHtm will be variants. You may want to declare them on separate lines:

Dim NomeFichTmp as String
Dim NomeFichHtm as String
Dim DirHtm as String

Cheers,

Madlarry

 

[bluenote]

I agree with Madlarry 'bout declarations.

Public Sub ScanFonteFicheiro(Ficheiro As String, DirDestino As String)

 Dim fichsaida As String

 fichsaida = ConstroiNomeSaida(Ficheiro, DirDestino)

End Sub

---------------

Public Function ConstroiNomeSaida(Ficheiro As String, DisDestino As String) as string

 Dim NomeFichTmp as string
 dim NomeFichHtm as string
 dim DirHtm      As String
 Dim TotalChar   as integer
 dim TiraExtensao As Integer

 TotalChar = Len(Ficheiro)
 TiraExtensao = TotalChar - 3
 NomeFichTmp = Left(Ficheiro, TiraExtensao)
 NomeFichHtm = NomeFichTmp & "htm"
 DirHtm = DisDestino & "\" & NomeFichHtm

 ConstroiNomeSaida = DirHtm

End Function

---------------------------------------------------------

) bluenote@uyuyuy.com
(excuse my english)