Converting Track changes to underline and strike through 2

[utoyo]

Is there any function of word that allows me to convert text marked up with track changes to underlined and strike through text?

Thanks in Advance.

 

[mintjulep]

Do you mean actually the strikethru font, or the the pre-2000 default track changes display of strikethru and underline?

If the latter, Tools | Options | Track Changes tab gives you the options needed to turn off the balloons and use the old way.

 

[utoyo]

I meant I have text without bubbles (which is the way I want it) but, I have made changes with track changes on and would like to make the changes part of the text. For example, if the word "forum" is underlined via track changes, I'd like to convert it to underlined text. (Basically, the track changes markup become part of the text).

 

[mintjulep]

Not that I know of. I spent some time a few years ago trying to accomplish it - without success.

Wound up printing as PDF with track changes on.

 

[MakeItSo]

It's not so difficult, you just need to pay attention to a few things.
Here's some commented and tested code that should work just fine.
;-)

Sub FormatRevisions()
Dim rev As Revision, txt As String, r As Long, ran As Range

'First switch off TrackChanges, else each of your reformattings will become a revision again
ActiveDocument.TrackRevisions = False

'***Now cycle through revisions, identify type of change
For Each rev In ActiveDocument.Revisions
    Select Case rev.Type
        Case wdRevisionDelete
            'secure "deleted" text as well as its position
            txt = rev.Range.Text
            r = rev.Range.Start
            'accept the revision to make the markup disappear
            rev.Accept
            'now type the text formatted as strikethrough at the position of the old text
            Set ran = ActiveDocument.Range(r, r)
            With ran
                .Text = txt
                .Font.StrikeThrough = 1
            End With
        Case wdRevisionInsert
            Set ran = rev.Range
            'accept the revision to make the markup disappear
            rev.Accept
            'now type the text formatted as underlined at the position of the old text
            ran.Font.Underline = 1
    End Select
Next rev
End Sub

[navy]"We had to turn off that service to comply with the CDA Bill."[/navy]
- The Bastard Operator From Hell