Db Opener Issues 1

[newguy86]

I have two VBScripts (one installs a shortcut for a Db and the other opens it). When I click on the shortcut that my installer script created, the database will open but then immediately close. Can anyone help me figure out what I am doing wrong?

Installer script

Dim oShell
Dim sDesk
Dim oShortCut
Dim strFileName 

Set oShell = CreateObject("WScript.Shell")
sDesk = oShell.SpecialFolders.Item("Desktop")
Set oShortCut = oShell.CreateShortcut(sDesk & "\Bowen Db.lnk")

With oShortCut
	.TargetPath = "C:\Program Files\Bowen Db Opener.vbs"
	.Description = "Bowen Db"
	.WorkingDirectory = "C:\Program Files\Bowen Db Opener.vbs"
    .Save
End With

MsgBox "Installation Complete!"

Opener script

Dim lfsobject
Dim dbsLTTFront

On Error Resume Next

Set lfsObject = CreateObject("Scripting.FileSystemObject")
lfsObject.CopyFile "************************\Bowen Db.mdb", "C:\Program Files\Bowen Db.mdb"

If Err.Number = 0 Then
    Set dbsLTTFront = CreateObject("Access.Application")
    'dbsLTTFront.AutomationSecurity = 1 'msoAutomationSecurityLow
    dbsLTTFront.Visible = True
    dbsLTTFront.OpenCurrentDatabase "C:\Program Files\Bowen Db.mdb"
Else
    'Err number 70, 7866 and -2147023170 sometimes occur with rampant clicking
    Msgbox ("The application takes a moment to load, please be patient.")
End If

Any assistance would be greatly appreciated.

Travis

http://www.enterprise.com

"Why would I ever want to learn about programming when Micorsoft products would be able to handle even the simplest of tasks. Oh...wait a minute...something's wrong with that statement!

 

[tsuji]

[0] If you choose to use the automation routine, which is in a sense good, making it free from user's path setting, you can add this line after the .OpenCurrentDatabase line, surrendering control to user.
[tt]
dbsLTTFront.OpenCurrentDatabase "C:\Program Files\Bowen Db.mdb"
[blue]dbsLTTFront.userControl=true[/blue]
[/tt]
[1] Otherwise, you can use .run (replacing the whole section of err.number=0) to get his done, but it would be dependent on the concrete path of the msaccess.
[tt]
createobject("wscript.shell").run "msaccess """ & "C:\Program Files\Bowen Db.mdb" & """"
[/tt]

 

[newguy86]

tsuji,
I used the first suggestion that you gave me and it worked perfectly.

Thanks!

Travis

http://www.enterprise.com

"Why would I ever want to learn about programming when Micorsoft products would be able to handle even the simplest of tasks. Oh...wait a minute...something's wrong with that statement!