Font Type

[sdocker]

Is there a way in VFP 9 to check if a selected font is Fixed or Proportional spaced?

 

[Mike Lewis]

Hi Sdocker, and welcome to the forum,

You could try the following code:

lcFont = "Courier New"  && or whatever
IF FONTMETRIC(16, lcFont, 10) = 54
  ? "This is fixed pitch"
ELSE
  ? "It's proportional"
ENDIF

The returned value tells you the font family. 54 is the family for most fixed-pitch fonts.

Mike

__________________________________
Mike Lewis (Edinburgh, Scotland)

Visual FoxPro tips, advice, training, consultancy
Custom software for your business

 

[sdocker]

Thanks Mike,

Exactly what I was looking for.

Sam

 

[alvechurchdata]

I may be showing my age here but 54 is fairly modern. FoxFont is 0 and FixedSys and Terminal are both 48.

In the olden days fixed pitch fonts had their final bit clear and were all even numbers. Fancy fonts were odd.

Geoff Franklin

http://www.alvechurchdata.co.uk

 

[alvechurchdata]

We're close to the end of a Friday afternoon here so a little experiment is tempting ...

Afont(af)
For n = 1 To Alen(af)
  b = Fontmetric(16, af(n), 10)
  If Not Bittest(b, 0)
    ? af(n)
    ?? b
  Endif
Next

Consolas                54
Courier                 48
Courier New             54
Fixedsys                48
FoxFont                  0
Lucida Console          54
Lucida Sans Typewriter  54
Terminal                48

These are just the fonts I happen to have here on XP. See if you get the same pattern on your own system.

Geoff Franklin

http://www.alvechurchdata.co.uk

 

[Mike Lewis]

Oh, well, Geoff, if you've got nothing better to do, I'll have a go too.

I just ran this:

LOCAL ARRAY laFonts(1)
LOCAL lnI

AFONT(laFonts)
FOR lnI = 1 TO ALEN(laFonts)
  ? FONTMETRIC(16, laFonts(lnI), 10), laFonts(lnI)
ENDFOR

The results are not completely consistent, and there's a certain amount of overlap (for example, a fixed pitch font can be serif or sans serif). But this is a quick summary of my results:

[b]Value    Family            Examples[/b]

7        Special/various   MS Outlook, Wingdings
23       Serif             Clarendon, Times New Roman
33       System            System
39       Sans serif        Univers, Verdana
54       Fixed pitch       Courier New, Lucinda Console
71       Cursive           Lucinda Handwriting, Vivaldi
87       Decorative        Broadway, Stencil

No doubt there are others as well.

Mike

__________________________________
Mike Lewis (Edinburgh, Scotland)

Visual FoxPro tips, advice, training, consultancy
Custom software for your business

 

[Mike Lewis]

Sam,

If my previous suggestion doesn't completely work for you, here's another idea:

lcFont = "Courier New"  && or whatever
IF TXTWIDTH("M", lcFont, 20) = TXTWIDTH(".", lcFont, 20)
  ? "Fixed pitch
ELSE
  ? "Proportional
ENDIF

The idea is that, if the width of a capital M is the same as the width of a dot, it's safe to assume the font is fixed pitch.

Mike

__________________________________
Mike Lewis (Edinburgh, Scotland)

Visual FoxPro tips, advice, training, consultancy
Custom software for your business

 

[brigmar]

For a fixed pitch font, the value returned by TXTWIDTH() is the same as the length of the string provided to it.

AFONT(laFonts)
FOR lnI = 1 TO ALEN(laFonts)
  ? laFonts(lnI)+" is "+IIF(TXTWIDTH("M",laFonts(lnI),24)=1.0,"Fixed Width","Proportional")
ENDFOR