Convert STRINGS to Proper Case. 2

[motoslide]

Is there a utility (similar to tr) that can be used to convert strings within a text file to Proper Case?

Before:
ACME HARDWARE|1234 YOUR STREET|ANYTOWN|BOB SMITH|(555) 555-1212

After:
Acme Hardware|1234 Your Street|Anytown|Bob Smith|(555) 555-1212

I'm sure there will be plenty of issues where the conversion would generate unwanted results (such as "PT CRUISER" becomes "Pt Cruiser" and "RYAN MCHENRY" becomes "Ryan Mchenry"). We can determine later if those issues are too difficult to live with.

"Proof that there is intelligent life in Oregon. Well, Life anyway.

 

[kHz]

See ksh [:upper:] [:lower:]

 

[futurelet]

ruby -e 'ARGF.each{|s| print s.split(/([A-Z]+)/).
map{|x| x.capitalize}}' textfile

 

[bigoldbulldog]

If this is headed in or out of Oracle, use the INITCAP function.

Here's a sed script:

s/^/ /
:loop
h
s/.*[^a-zA-Z0-9][A-Z]\([A-Z]\{1,\}\).*/\1/
/[^A-Z]/{
        s/^[^a-zA-Z0-9]\(.*\)/\1/
        b
}
y/ABCDEFGHIJKLMNOPQRTSUVWXYZ/abcdefghijklmnopqrtsuvwxyz/
G
s/\(.*\)\n\(.*[^a-zA-Z0-9][A-Z]\)[A-Z]\{1,\}/\2\1/
t loop

Cheers,
ND

 

[chipperMDW]

If you have GNU sed:

$ sed 's/\b\(\w*\)\b/\L\u\1/g'
ACME HARDWARE|1234 YOUR STREET|ANYTOWN|BOB SMITH|(555) 555-1212
Acme Hardware|1234 Your Street|Anytown|Bob Smith|(555) 555-1212

 

[motoslide]

Thanks much, folks. I'll give the sed methods a try and see what comes out. I won't have access to the test data for a few days.
I don't have ruby, but that looks like a very clean solution.

"Proof that there is intelligent life in Oregon. Well, Life anyway.

 

[bigoldbulldog]

I seldom use perl but this should be clean and easy:

perl -n -e "s/\b(\w+)/\L\u$&/g;print"

Cheers,
ND

 

[feherke]

Hi

Nice one, bigoldbulldog, but you can make that shorter :

perl -pe 's/\b(\w+)/\L\u$&/g'

Feherke.

http://rootshell.be/~feherke/

 

[PHV]

perl -pe 's/\b(\w+)/\L\u$&/g'
Seems to work only for 7bits ASCII files, not for iso8859-1 accented stuff (as we all use in real world (ie outside USA ;-))).

 

[feherke]

Hi

Yes, I saw that. ( My usual test file is a lasagna recipe in hungarian. )

But anyway, neither the other scripts works well with such texts. ( At least using the versions I have. )

Feherke.

http://rootshell.be/~feherke/

 

[bigoldbulldog]

What about contractions in English. This is also trouble.

There's always C. The ascii stuff would be easy with good performance then you have to contend with the specific cases, contractions, and such.

Est-ce que j'ai raison?

Cheers,
ND

 

[motoslide]

Both the PERL and SED commands worked as expected. Thanks much. I even tried with a hyphenated last name, which was successful.

I gave BullDog the star because his sed script confused me but worked great.

"Proof that there is intelligent life in Oregon. Well, Life anyway.

 

[bigoldbulldog]

In case of possesive company names, I hacked this in:

s/^/ /
:loop
h
s/.*[^a-zA-Z0-9][A-Z]\([A-Z]\{1,\}\).*/\1/
/[^A-Z]/{
        s/^[^a-zA-Z0-9]\(.*\)/\1/
        s/'S\([| ]\)/'s\1/g
b
}
y/ABCDEFGHIJKLMNOPQRTSUVWXYZ/abcdefghijklmnopqrtsuvwxyz/
G
s/\(.*\)\n\(.*[^a-zA-Z0-9][A-Z]\)[A-Z]\{1,\}/\2\1/
t loop

Now

ACME HARDWARE|1234 YOUR STREET|ANYTOWN|BOB SMITH|(555) 555-1212
SAM'S CLUB|1234 YOUR STREET|ANYTOWN|BOB SMITH-BRADLEY JR|(555) 555-1212
FRANK'S|1234 YOUR STREET|ANYTOWN|CARMEN D'SOUZA|(555) 555-1212

becomes

Acme Hardware|1234 Your Street|Anytown|Bob Smith|(555) 555-1212
Sam's Club|1234 Your Street|Anytown|Bob Smith-Bradley Jr|(555) 555-1212
Frank's|1234 Your Street|Anytown|Carmen D'Souza|(555) 555-1212

Cheers,
ND

 

[futurelet]

ACME HARDWARE|1234 YOUR STREET|ANYTOWN|BOB SMITH|(555) 555-1212
SAM'S CLUB|1234 YOUR STREET|ANYTOWN|BOB SMITH-BRADLEY JR|(555) 555-1212
FRANK'S|1234 YOUR STREET|ANYTOWN|CARMEN D'SOUZA|(555) 555-1212

ruby -pe 'gsub(/\w+('\w(?!\w))?/){$&.capitalize}'

Output:

Acme Hardware|1234 Your Street|Anytown|Bob Smith|(555) 555-1212
Sam's Club|1234 Your Street|Anytown|Bob Smith-Bradley Jr|(555) 555-1212
Frank's|1234 Your Street|Anytown|Carmen D'Souza|(555) 555-1212