Function Error - A date is required here

[hwwagen]

The following code displays the error message "A date is required here" when running at the marked location. This is a date field and I don't readily see anything wrong with the code. I would appreciate another set of eyes to examine it or someone with more experience to tell me what I've done wrong.

// fMaximumDate
//
//  Finds the latest finish and earliest start dates for each operation.
//
//  The following four conditions per work center are possible:
//
//      1.  No operation - default 
//              - Set date to date(0), 30/12/1899 
//              - print "N/A"
//      2.  Operation without dates 
//              - Set date to date(1), 31/12/1899 
//              - print "Required"
//      3.  Operation with dates
//              - Determine earliest start date
//              - Determine latest finish date
//
//  When printing the date fields do the following:
//
//      1.  Start & Finish dates = date(0)
//              - print "N/A"
//      2.  Start Date & Finish Dates = date(1)
//              - print "Required"
//      3.  Start Date exists and Finish Date = date(1)
//              - print "S MM/DD"
//      4.  Finish Date exists
//              - print Finish Date
//

WhilePrintingRecords;
stringvar array GroupNameArray;
dateVar array GroupDateStartArray;
dateVar array GroupDateFinishArray;

stringvar ModifiedWorkCenter;
local numbervar i;

// Prefix Bay work centers with a '4' for sorting
if Left ({SHOP_ORDER_OPERATION\.WORK_CENTER_NO},3) = "BAY" then
    ModifiedWorkCenter := "4" + {SHOP_ORDER_OPERATION\.WORK_CENTER_NO}
else
    ModifiedWorkCenter := {SHOP_ORDER_OPERATION\.WORK_CENTER_NO};

// Find Corresponding Workcenter

for i := 1 to UBound (GroupNameArray) do
(
    if ModifiedWorkCenter = GroupNameArray[i] then
    (
        if GroupDateFinishArray[i] = Date(0) then
            if isNull({OPERATION_HISTORY\.DATE_APPLIED}) then
                GroupDateFinishArray[i] := Date(1)
            else
****                GroupDateFinishArray[i] := ****{OPERATION_HISTORY\.DATE_APPLIED}
        else
            if GroupDateFinishArray[i] > Date(1) then
                if isNull({OPERATION_HISTORY\.DATE_APPLIED}) then
                    GroupDateFinishArray[i] := Date(1)
                else
                    if {OPERATION_HISTORY\.DATE_APPLIED} > GroupDateFinishArray[i] then
                        GroupDateFinishArray[i] := {OPERATION_HISTORY\.DATE_APPLIED};

        if GroupDateStartArray[i] = Date(0) then
            if isNull({OP_PLAN\.REAL_START}) then
                GroupDateStartArray[i] := Date(1)
            else
                GroupDateStartArray[i] := {OP_PLAN\.REAL_START}
        else
            if not isNull({OP_PLAN\.REAL_START}) then
                GroupDateStartArray[i] := {OP_PLAN\.REAL_START}
            else
                if {OP_PLAN\.REAL_START} < GroupDateStartArray[i] then
                    GroupDateStartArray[i] := {OP_PLAN\.REAL_START};

        exit for;
    )
)

The cursor points to before the {OPERATION_HISTORY\.DATE_APPLIED} field on the line marked with asterisks.

 

[BobSuruncle]

It's possible that your field {OPERATION_HISTORY\.DATE_APPLIED}is a DateTime field.
If you're not concerned about the time part, you could use Date({OPERATION_HISTORY\.DATE_APPLIED}) or change your array to a datetime

Bob Suruncle

 

[hwwagen]

Thank you. That was exactly what the problem was.