Dat Environment

[sdocker]

Is ther any way to check to see if a forms data environment has any has code attached to it.

I have an app with numerous forms and occasionaly I find incorrect data environment in it.

Rather than opening each form and checking, I am lookin for some code to do it. It would probably be similar to the widely used code to "clear tage in report forms".

Sam

 

[Olaf Doschke]

In principle, yes. Because each SCX is a DBF and you can USE and then of course navigate to anything including DE code faster than doing that manually in the IDE.

Nevertheless I wouldn't suggest writing anything.

Mainly you USE some.scx and locate the record with ObjName="Dataenvironment", then see into Methods Memo for code of the dataenvironment.

Bye, Olaf.

 

[TamarGranor]

[tt]MODIFY PROJECT YourProject
FOR EACH oFile IN _VFP.ActiveProject.Files
IF oFile.Type = "K" && form
USE (m.oFile) ALIAS __Form
LOCATE FOR Class = dataenvironment
IF FOUND() AND NOT EMPTY(Methods)
* There's code in the DE. Do what you want.
ENDIF
USE IN SELECT("__FORM")
ENDIF
ENDFOR
[/tt]

Tamar

 

[sdocker]

Tamar,

This is what I was looking for.

Tamar and Olaf,
Except I found the code in the method of an object named cursor1.
What would happen if there is a table in the DE window of the form, but no code. Where would the evidence of this show up in the .scx file?

I noticed that if I remove the table from the DE window, the object "Cursor1" is no longer in the .scx file.

Sam

 

[Olaf Doschke]

Every table or view you put into the dataenvironment is in a cursor object. This is not to be confused with a cursor in a workarea, but its named that way, as it results in such a cursor.

See:

http://msdn.microsoft.com/en-us/library/sae4ksse(v=vs.80).aspx,

http://msdn.microsoft.com/en-us/library/hbhch4kb(v=vs.80).aspx

Indeed also these cursor objects can have code in them. Strictly speaking still that isn't code in the dataenvironment like click code in form buttons is no form code, but button code.

All tables and views in a DE will show up as such objects with class = "cursor", you could also have cursoradaptes in there. Anything in the DE will point to the Dataenvironment record via the Parent field, as the Parent field is empty for the dataenvironment itself you can find all such records via LOCATE FOR EVL(Parent,Objname) = "Dataenvironment"

All these objects in the DE can have no further child objects, but of course any code in there can create any further objects, if you want to find all classes and project files involved in the DEs of your forms yo would therefore also start parsing code and finding further references.

Bye, Olaf.

 

[Olaf Doschke]

So this would find them all:

Modify Project ?
For Each oFile In _vfp.ActiveProject.Files
   If oFile.Type = "K" && form
      Use (m.oFile.Name) Alias __Form
      Locate For Evl(Parent,ObjName) = "Dataenvironment"
      Do While Found() 
         If Not Empty(Methods)
            * There's code in the DE. Do what you want.
            ? "Code found in", oFile.Name, Objname
         EndIf 
         Continue 
      EndDo
      Use In Select("__FORM")
   Endif
Endfor

Bye, Olaf.

 

[sdocker]

Thanks guys,

The code and explantion were a great help. The code works fine with some minor modifications for what I needed.

Sam