How can you WAIT after a CALL stmt ?? 1

Dylan · Aug 17, 1999

I have a call stmt in a pgm that runs a batch file. I would like the pgm to pause until the CALL to this batch file completes due to the fact that the next stmt uses the file created by the batch pgm in an ImportExternalData stmt. Without some kind of pause the program trys to do the import before the fle is created. 
 
Any help would be appreciated. 
 
Thanks

MikeLacey · Aug 18, 1999

you programming in VB? 
-mike 
--- 
Mike_Lacey@Cargill.Com

Dylan · Aug 18, 1999

Yes, This code would be in an Event in my Access 97 db.

robherc · Sep 7, 1999

hmmm....in QB 4.5 you can use: 
PAUSE x 
(x=numb of secs to pause) to make the program stop for a little while; not sure on a VB counterpart, but you might have a little success if you tried that way. 
 
 
-Robherc 
robherc@netzero.net

engcomp · Oct 2, 1999

I would use the following steps: 
 
1. Make sure any old version of the file is deleted. 
 
2. Set an error trap that pauses briefly. 
 
3. Try to open the file from within a while-loop. 
 
4. Exit the while-loop when successfully opened. 
 
This overcomes the problem with a fixed-length pause, which may be too short (the program fails) or too long (the user gets fed up).

MikeLacey · Oct 4, 1999

Here's a VB5 module that will do the trick. I'm not really an Access person - sorry. 
 
The ShellAndWaitFor function is the one to call. 
 
Regards 
 
Mike 
 
==snip== 
Attribute VB_Name = "ProcessControl" 
Option Explicit 
 
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long 
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long 
Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long 
Private Declare Function CreateProcessBynum Lib "kernel32" Alias "CreateProcessA" (ByVal lpApplicationName As String, ByVal lpCommandLine As String, ByVal lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, lpEnvironment As Any, ByVal lpCurrentDirectory As String, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long 
Private Declare Function WaitForInputIdle Lib "user32" (ByVal hProcess As Long, ByVal dwMilliseconds As Long) As Long 
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long 
 
 
Private Const SYNCHRONIZE = &H100000 
Private Const INFINITE = &HFFFF ' Infinite timeout 
Private Const DEBUG_PROCESS = &H1 
Private Const DEBUG_ONLY_THIS_PROCESS = &H2 
Private Const CREATE_SUSPENDED = &H4 
Private Const DETACHED_PROCESS = &H8 
Private Const CREATE_NEW_CONSOLE = &H10 
Private Const NORMAL_PRIORITY_CLASS = &H20 
Private Const IDLE_PRIORITY_CLASS = &H40 
Private Const HIGH_PRIORITY_CLASS = &H80 
Private Const REALTIME_PRIORITY_CLASS = &H100 
Private Const CREATE_NEW_PROCESS_GROUP = &H200 
Private Const CREATE_NO_WINDOW = &H8000000 
Private Const WAIT_FAILED = -1& 
Private Const WAIT_OBJECT_0 = 0 
Private Const WAIT_ABANDONED = &H80& 
Private Const WAIT_ABANDONED_0 = &H80& 
Private Const WAIT_TIMEOUT = &H102& 
 
Private Type PROCESS_INFORMATION 
hProcess As Long 
hThread As Long 
dwProcessId As Long 
dwThreadId As Long 
End Type 
 
Private Type STARTUPINFO 
cb As Long 
lpReserved As String 
lpDesktop As String 
lpTitle As String 
dwX As Long 
dwY As Long 
dwXSize As Long 
dwYSize As Long 
dwXCountChars As Long 
dwYCountChars As Long 
dwFillAttribute As Long 
dwFlags As Long 
wShowWindow As Integer 
cbReserved2 As Integer 
lpReserved2 As Long 
hStdInput As Long 
hStdOutput As Long 
hStdError As Long 
End Type 
 
Public Function ShellAndWaitFor(Command As String) As Boolean 
 
Dim res As Long 
Dim RetVal As Boolean 
Dim sinfo As STARTUPINFO 
Dim pinfo As PROCESS_INFORMATION 
 
sinfo.cb = Len(sinfo) 
sinfo.lpReserved = vbNullString 
sinfo.lpDesktop = vbNullString 
sinfo.lpTitle = vbNullString 
sinfo.dwFlags = 0 
 
res = CreateProcessBynum(Command, vbNullString, 0, 0, True, NORMAL_PRIORITY_CLASS, _ 
ByVal 0&, vbNullString, sinfo, pinfo) 
 
If (res = 1) Then 
WaitFor pinfo 
RetVal = True 
Else 
RetVal = False 
End If 
 
ShellAndWaitFor = RetVal 
 
End Function 
 
Private Sub WaitFor(pinfo As PROCESS_INFORMATION) 
Dim res As Long 
 
' Let the process initialize 
Call WaitForInputIdle(pinfo.hProcess, INFINITE) 
' Don't need the thread handle - so lose that straight off 
Call CloseHandle(pinfo.hThread) 
Do 
If WaitForSingleObject(pinfo.hProcess, 0) <> WAIT_TIMEOUT Then Exit Do 
DoEvents 
Loop While True 
 
' Kill the last handle of the process 
Call CloseHandle(pinfo.hProcess) 
 
' And relax 
 
End Sub 
==snip== 
 
Mike Lacey <a href=mailto:Mike_Lacey@Cargill.Com>Mike_Lacey@Cargill.Com</a> <a href= > </a>

Dylan · Oct 4, 1999

Yes iam using VB within Access 97

robherc · Oct 4, 1999

Hmmm.....have the batch program delete/create a diff file after it's done with the first & use a DO WHILE loop to keep testing for the presence/absence of the other file in your VB app before proceeding...that whould take a few less lines of code. -Robherc <a href=mailto:robherc@netzero.net>robherc@netzero.net</a> <a href= > </a> *nix installation & program collector/reseller. Contact me if you think you've got one that I don't

MikeLacey · Oct 5, 1999

Rob, 
 
I can understand why you made the comment - looks like a sledge hammer to crack a nut. 
 
But there are a couple of advantages to doing it this way: 
 
    Solution is generic. It will work in any application you write and be easy to use. 
 
    The code is in a single module. This makes it easy to include and to use. 
 
    It doesn't rely on the ability to create a file. 
 
Remember - you have to be LIPpy - that's Lazy, Impatient and Proud 
 
Lazy            Because you never want to write anything twice. 
Impatient    Because it has to run just that bit quicker. 
Proud        Because you don't want someone to read your code - in a years time - and say "which (*&% wrote this?" 
 
<grin> 
 
Mike Mike Lacey <a href=mailto:Mike_Lacey@Cargill.Com>Mike_Lacey@Cargill.Com</a> <a href= > </a>

Alt255 · Oct 5, 1999

Mike's right. Write once and forget about it. It's hard to remember but becomes hard to forget in a loop without a DoEvents.

Guest_imported · Apr 6, 2002

If you take people's code, you could at least give them some credit for writing it, and not say it is you that wrote it...

This is a post on how to launch an application and wait for it to execute before proceding on to the next line of code...

http://planetsourcecode.com/vb/scripts/ShowCode.asp?txtCodeId=3716&lngWId=1

Maybe it's just me, but your code looks exactly like the one on the above link, and that one was submitted 9 days before yours. So next time give the guy some credit and put a link to the original source....

Tek-Tips is the largest IT community on the Internet today!

Members share and learn making Tek-Tips Forums the best source of peer-reviewed technical information on the Internet!

How can you WAIT after a CALL stmt ?? 1

Dylan

MIS

MikeLacey

MIS

Dylan

MIS

robherc

Programmer

engcomp

Programmer

MikeLacey

MIS

Dylan

MIS

robherc

Programmer

MikeLacey

MIS

Alt255

Programmer

Guest_imported

New member

Similar threads

Part and Inventory Search

Sponsor