Converting from Row to column

[sdslrn123]

A = 1
A = 2
A = 3

B = 5
B = 1
B = 7

e.t.c
C = .....


Is there a way to convert this format to:
A = 1,2,3
B = 5,1,7
C = ...
.
.
.
Z = ...



I am thinking
while in data file
split each line to letters and numbers.
if next letter matches previous letter push into an array

otherwise create a new array called B?

 

[ishnid]

Create a hash of arrays. The keys of the hash are the letters and the values are arrays of the numbers associated with each letter. Google for perllol for more on multidimensional data structures in Perl.

 

[brigmar]

Using Hashes:

my %lines=();
open DATAFILE, "input.txt";
while(<DATAFILE>) {
  chomp;
  my ($letter,$number) = split(/=/);
  $letter =~ s/\s+$//;
  $number =~ s/^\s+//;
  if(defined($lines{$letter})) {
    $lines{$letter} .= ",$number";
  } else {
    $lines{$letter} = "$letter=$number";
  }
}
close DATAFILE;

foreach (keys %lines) {
  print "$lines{$_}\n";
}

 

[ishnid]

  my ($letter,$number) = split(/=/);
  $letter =~ s/\s+$//;
  $number =~ s/^\s+//;

Why force yourself to remove the spaces later when you can just include them in your split?

my ( $letter, $number ) = split( / = / );

 

[raklet]

Here is the hash of arrays solution.

my %values;
while (<DATA>) {
    chomp;
    my ($key,$val) = split/ = /;
    push @{$values{$key}},$val;
}
foreach my $key (keys %values) {
    next if !$key;
    print "$key = " . join(',', @{$values{$key}}) . "\n";

}

__DATA__
A = 1
A = 2
A = 3

B = 5
B = 1
B = 7

 

[brigmar]

Why force yourself to remove the spaces later when you can just include them in your split?

Because they may or may not be there.

 

[ishnid]

There's nothing in the OP's post to suggest that they won't be there. They're in the data format that's posted.

If you are allowing for them to be absent, then you can include that in the split too:

my ( $letter, $number ) = split( / ?= ?/ );

 

[rharsh]

Or you can skip the split and just use a regex:

while (<DATA>) {
    push(@{$values{$1}}, $2) if /(\w+)\s*=\s*(\w+)/;
}

One thing that I don't think was addressed is the order of the keys. Sorting them is easy as far as the sample data is concerned, but if the order of the keys in the real data isn't easily reproduced, something (an array probably) will need to be implemented to track the order the keys are read.