Display today date day with the suffix after the day.

[troop49]

Example:

17th day of September 2010

How can i display the 'th' after the 17
or the 'rd' for the 3rd etc...

 

[IanWaterman]

In format date click customise

At the bottom you can change separators, opposite the day separator click the formula box.

If day(datefield) in [ 3, 23] then 'rd' else
If day(datefield) in [ 1, 21, 31] then 'st' else
If day(datefield) in [ 2, 22] then 'nd' else
'th'

Ian

 

[briangriffin]

If you want to return the entire string:

local stringvar v_day;
local stringvar v_result;

v_day := 

select day({@date}) 

case 1,21,31: "st"
case 2,22: "nd"
case 3,23: "rd"
case 4 to 20,24 to 30: "th";

v_result := totext(day({DateField}),"#",0) + v_day + " day of " + monthname(month({DateField})) + ", " + totext(year({DateField}),"#",0);

v_result

This would probably be a good opportunity for a custom function:

Function  (dateVar v1)

local stringvar v_day;
local stringvar v_result;

v_day := 

select day(v1) 

case 1,21,31: "st"
case 2,22: "nd"
case 3,23: "rd"
case 4 to 20,24 to 30: "th";


v_result := totext(day(v1),"#",0) + v_day + " day of " + monthname(month(v1)) + ", " + totext(year(v1),"#",0);

v_result

 

[troop49]

//
If day(CurrentDate) in [ 3, 23] then 'rd' else
If day(CurrentDate) in [ 1, 21, 31] then 'st' else
If day(CurrentDate) in [ 2, 22] then 'nd' else'th'


THis work beautifully.
THANK YOU!!!!!!!