File's hash code - how to get it? 3

[IlyaRabyy]

Colleagues,
the subject line says it.
Search in the MS Learning (aka on-line Help) produced "you're in a helicopter" results.
GetFileHashCode() threw an exception even before Ctrl+S.

AHWBGA!

Regards,

Ilya

 

[strongm]

here's an example I've knocked together

[COLOR=blue]Imports System.Security.Cryptography
Imports System.IO

Public Class Form1
    Public Enum HashOption
        hashMD5
        hashSHA1
        hashSHA256
        hashSHA512
    End Enum

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        MessageBox.Show(filehash("d:\downloads\deleteme\test.txt", HashOption.hashSHA256))
    End Sub

    Function filehash(file_name As String, Optional hashmethod As HashOption = HashOption.hashSHA512) As String
        Dim hash
        Dim hashValue() As Byte

        Dim fileStream As FileStream = File.OpenRead(file_name)
        fileStream.Position = 0

        [COLOR=green]' There are multiple ways of selecting the desired hashing algorithm
        ' This is just one[/color]
        Select Case hashmethod
            Case HashOption.hashMD5
                hash = MD5.Create()
            Case HashOption.hashSHA1
                hash = SHA1.Create()
            Case HashOption.hashSHA256
                hash = SHA256.Create()
            Case HashOption.hashSHA512
                hash = SHA512.Create()
            Case Else
        End Select

        hashValue = hash.ComputeHash(fileStream)
        Dim hash_hex = Convert.ToHexString(hashValue)
        fileStream.Close()
        filehash = hash_hex

    End Function
End Class[/color]

 

[IlyaRabyy]

Thank you, StrongM!
There's one drawback, though:

Is it because my testing program is on .NET Framework 4.8, and Convert.ToHexString() method

I opened the Project Options screen (VS 2022), and there's no option for .NET, only for the Framework...



Regards,

Ilya

 

[mikrom]

if this doesn't work with the older .NET framework:

Dim hash_hex = Convert.ToHexString(hashValue)

then try if this works for you:

Dim hash_hex = BitConverter.ToString(hashValue).Replace("-", "");

 

[strongm]

mikrom has provided the earlier code that can be used

 

[IlyaRabyy]

Thank you, mikrom, it worked!

Regards,

Ilya

 

[strongm]

Sorry - can I just check - did my solution work for you?

 

[mikrom]

Hi IlyaRabyy,
it's fine that it worked, but the credit goes to strongm for providing an essential solution example, with my involvement being only very marginal.

 

[IlyaRabyy]

can I just check - did my solution work for you?

It did, muchos gratis, le grand merci, tada raba, bol'shoe spasibo, djakue bardzo!

Regards,

Ilya