Exporting PwerPoint slides as jpg into a folder using vba Access 1

[aldi07]

Hi,
I am using Access vba to export all slides from a PowerPoint presentation, as jpg files, into a folder.
It does not work, because I am obviously making many syntax mistakes:

Private Sub pptTest()
    Dim objPresentation As PowerPoint.Presentation
    Dim objSlide As PowerPoint.Slide
    Dim strFileName As String
    Dim j As Integer
    Dim x As Integer
    Dim mobjPPT As PowerPoint.Application

    Set mobjPPT = New PowerPoint.Application
    
    Set objPresentation = mobjPPT.Presentations.Open("C:\MyPowerPointPathAndName.pptm")
    
    j = objPresentation.Slides.Count
    If j > 0 Then
        With objPresentation

                For x = 1 To j
                    ActivePresentation.Slides(x).Export _
                    FileName:="MyFileName" & "str(x),jpg"
                Next x
                pptPres.Slides.Range.Delete

        End With
    End If
    
End Sub

I need guidance here. Thank you.

 

[combo]

One line to correct:
[pre] objPresentation.Slides(x).Export _
FileName:="MyFileName" & Format(x, String(Len(Cstr(j)),"0")) & ".jpg", FilterName:="JPG"[/pre]

[tt]Format[/tt] instead of raw x for better sorting if j>9. A path is missing in FileName, you can specify to avoid default.


combo

 

[aldi07]

It worked combo. Thank you very much.
Actually you made me realise also that I was using ActivePresentation instead of objPresentation.
Another mistake: I was using pptPres instead of objPresentation.
Once all the correction were made, it worked fine. Thank you again!

 

[Andrzejek]

It may be beneficial to other TT visitors to know your full code solution.
And how about a Star for combo?

---- Andy

"Hmm...they have the internet on computers now"--Homer Simpson

 

[aldi07]

Andrzejek,
I did give combo a star, except that I forgot to confirm it... Well, it's done now!
Here is the code as requested:

Private Sub PPT_Test_Click()
    Dim objPresentation As PowerPoint.Presentation
    Dim objSlide As PowerPoint.Slide
    Dim strFileName As String
    Dim i As Long
    Dim j As Long
    Dim x As Integer
    Dim mobjPPT As PowerPoint.Application

    Set mobjPPT = New PowerPoint.Application
    
    Set objPresentation = mobjPPT.Presentations.Open("MyPathAndPowerPointFileName.pptm")
    
    j = objPresentation.Slides.Count
    If j > 0 Then
        With objPresentation
            For x = 1 To j
                objPresentation.Slides(x).Export _
                    FileName:="MyPathAndSlideFileName" & Format(x, String(Len(CStr(j)), "0")) & ".jpg", FilterName:="JPG"
            Next x
            objPresentation.Slides.Range.Delete
        End With
    End If
    MsgBox "Done"

End Sub

 

[Andrzejek]

Not to be picky, but your [tt]With objPresentation / End With[/tt] is either not needed or not used.

Either:

...
    If j > 0 Then
        With objPresentation
            For x = 1 To j
                [s]objPresentation[/s].Slides(x).Export _
                    FileName:="MyPathAndSlideFileName" & Format(x, String(Len(CStr(j)), "0")) & ".jpg", FilterName:="JPG"
            Next x
            [s]objPresentation[/s].Slides.Range.Delete
        End With
    End If
...

or

...
    If j > 0 Then
        [s]With objPresentation[/s]
            For x = 1 To j
                objPresentation.Slides(x).Export _
                    FileName:="MyPathAndSlideFileName" & Format(x, String(Len(CStr(j)), "0")) & ".jpg", FilterName:="JPG"
            Next x
            objPresentation.Slides.Range.Delete
        [s]End With[/s]
    End If
...

but not both

---- Andy

"Hmm...they have the internet on computers now"--Homer Simpson

 

[aldi07]

You are quite right Andy.
I did not understand the exact way "with / end with" should be used.
It is clearer now. Thank you. By the way, I chose your first solution.