CSR's should only get a call if wait time is >=2 min 1

[Benighted]

Does anyone know if it possible to set a parameter within Symp v. 4 that a certain set of agents only will receive a call if wait time is 2 minutes or more? Any help is appreciated.

 

[DancingDave]

Do you mean expected wait time (EWT - Skillset intrinsic) or the age of the call when you talk about 'wait time'

For EWT, you would need to insert a check (ideally you would have a loop section in your script that this would go in) that queued to a secondary skillset that is allocated to this group of agents if EWT on the primary skillset was >= 2 minutes.

You could also put in a second check to dequeue the call from this skillset if the EWT drops below the two minutes before the call is answered.

One word of warning if using EWT. It is only really accurate if your call centre takes a lot of calls of approximately the same length. If volumes are low or call length varies, EWT can be wildly inaccurate.

If using Age of Call, place a test in the script (again likely to be in your loop section) that queues to a secondary skillset that is allocated to this group of agents if the age of call intrinsic is > 120.

Let me know if you need example syntax

DD

 

[rfwhite]

As DD says above you might be better off using age
of call as the trigger. Using EWT will probably be unpredictable depending on your call volume.

 

[Benighted]

Is see that Wait time within Symp is defined as the time that a agent is waiting for a call. This is not my definition.

I want certain group of agents to only receive calls when the average wait time on a skillset goes above 2 minutes.

It would be great to see some kind of example on this.

 

[DancingDave]

Bearing in mind the issues noted above with using EWT, I would use the following scripting.

Note cv_queued is a call variable of type Boolean, with a default value of FALSE.

Stick this in your existing loop section so it is checked on a regular basis. The script will dequeue from a skillset if the EWT drops below 2 minutes. There are also checks to make sure a call isn't queued to a skillset that it is already being queued to. Wait time and messaging will be down to your own company standards

DD





IF EXPECTED WAIT TIME Skillset_A >= 120
AND IF cv_queued = FALSE THEN
IF NOT OUT OF SERVICE Skillset_B THEN
QUEUE TO SKILLSET Skillset_B WITH PRIORITY 3
ASSIGN TRUE TO cv_queued
END IF
END IF

WAIT 10

OPEN VOICE SESSION
PLAY PROMPT
VOICE SEGMENT vs_Customer_Appeasement_Msg10
END VOICE SESSION

IF cv_queued = TRUE
AND EXPECTED WAIT TIME Skillset_A < 120 THEN
REMOVE FROM SKILLSET Skillset_A
ASSIGN FALSE TO cv_queued
END IF

 

[Benighted]

Thank you very much. Will give it a shot

 

[Benighted]

Finally I've gotten the chance to test thi script. Although I'm having problems getting it to work. The line : AND IF cv_queued = FALSE THEN, is not accepted. It states "Line: 44, Position: 9, Code: 15, Error: Syntax error or unsupported command". What's up with this?

 

[mte0910]

You don't say AND IF.
The sentax is...
IF XXX
AND
YYY
THEN
ZZZ
END IF

The second IF is understood.

 

[Benighted]

Thanks for your reply. I've tried to do some changes to the script, and it's validated ok. When I try to do some test calls I'm not transferred from skillset A to skillset B when the EWT exceeds 2 mins. I've tried to take out the waitloop, but without any result. Here's the script :

/* Title: CDN 6497 Kundeservice_test*/


IF (DATE = Holiday_closed)
OR (DATE = JulNyttAften AND TIME OF DAY = Closed_julnytt)
OR (DATE = Romjuldays AND TIME OF DAY = Closed_Romjul20)
OR (DATE = Askeonsdag_closed AND TIME OF DAY = Closed_Askeonsdag)
OR (DATE = Holiday_paske AND TIME OF DAY = Closed_Paskeaften)
OR (DAY OF WEEK = saturday AND TIME OF DAY = Closed_sat_16)
OR (DAY OF WEEK = sunday)
OR (DAY OF WEEK = Weekdays AND TIME OF DAY = closed_hours_GE1) THEN
GIVE IVR 6121 WITH TREATMENT 1051
END IF

/* Ko Script*/
IF OUT OF SERVICE Kundeservice_test THEN /* Sjekker om det er agent innlogget*/
GIVE IVR 6121 WITH TREATMENT 1051 /* GIR VALG Gir Gratis å bruke kontofon*/

DISCONNECT
END IF


QUEUE TO SKILLSET Kundeservice_test
WAIT 2 /* Allow time in case an agent is available */
/* Allow time in case an agent is available */

/*GIVE IVR 6121 WITH TREATMENT 1050 */ /*Beskjed om utsendendelse av faktura 250405(faktura250504) -(aktivert 0206 15:40)*/
GIVE IVR 6121 WITH TREATMENT 1005 /* Det er gratis å bruke kontofon*/

GIVE MUSIC music_route

SECTION WAITLOOP
IF NOT OUT OF SERVICE Brann THEN /* Sjekker om det er noen logget inn på Brann skillset*/
GIVE RAN Brann_ran /* GIR talemedling ved Brann*/
DISCONNECT
END IF

WAIT 20
IF NOT QUEUED THEN
IF OUT OF SERVICE Kundeservice_test THEN /* Sjekker om det er agent innlogget*/
GIVE IVR 6121 WITH TREATMENT 1051 /* GIR VALG ..Gir Gratis å bruke kontofon*/

IF EXPECTED WAIT TIME Kundeservice_test >= 120
AND cv_queued = FALSE THEN
IF NOT OUT OF SERVICE Kundeservice_6060 THEN
QUEUE TO SKILLSET Kundeservice_6060 WITH PRIORITY 3
ASSIGN TRUE TO cv_queued
END IF
END IF

WAIT 10

/*OPEN VOICE SESSION
PLAY PROMPT
VOICE SEGMENT music_route
END VOICE SESSION*/

IF cv_queued = TRUE
AND EXPECTED WAIT TIME Kundeservice_test < 120 THEN
REMOVE FROM SKILLSET Kundeservice_test
ASSIGN FALSE TO cv_queued
END IF

DISCONNECT
ELSE

WAIT 2
END IF

END IF

GIVE IVR 6121 WITH TREATMENT 1006 /* Alle linjer er opptatt, vent og ha klart ktr nr*/

EXECUTE WAITLOOP

Thanks again for you help.

 

[DancingDave]

Try this...

I've added a WAIT 2 after queueing to Kundeservice_6060 and I've changed it to dequeue from Kundeservice_6060 rather than Kundeservice_test if EWT for Kundeservice_test drops below 120 seconds (both of these were mistakes in my original post). cv_queued is false as default isn't it?

Let us know how you get on.

DD

SECTION WAITLOOP

IF NOT OUT OF SERVICE Brann THEN
GIVE RAN Brann_ran
DISCONNECT
END IF

WAIT 20

IF NOT QUEUED THEN
IF NOT OUT OF SERVICE Kundeservice_test THEN
QUEUE TO SKILLSET Kundeservice_test WAIT 2
ELSE
GIVE IVR 6121 WITH TREATMENT 1051
END IF
END IF

IF EXPECTED WAIT TIME Kundeservice_test >= 120
AND cv_queued = FALSE THEN
IF NOT OUT OF SERVICE Kundeservice_6060 THEN
QUEUE TO SKILLSET Kundeservice_6060 WITH PRIORITY 3
WAIT 2
ASSIGN TRUE TO cv_queued
END IF
END IF

WAIT 10

IF cv_queued = TRUE
AND EXPECTED WAIT TIME Kundeservice_test < 120 THEN
REMOVE FROM SKILLSET Kundeservice_6060
ASSIGN FALSE TO cv_queued
END IF



GIVE IVR 6121 WITH TREATMENT 1006

EXECUTE WAITLOOP

 

[Benighted]

It still doesn't work I'm afraid. I'm stuck in the waitloop, and I'm not transferred to Kundeservice_6060 when the wait time exceeds 120 secs.
I've set cv_queued to false as default.
Thanks again for all your help.

 

[DancingDave]

Remember , there is a difference between EWT and the time the call has been waiting to be answered. EWT is calculated based on all calls on that skillset, whereas the actual wait time applies only to that call.

The script will only queue to K_6060 if the EXPECTED WAIT TIME intrinsic for the K_test skillset is > 120, Not the age of the call is > 120.

If it is the age of the call that you want to trigger the call being queued to K_6060 then just change 'EXPECTED WAIT TIME Kundeservice_test ' to 'AGE OF CALL'.

If it is the EWT that you want to use, then I would change the script so that it queues to K_6060 if EWT K_test is > 2 seconds to satisfy yourself it does work.

NB Make test calls to K_test on another script and take your time to answer them so that EWT K_test is > 2 seconds before you do the above.

You should then get the desired results.

DD

 

[Benighted]

It's working now! ) Both with age of call and EWT. I tried with age of call before as well, but forgot to remove kundeservice_test. Now I've just made a teamleader in customer service very happy. Thank you very much for your help. This was much better then using the local vendor. (that have 1 guy that knows Symp scripting and that uses 1 month to reply)

 

[DancingDave]

You're welcome.

DD