HI EXPORTS! PLEASE HELP ME OPEN A FILE 2

[DIVINEDAR0956]

Hi EXPERTS,

I have the following code below that works very good. It gives me the correct message as far as the file that I pick to open but I can seem to get it just to "OPEN". I want it to open the file for editing. I have color coded the parts that I think is right for opening the file but I may have it in the wrong place. PLEASE HELP!. As you can tell I retrieved this tek-tips but just have a couple of questions.

I have added a colorface where I have questions. I hope whomever understands that I want the file to open in excel and able to edit the file.

Also where would I include the process of updating the links in excel to access.

Thank you and your help is most appreciated.
------------------------------------------------------------
Option Compare Database
Option Explicit
'***************** Code Start **************
'This code was originally written by Ken Getz.
'It is not to be altered or distributed,
'except as part of an application.
'You are free to use it in any application,
'provided the copyright notice is left unchanged.
'
' Code courtesy of:
' Microsoft Access 95 How-To
' Ken Getz and Paul Litwin
' Waite Group Press, 1996

Type tagOPENFILENAME
lStructSize As Long
hwndOwner As Long
hInstance As Long
strFilter As String
strCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
strFile As String
nMaxFile As Long
strFileTitle As String
nMaxFileTitle As Long
strInitialDir As String
strTitle As String
flags As Long
nFileOffset As Integer
nFileExtension As Integer
strDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type

Declare Function aht_apiGetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (OFN As tagOPENFILENAME) As Boolean

Declare Function aht_apiGetSaveFileName Lib "comdlg32.dll" _
Alias "GetSaveFileNameA" (OFN As tagOPENFILENAME) As Boolean
Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long

Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
' You won't use these.
'Global Const ahtOFN_ENABLEHOOK = &H20
'Global Const ahtOFN_ENABLETEMPLATE = &H40
'Global Const ahtOFN_ENABLETEMPLATEHANDLE = &H80
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
' New for Windows 95
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000

Function TestIt()
' Testing Subroutine that left in to demonstrate how to call opendialog. Not used in program.
Dim strFilter As String
Dim lngFlags As Long
Dim xlWB As Object
Dim xlApp As Object
Set xlApp = CreateObject("Excel.Application&quot
strFilter = ahtAddFilterItem(strFilter, "Excel Files (*.xls)", "*.XLS&quot
'strFilter = ahtAddFilterItem(strFilter, "dBASE Files (*.dbf)", "*.DBF&quot
'strFilter = ahtAddFilterItem(strFilter, "Text Files (*.txt)", "*.TXT&quot
strFilter = ahtAddFilterItem(strFilter, "All Files (*.*)", "*.*&quot
MsgBox "You selected: " & ahtCommonFileOpenSave(InitialDir:="C:\Cost\", _
Filter:=strFilter, FilterIndex:=3, flags:=lngFlags, _
DialogTitle:="Hello! Open Me!&quot
' Since you passed in a variable for lngFlags,
' the function places the output flags value in the variable.
Debug.Print Hex(lngFlags)
Set xlWB = xlApp.Workbooks.Open ?????, False)
The question marks means what variable would I enter there for it to recognize the file that I pick to open
End Function

Function GetOpenFile(Optional varDirectory As Variant, _
Optional varTitleForDialog As Variant) As Variant
' Here's an example that gets an Access database name.
Dim strFilter As String
Dim lngFlags As Long
Dim varFileName As Variant
' Specify that the chosen file must already exist,
' don't change directories when you're done
' Also, don't bother displaying
' the read-only box. It'll only confuse people.
lngFlags = ahtOFN_FILEMUSTEXIST Or _
ahtOFN_HIDEREADONLY Or ahtOFN_NOCHANGEDIR
If IsMissing(varDirectory) Then
varDirectory = ""
End If
If IsMissing(varTitleForDialog) Then
varTitleForDialog = ""
End If

' Define the filter string and allocate space in the "c"
' string Duplicate this line with changes as necessary for
' more file templates.
strFilter = ahtAddFilterItem(strFilter, _
"Access (*.mdb)", "*.MDB;*.MDA&quot
' Now actually call to get the file name.
varFileName = ahtCommonFileOpenSave( _
OpenFile:=True, _
InitialDir:=varDirectory, _
Filter:=strFilter, _
flags:=lngFlags, _
DialogTitle:=varTitleForDialog)
If Not IsNull(varFileName) Then
varFileName = TrimNull(varFileName)
End If
GetOpenFile = varFileName
End Function

Function ahtCommonFileOpenSave( _
Optional ByRef flags As Variant, _
Optional ByVal InitialDir As Variant, _
Optional ByVal Filter As Variant, _
Optional ByVal FilterIndex As Variant, _
Optional ByVal DefaultExt As Variant, _
Optional ByVal FileName As Variant, _
Optional ByVal DialogTitle As Variant, _
Optional ByVal hwnd As Variant, _
Optional ByVal OpenFile As Variant) As Variant
' This is the entry point you'll use to call the common
' file open/save dialog. The parameters are listed
' below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter
' set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one.
' Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename
Dim OFN As tagOPENFILENAME
Dim strFileName As String
Dim strFileTitle As String
Dim fResult As Boolean
' Give the dialog a caption title.
If IsMissing(InitialDir) Then InitialDir = CurDir
If IsMissing(Filter) Then Filter = ""
If IsMissing(FilterIndex) Then FilterIndex = 1
If IsMissing(flags) Then flags = 0&
If IsMissing(DefaultExt) Then DefaultExt = ""
If IsMissing(FileName) Then FileName = ""
If IsMissing(DialogTitle) Then DialogTitle = ""
If IsMissing(hwnd) Then hwnd = Application.hWndAccessApp
If IsMissing(OpenFile) Then OpenFile = True
' Allocate string space for the returned strings.
strFileName = Left(FileName & String(256, 0), 256)
strFileTitle = String(256, 0)
' Set up the data structure before you call the function
With OFN
.lStructSize = Len(OFN)
.hwndOwner = hwnd
.strFilter = Filter
.nFilterIndex = FilterIndex
.strFile = strFileName
.nMaxFile = Len(strFileName)
.strFileTitle = strFileTitle
.nMaxFileTitle = Len(strFileTitle)
.strTitle = DialogTitle
.flags = flags
.strDefExt = DefaultExt
.strInitialDir = InitialDir
' Didn't think most people would want to deal with
' these options.
.hInstance = 0
'.strCustomFilter = ""
'.nMaxCustFilter = 0
.lpfnHook = 0
'New for NT 4.0
.strCustomFilter = String(255, 0)
.nMaxCustFilter = 255
End With
' This will pass the desired data structure to the
' Windows API, which will in turn it uses to display
' the Open/Save As Dialog.
If OpenFile Then
fResult = aht_apiGetOpenFileName(OFN)
Else
fResult = aht_apiGetSaveFileName(OFN)
End If

' The function call filled in the strFileTitle member
' of the structure. You'll have to write special code
' to retrieve that if you're interested.
If fResult Then
' You might care to check the Flags member of the
' structure to get information about the chosen file.
' In this example, if you bothered to pass in a
' value for Flags, we'll fill it in with the outgoing
' Flags value.
If Not IsMissing(flags) Then flags = OFN.flags
ahtCommonFileOpenSave = TrimNull(OFN.strFile)
Else
ahtCommonFileOpenSave = vbNullString
End If
End Function

Function ahtAddFilterItem(strFilter As String, _
strDescription As String, Optional varItem As Variant) As String
' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases&quot, a null character, the skeleton
' (like "*.mdb;*.mda&quot and a final null character.

If IsMissing(varItem) Then varItem = "*.*"
ahtAddFilterItem = strFilter & _
strDescription & vbNullChar & _
varItem & vbNullChar
End Function

Private Function TrimNull(ByVal strItem As String) As String
Dim intPos As Integer
intPos = InStr(strItem, vbNullChar)
If intPos > 0 Then
TrimNull = Left(strItem, intPos - 1)
Else
TrimNull = strItem
End If
End Function
'************** Code End *****************


Public Sub CallOpenFile()
TestIt
End Sub

 

[VBslammer]

I noticed from the comments in your code that you've adapted some of Getz's code from an Access 95 book. There is a newer way to use automation that is more intuitive and works better:

Public Function OpenExcel()
On Error GoTo ErrHandler

  Dim xl As Excel.Application
  Dim wb As Excel.Workbook
  Dim sht As Excel.Worksheet
  
  Set xl = New Excel.Application
  Set wb = xl.Workbooks.Open("C:\Test.xls")
  Set sht = wb.Sheets("Sheet1")
  
  With sht
    .Cells(1, 1) = "Hello"
    .Cells(1, 2) = "World"
  End With
  
  sht.PrintOut
  
  wb.Close False
  
  xl.Quit
  
ExitHere:
  On Error Resume Next
  Set sht = Nothing
  Set wb = Nothing
  Set xl = Nothing
  Exit Function
ErrHandler:
  MsgBox "Error: " & Err & " - " & Err.Description
  Resume ExitHere
End Function

---------------------------------------------------------

Make sure to reference the Excel library in your project.

VBSlammer

 

[DIVINEDAR0956]

Thanks for the quick response. But that's not exactly what I'm looking for. I would like for the part where you have written "C:\Test.xls" to be a variable for the file that's selected when the directory opens. When the directory opens, you choose a file, and then that file opens in it's associated application. When I tried to run what was given to me
Dim xl As Excel.Application
Dim wb As Excel.Workbook
Dim sht As Excel.Worksheet

Set xl = New Excel.Application
Set wb = xl.Workbooks.Open("C:\Test.xls&quot
Set sht = wb.Sheets("Sheet1&quot
It initiated errors of "user define type not defined". I know to Dim and Set is to define but this one didn't work. Am I doing something wrong.

Thank you.

 

[VBslammer]

Did you set a reference to the 'Microsoft Excel X.0 Object Library?'

I'm Using Excel 2000 (Excel 9.0)

VBSlammer

 

[DIVINEDAR0956]

Thank you VBSlammer. I go through my references and don't find one for Microsoft Excel of any kind. Is there somewhere where I can download the references for Excel. Maybe this might help.

 

[VBslammer]

I assumed you had Microsoft Office Developer or at least Microsoft Office Professional on your box since this is an Access forum. If you only have Access you're going to have to get a full Office suite.

VBSlammer

 

[DIVINEDAR0956]

VBSlammer thank you for responding to me. I found it and included it in my selected references. But the file still doesn't open it only gives me a message. So what am I doing wrong. Thank you.

 

[VBslammer]

Is it the same error message "User-defined type not defined?"

VBSlammer

 

[DIVINEDAR0956]

Thank you for your help VBSlammer. Okay. I found this so please hlep work with this. The following says the file is open but there is no file open.

Private Sub Command1_Click()


Dim xl As Excel.Application
Dim wb As Excel.WORKBOOK
Dim sht As Excel.Worksheet

Set xl = Excel.Application
Set wb = xl.Workbooks.Open("C:\Cost\P0026.XLS&quot
Set sht = wb.Sheets("Sheet1&quot

End Sub

Can we make the above open the directory "C:\Cost\" and pick a file within that directory and open up in excel.

This gives me a message that the file is already open but reality the file is not open. Once I see that this can be accomplish I can probably figure out the update of the links in each file because all the files will be same just with different input information.

PLEASE HELP!!!!

THANK YOU.

DARLENE
dsippio@comtechsystems.com

 

[VBslammer]

With this automation code you won't actually see Excel, and that's usually what we're after unless the user needs to interact with the application before closing it.

If you want to browse for the file then you can go ahead and use its built-in 'Open' Dialog to search for an input file:

Set xl = Excel.Application
' If you want Excel to appear, use next line:
' xl.Visible = True

xl.Dialogs(xlDialogOpen).Show "C:\Cost"
Set wb = xl.ActiveWorkbook
Set sht = wb.Sheets(1)

VBSlammer

 

[DIVINEDAR0956]

VBSlammer you are the greatest I owe you a star. This is the closest I came in a month of trying to do this. I'm taking it home this weekend and work on it and I pray that it is okay. The only thing that I see is that when it opens the file it also saves the procedure in that file. I'll let you know more Monday when I return to work. THANK YOU, THANK YOU, THANK YOU.