Display e-mail address 1

[cdtech9198]

Hello I am working on a script to change default smtp address for a group of users in a ou. I can not do it with exchange using recipient policy. Once I get the default email hopefully I can store everything to the left of the @ sign and amend @newdomain.com

Right now I am just trying to query AD to display the mail address but having trouble. Its been a while since I touched vbscript

Set objShell = WScript.CreateObject("WScript.Shell")
Set objNetwork = CreateObject("Wscript.Network")
Set objFSO = CreateObject("Scripting.FileSystemObject")


OUPath = "LDAP://OU=test,DC=foo,DC=com"

Set CNUsers = GetObject (OUPath)
CNUsers.Filter = Array("user")
For Each User in CNUsers
     address = User.mail  
     wscript.echo address

Next

Thank you.

 

[markdmac]

You are using the wrong property. You need to enumerate ProxyAddresses. The default email address uses upper case SMTP, recondary addresses use lower case smtp.

You don't say how you want to change the email so I've just given you an example of changing the default domain.

Const ADS_PROPERTY_APPEND = 3
Const ADS_PROPERTY_DELETE = 4
Dim qQuery, objConnection, objCommand, objRecordSet, obj
Dim oRootDSE, strDomain

Set oRootDSE = GetObject("LDAP://rootDSE")
strDomain = oRootDSE.get("defaultNamingContext")

strOU = "test"

' other categories = computer, user, printqueue, group
qQuery = "<LDAP://OU=" & strOU & "," & strDomain &">;" & _
		"(objectCategory=person)" & _
       ";distinguishedName;subtree"

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand = CreateObject("ADODB.Command")
objConnection.Open "Provider=ADsDSOObject;"
objCommand.ActiveConnection = objConnection
objCommand.CommandText = qQuery
Set objRecordSet = objCommand.Execute

While Not objRecordSet.EOF
    Set objUser = GetObject("LDAP://" & objRecordSet.Fields("distinguishedName"))
    arrEmails = objUser.ProxyAddresses
    For Each email In arrEmails
    	If Left(email,4)="SMTP" Then
    	'Assume we are changing the default domain for a user just as an example
    		NewMail = Replace(email,"oldDomain.com","newDomain.com")
		    objUser.PutEx ADS_PROPERTY_DELETE, "proxyAddresses", array(email)
		    objUser.SetInfo  
		    objUser.PutEx ADS_PROPERTY_APPEND, "proxyAddresses", array(newMail) 
			objUser.SetInfo
    	End If
    Next
    objRecordSet.MoveNext
Wend

objConnection.Close

I hope you find this post helpful.

Regards,

Mark

Check out my scripting solutions at

http://www.thespidersparlor.com/vbscript

Work SMARTER not HARDER. The Spider's Parlor's Admin Script Pack is a collection of Administrative scripts designed to make IT Administration easier! Save time, get more work done, get the Admin Script Pack.

 

[cdtech9198]

Yes I figured out the ProxyAddress is where I need to be. I will be adding a new default domain name and setting it as default SMTP. Do not want to delete the old one. Thank you.

 

[markdmac]

You will need to delete and then add back in the address as a secondary address. Change the For Each as follows:

For Each email In arrEmails
        If Left(email,4)="SMTP" Then
        'Assume we are changing the default domain for a user just as an example
            SaveMail = Replace(email,"SMTP","smtp")
            NewMail = Replace(email,"oldDomain.com","newDomain.com")
            objUser.PutEx ADS_PROPERTY_DELETE, "proxyAddresses", array(email)
            objUser.SetInfo  
            objUser.PutEx ADS_PROPERTY_APPEND, "proxyAddresses", array(newMail) 
            objUser.SetInfo
            objUser.PutEx ADS_PROPERTY_APPEND, "proxyAddresses", array(SaveMail) 
            objUser.SetInfo
        End If
    Next

I hope you find this post helpful.

Regards,

Mark

Check out my scripting solutions at

http://www.thespidersparlor.com/vbscript

Work SMARTER not HARDER. The Spider's Parlor's Admin Script Pack is a collection of Administrative scripts designed to make IT Administration easier! Save time, get more work done, get the Admin Script Pack.

 

[cdtech9198]

Very nice. I was almost there. I was first querying the proxyaddress then striping the @olddomain.com off using Right and Len commands. Next was I adding name@newdomain.com using
objUser.PutEx ADS_PROPERTY_APPEND.

Only thing I noticed is that the mail attribute in ADUC is not changing to reflect the new email address.

 

[markdmac]

For Each email In arrEmails
        If Left(email,4)="SMTP" Then
        'Assume we are changing the default domain for a user just as an example
            SaveMail = Replace(email,"SMTP","smtp")
            NewMail = Replace(email,"oldDomain.com","newDomain.com")
            objUser.PutEx ADS_PROPERTY_DELETE, "proxyAddresses", array(email)
            objUser.SetInfo  
            objUser.PutEx ADS_PROPERTY_APPEND, "proxyAddresses", array(newMail) 
            objUser.SetInfo
            objUser.PutEx ADS_PROPERTY_APPEND, "proxyAddresses", array(SaveMail) 
            objUser.SetInfo[b]
            objuser.Put "mail" , newMail
	    objUser.SetInfo[/b]
        End If
    Next

I hope you find this post helpful.

Regards,

Mark

Check out my scripting solutions at

http://www.thespidersparlor.com/vbscript

Work SMARTER not HARDER. The Spider's Parlor's Admin Script Pack is a collection of Administrative scripts designed to make IT Administration easier! Save time, get more work done, get the Admin Script Pack.