Date Range

[ksimmsa]

I have a report in Access based off of a query that has a date range. I need to have the selected date range to appear at the header of the report.

Thanks in advance for you help.

 

[drctx]

this is the way i came up with doing this.

put this in a module:

Public varStartDate As Variant
Public varEndDate As Variant

Public Function getvarStartDate() As String
'hold Start Date
   getvarStartDate = varStartDate
End Function

Public Function getvarEndDate() As String
'hold Start Date
   getvarEndDate = varEndDate
End Function

----------------------------------------------------

add the code below to a form named frmCFMCriteria that has:
text box named txtStartDate
text box named txtEndDate
command button named cmdEnter
command button named cmdCancel

Private Sub cmdCancel_Click()
    DoCmd.Close acForm, "frmCFMCriteria"
End Sub

Private Sub cmdEnter_Click()
    varStartDate = Me.txtStartDate
    varEndDate = Me.txtEndDate
    DoCmd.OpenReport "CFM Log", acViewPreview
    DoCmd.Close acForm, "frmCFMCriteria"
End Sub

Private Sub Form_Load()
    Me.TimerInterval = 1
End Sub

Private Sub Form_Timer()
    Me.TimerInterval = 0
    DoCmd.Close acReport, "CFM Log"
End Sub

----------------------------------------------------

add this to the criteria of the date field:

Between getvarStartDate() And getvarEndDate()

----------------------------------------------------

then add a text box to the header of the report and add this as the control source:

="From " & getvarStartDate() & " through " & getvarEndDate()

----------------------------------------------------

add this code to the report:

Private Sub Report_Close()
    varStartDate = ""
    varEndDate = ""
End Sub

Private Sub Report_Open(Cancel As Integer)
    If varStartDate = "" Or varEndDate = "" Then
        DoCmd.OpenForm "frmCFMCriteria"
        Cancel = 1
        Exit Sub
    End If
End Sub