Help Disabling Inactive User Account (VBScript)

[Kuddz]

Hi there,

Badly need help on this script, ive been searching for this kind of script that can automatically disable inactive user account that doesnt logon in 90 days. My platform OS is windows 2008 server.

Also that can be added in task schedule so that i can run the script every month or in a certain time.

Thanks

Regards

 

[Kuddz]

I forgot to include this ..

Will query about the inactive user with a range of 30 - 90 days .. then if it finds a user inactive for that day.. automatically it will be disable.

 

[Azren]

Are these users in a DOmain ? Or local server groups ?

 

[Kuddz]

These are domain user.

 

[Kuddz]

Can anyone please help me?

 

[PHV]

Can anyone please help me?
What have YOU tried so far and where in YOUR code are you stuck ?

Hope This Helps, PH.
FAQ219-2884
FAQ181-2886

 

[Kuddz]

Im not actually developing a code .. ive just what i can find from the internet so far this is the code that ive tried

===============

' VBScript program to disable all user accounts that have not
' logged into the domain in the last 90 days.

Option Explicit

Dim adoCommand, adoConnection, strBase, strFilter, strAttributes
Dim objRootDSE, strDNSDomain, strQuery, adoRecordset
Dim dtmDate, intDays, strUserDN, objUser
Dim lngSeconds, str64Bit
Dim objShell, lngBiasKey, lngBias, k

' Specify number of days. Any users that have not logged into the
' domain in this many days will be automatically disabled.
intDays = 90

' Determine the date this many days in the past (in local time zone).
dtmDate = DateAdd("d", -intDays, Now())

' Obtain local Time Zone bias from machine registry.
Set objShell = CreateObject("Wscript.Shell")
lngBiasKey = objShell.RegRead("HKLM\System\CurrentControlSet\Control\" _
& "TimeZoneInformation\ActiveTimeBias")
If (UCase(TypeName(lngBiasKey)) = "LONG") Then
lngBias = lngBiasKey
ElseIf (UCase(TypeName(lngBiasKey)) = "VARIANT()") Then
lngBias = 0
For k = 0 To UBound(lngBiasKey)
lngBias = lngBias + (lngBiasKey(k) * 256^k)
Next
End If

' Convert the datetime value to UTC.
dtmDate = DateAdd("n", lngBias, dtmDate)

' Find number of seconds since 1/1/1601 for this date.
lngSeconds = DateDiff("s", #1/1/1601#, dtmDate)

' Convert the number of seconds to a string.
' and convert to 100-nanosecond intervals.
str64Bit = CStr(lngSeconds) & "0000000"

' Setup ADO objects.
Set adoCommand = CreateObject("ADODB.Command")
Set adoConnection = CreateObject("ADODB.Connection")
adoConnection.Provider = "ADsDSOObject"
adoConnection.Open "Active Directory Provider"
adoCommand.ActiveConnection = adoConnection

' Search entire Active Directory domain.
Set objRootDSE = GetObject("LDAP://RootDSE")
strDNSDomain = objRootDSE.Get("defaultNamingContext")
strBase = "<LDAP://" & strDNSDomain & ">"

' Filter on user objects where lastLogonTimeStamp is
' older than the date specified, but is not zero.
strFilter = "(&(objectCategory=person)(objectClass=user)" _
& "(lastLogonTimeStamp<=" & str64Bit & ")(!lastLogonTimeStamp=0))"

' Comma delimited list of attribute values to retrieve.
strAttributes = "distinguishedName"

' Construct the LDAP syntax query.
strQuery = strBase & ";" & strFilter & ";" & strAttributes & ";subtree"
adoCommand.CommandText = strQuery
adoCommand.Properties("Page Size") = 100
adoCommand.Properties("Timeout") = 30
adoCommand.Properties("Cache Results") = False

' Run the query.
Set adoRecordset = adoCommand.Execute

' Enumerate the resulting recordset.
Do Until adoRecordset.EOF
' Retrieve values.
strUserDN = adoRecordset.Fields("distinguishedName").Value
' Bind to the user object.
Set objUser = GetObject("LDAP://" & strUserDN)
' Disable the user account.
objUser.AccountDisabled = True
objUser.SetInfo
' Move to the next record in the recordset.
adoRecordset.MoveNext
Loop

' Clean up.
adoRecordset.Close
adoConnection.Close

Function Integer8Date(ByVal objDate, ByVal lngBias)
' Function to convert Integer8 (64-bit) value to a date, adjusted for
' local time zone bias.
Dim lngAdjust, lngDate, lngHigh, lngLow
lngAdjust = lngBias
lngHigh = objDate.HighPart
lngLow = objDate.LowPart
' Account for error in IADsLargeInteger property methods.
If (lngLow < 0) Then
lngHigh = lngHigh + 1
End If
If (lngHigh = 0) And (lngLow = 0) Then
lngAdjust = 0
End If
lngDate = #1/1/1601# + (((lngHigh * (2 ^ 32)) _
+ lngLow) / 600000000 - lngAdjust) / 1440
' Trap error if lngDate is ridiculously huge.
On Error Resume Next
Integer8Date = CDate(lngDate)
If (Err.Number <> 0) Then
On Error GoTo 0
Integer8Date = #1/1/1601#
End If
On Error GoTo 0

End Function
==================

Heres the error

Line : 41
Char : 2
Error: A refferal was returnend from the server
Code : 8007202B
Source : (null)

Thanks