FoxTools and the undocumented FoxTouch()

[GriffMG]

I needed to set a file Date / Time stamp back to what it was before I added a barcode to a pdf file.

I opted to use FoxTouch() which is in the FoxTools.fll

This has one niggle, it adopts a 'bias' when you set the time stamp, so in the UK right now
if I used FoxTouch to save the file at 17:48, it would actually set it to 18:48.

I tried to get the bias from the TimeZoneInformation, but could not get it to work at all.
So, I reasoned that I could calculate it from the new file time stamp anyway...

Thus, all you have to do is test to see if the time you got was different to the time you hoped for.
If it is, calculate how far out it is and deduct that from the time you want and then set it again.

FUNCTION MyTouch
	PARAMETERS m.FileName,m.WasFTime
	PRIVATE m.FileName,M.WasFTime, M.NowFDate, M.NowFTime, M.TimeDiff
	** Set the hours format to 24HR
	SET HOURS TO 24
	** Open up the FOXTOOLS - in the same folder as the executable (because the system puts it there if it isn't already)
	SET LIBRARY TO ("foxtools") additive
	** RESET THE TIME AND DATE BACK...
         =FOXTOUCH( m.FileName, YEAR(m.WasFTime),MONTH(m.WasFTime), DAY(m.WasFTime), HOUR(m.WasFTime), MINUTE(m.WasFTime), SEC(m.WasFTime))		
         ** FOXTOUCH INCLUDES A 'BIAS' THAT WILL PUT THE TIME WRONG... SO IF WE WORK OUT HOW FAR OUT IT IS WE CAN RETOUCH AND CORRECT
	m.NowFDATE = FDATE(m.FileName)
	m.NowFTIME = FTIME(m.FileName)
	m.NowFTIME = CTOT(STR(YEAR(m.NowFDATE),4,0)+"-"+alltrim(STR(MONTH(m.NowFDATE),2,0))+"-"+alltrim(STR(Day(m.NowFDATE),2,0))+"T"+m.NowFTIME)
	IF M.NOWFTIME <> M.WASFTIME
	    M.TIMEDIFF = M.NOWFTIME - M.WASFTIME
	    M.WASFTIME = M.WASFTIME - M.TIMEDIFF
	    =FOXTOUCH( m.FileName, YEAR(m.WasFTIME),MONTH(m.WasFTIME), DAY(m.WasFTIME), HOUR(m.WasFTIME), MINUTE(m.WasFTIME), SEC(m.WasFTIME))		
	ENDIF			
    
	RELEASE LIBRARY foxtools
RETURN(.T.)

Regards

Griff
Keep [Smile]ing

There are 10 kinds of people in the world, those who understand binary and those who don't.

 

[Mike Lewis]

I tried to get the bias from the TimeZoneInformation, but could not get it to work at all

Not to detract in any way from your code, Griff, but faq184-3322 shows a way of getting the bias.

Mike



__________________________________
Mike Lewis (Edinburgh, Scotland)

Visual FoxPro articles, tips, training, consultancy

 

[GriffMG]

I know Mike, but I couldn't get that to work at all - just kept getting a blank for the bias.

Maybe it doesn't work in Windows 7 and above?
Or, more likely, I'm too stupid to get it to work!

Regards

Griff
Keep [Smile]ing

There are 10 kinds of people in the world, those who understand binary and those who don't.

 

[Olaf Doschke]

AFAIK file times are UTC and so you can inversely use this to find out your time zone bias to UTC.

Bye, Olaf.

 

[Olaf Doschke]

By the way:

FDATE(m.FileName,1) returns the datetime, so you won't need FTIME() and CTOT(), you already will have a datetime value, type "T".

It's just, that I always prevent CTOT or CTOD conversions, as they depend on too many date settings, even though VFP makes some right guesses, even if you have your MARK or HOURS or anything set differently.

Bye, Olaf.

 

[GriffMG]

Good thinking Olaf

Regards

Griff
Keep [Smile]ing

There are 10 kinds of people in the world, those who understand binary and those who don't.

 

[GriffMG]

FUNCTION MyTouch
	PARAMETERS m.FileName,m.WasFTime
	PRIVATE m.FileName,M.WasFTime, M.NowFDate, M.NowFTime, M.TimeDiff
	** Set the hours format to 24HR
	SET HOURS TO 24
	** Open up the FOXTOOLS - in the same folder as the executable (because the system puts it there if it isn't already)
	SET LIBRARY TO ("foxtools") additive
	
	** RESET THE TIME AND DATE BACK...
         =FOXTOUCH( m.FileName, YEAR(m.WasFTime),MONTH(m.WasFTime), DAY(m.WasFTime), HOUR(m.WasFTime), MINUTE(m.WasFTime), SEC(m.WasFTime))		
         ** FOXTOUCH INCLUDES A 'BIAS' THAT WILL PUT THE TIME WRONG... SO IF WE WORK OUT HOW FAR OUT IT IS WE CAN RETOUCH AND CORRECT
	m.NowFTIME = FDATE(m.FileName,1)
	IF M.NOWFTIME <> M.WASFTIME
	    M.TIMEDIFF = M.NOWFTIME - M.WASFTIME
	    M.WASFTIME = M.WASFTIME - M.TIMEDIFF
	    =FOXTOUCH( m.FileName, YEAR(m.WasFTIME),MONTH(m.WasFTIME), DAY(m.WasFTIME), HOUR(m.WasFTIME), MINUTE(m.WasFTIME), SEC(m.WasFTIME))		
	ENDIF			
    
	RELEASE LIBRARY foxtools
RETURN(.T.)

Regards

Griff
Keep [Smile]ing

There are 10 kinds of people in the world, those who understand binary and those who don't.

 

[Mike Gagnon]

I get a positive Bias with this function:

http://www.news2news.com/vfp/index.php?example=73

And I get a negative value with this function:

clear 
strComputer = "."
objWMIService = GetObject("winmgmts:\\" + strComputer + "\root\cimv2")
colItems = objWMIService.ExecQuery("Select * from Win32_TimeZone")
For Each objItem in colItems
    ? "Description of time zone in hours: " + objItem.Description
    ? "Daylight Name: " + objItem.DaylightName
    ? "Standard Name: " + objItem.StandardName
    ? "Offset in minutes: " +transform(objItem.Bias )
Next

But in either case I get a value (Windows 7)


Mike Gagnon

If you want to get the best response to a question, please check out FAQ184-2483 first.
ReFox XI (www.mcrgsoftware.com)

 

[GriffMG]

Thanks Mike,

I never tried the winmgmts technique and simply couldn't get a result with the other one...
But the method I've adopted seems to work well.

Regards

Griff
Keep [Smile]ing

There are 10 kinds of people in the world, those who understand binary and those who don't.