fill array in module

[DaPhil]

Hi,
following problem: I want to fill an array within a module. My Code:

module myModule
implicit none
save

integer :: l

integer, parameter :: nt = 4524
real*8, parameter :: tMin = 0.0d0
real*8, parameter :: tMax = 6.0d0
real*8, parameter :: dt = (tMax - tMin) / (nt - 1)
real*8, dimension(nt) :: t

do l = 1, nt
t(l) = tMin + (l - 1) * dt
end do

end module myModule

I get an error: This statement must not appear in the specification part of a module

Is it not possible to fill that array in the module?

Thanks for any help

 

[FJacq]

A module never contains instructions directly but is, on the contrary, a container for data and procedures containing instructions.

In addition, every program needs a main procedure. This is true with many languages like C, C++, FORTRAN, JAVA...

So I suggest something like :

module myModule

  implicit none
  save
  private
  
  public :: compute_t,dp
  
  integer ,parameter :: dp=selected_real_kind(15)
  real(dp),parameter :: tMin = 0.0_dp
  real(dp),parameter :: tMax = 6.0_dp
  
  contains
  
  subroutine compute_t(t)
    real(dp),intent(out) :: t(:)
    integer :: i,nt
    real(dp) :: dt
    nt=SIZE(t)
    dt = (tMax - tMin) / (nt - 1)
    do i=1,nt
      t(i) = tMin + i*dt
    enddo
  end subroutine
  
end module myModule

program test
  use myModule
  implicit none
  real(dp) :: table(4524)
  call compute_t(table)
  write(*,*) table(4000)
end program

I put that in the file "t44.f90". To test :

[lcoul@localhost test]$ ifort t44.f90
[lcoul@localhost test]$ ./a.out
   5.30621269069202

François Jacq