Find Computers with Static IP addresses 1

[Brycspain]

I have a list of about 1400 PC's and wanted to run a WMI querry against each one to find out if they have a static IP address. I can run a script to check for active DHCP however, I would then have to compare that list to my full list of computers to see which ones are using static IPs. Ive checked the FAQ's, searched for Static IP's in this forum, and have experimented with many of the WMI NetworkAdapterConfiguration settings and can't get the script to do what I need it to do. Can someone help me please?

Set objOU = GetObject("LDAP://OU=Computers, DC=microsoft, DC=com")

For Each objComputer in objOU
    strComputer = objComputer.cn
    If TestPing(strComputer) = False Then
		WScript.Echo "Couldn't reach " & strComputer
    Else
    Set objWMIService = GetObject _
    ("winmgmts:" & "!\\" & strComputer & "\root\cimv2")
    Set colAdapters = objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled = True")

    For Each objAdapter In colAdapters
        Wscript.Echo objAdapter.IPEnabled & strComputer
    Next
    End If
Next

 

[PHV]

Perhaps this ?
...
For Each objAdapter In colAdapters
If objAdapter.DHCPEnabled = False Then
Wscript.Echo objAdapter.IPAddress & " : " & strComputer
End If
Next
...

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ181-2886

 

[Brycspain]

Thanks PHV

Im getting this error:
(20, 1) Microsoft VBScript compilation error: Unexpected 'Next'

I have 2 For statements and 2 Next statements so I'm not sure why this error is kicking off.

Set objOU = GetObject("LDAP://OU=Computers, DC=microsoft, DC=com")

For Each objComputer in objOU
    strComputer = objComputer.cn
    If TestPing(strComputer) = False Then
        WScript.Echo "Couldn't reach " & strComputer
    Else
    Set objWMIService = GetObject _
    ("winmgmts:" & "!\\" & strComputer & "\root\cimv2")
    Set colAdapters = objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled = True")

    For Each objAdapter In colAdapters
        If objAdapter.DHCPEnabled = False Then
    Wscript.Echo objAdapter.IPAddress & " : " & strComputer
        End If
    Next
Next

Testping function here

 

[Brycspain]

I figured it out....missing an End if

Thanks again.

 

[Brycspain]

PHV,

My script ran however, none of the static IP machines were echoed out. I took the script and scaled it down for a single PC like this:

'On Error Resume Next

strComputer = "StaticIPComputer"
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
    Set colAdapters = objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled = True")

    For Each objAdapter In colAdapters
        If objAdapter.DHCPEnabled = False Then
        Wscript.Echo objAdapter.IPAddress & " : " & strComputer
        End If
    Next

And I received a type mismatch error on the echo line. The machine I am pointing to is a Windows 2000 build 2195.

Am I missing something?

Thanks

 

[PHV]

Sorry for the typo:
Wscript.Echo Join(objAdapter.IPAddress, ",") & " : " & strComputer

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ181-2886

 

[Brycspain]

You're the man as always...thanks for the help.

 

[jfdabiri]

IPAddress is an array item. it should be like this:

[b]
For i = 0 To UBound(objAdapter.IPAddress)
        If objAdapter.DHCPEnabled = False Then      
           msg = msg & objAdapter.IPAddress(i) 
        End If
next

[/b]

 

[jfdabiri]

sorry for the msg. it should be <b>msgbox or wscript.echo:</b>
For i = 0 To UBound(objAdapter.IPAddress)
If objAdapter.DHCPEnabled = False Then
msgbox objAdapter.IPAddress(i) & ":" & strcomputer
End If
next