Tek-Tips is the largest IT community on the Internet today!

Members share and learn making Tek-Tips Forums the best source of peer-reviewed technical information on the Internet!

Register Log in
  • Congratulations SkipVought on being selected by the Tek-Tips community for having the most helpful posts in the forums last week. Way to Go!

code runs in access 2003 but not in 2010 4

Status
Not open for further replies.
kiwieur

kiwieur

Technical User
Apr 25, 2006
200
0
0
GB
I have been using the code below in access 2003 for around 18 months to send an e-mail I am now testing this using 2010 and I am getting an

"application defined or object defined error" at the line highlighted in red

Code: 
Public Function cmdPrint_Click(view As Integer)
'On Error GoTo cmdPrint_Click_Error

Dim wnd As Long
Dim uClickYes As Long
Dim Res As Long
Dim strFilename As String
Dim strNewName As String
Dim strHead As String
Dim strSub As String
Dim DDate As String
Dim strfrp As String
Dim strContact As String


strFilename = "Some Company"
strSub = " "
strOrderID = Forms![frmOrdersMain]![txtOrderNo]
strOrderBy = Forms![frmOrdersMain]![txtOrderedBy]

D = Format(Now, "dd")
m = Format(Now, "mm")
Y = Format(Now, "yy")

DDate = D & "-" & m & "-" & Y

strHead = strFilename & "  Order No_" & strOrderID & "  Dated " & DDate

strNewName = DLookup("[Path]", _
    "tblFilePaths", "[Type] = 'E-Mail'") & strFilename & "_Order No_" & strOrderID & "_" & DDate & ".pdf"

Forms![frmOrdersMain]![txtFileName] = strFilename & "_Order No_" & strOrderID & "_" & DDate & ".pdf"

Call SaveReportAsPDF("rptOrderB", strNewName)

 Dim patha, pathT, pathC, pathH, pathS, CustMail, KamMail As String

SuppMail1 = Forms!frmOrdersMain!txtEMail
SuppMail2 = Forms!frmOrdersMain!txtEMail2
patha = strNewName

strSub = "Dear Sir/Madam " & _
vbCrLf & vbCrLf & _
"Please find attached a PDF document relating to our Order No  " & strOrderID & _
vbCrLf & vbCrLf & _
"Kind regards" & _
vbCrLf & vbCrLf & _
strOrderBy

pathT = SuppMail1

pathC = SuppMail2

'pathC = DLookup("[E-mail]", "tblreps", _
    "repid = " & Forms!frmPriceInputScreen!ExternalRep)

If IsNull(pathT) And IsNull(pathC) = True Then

    MsgBox "You Must Select A Supplier Contact To EMail The Order To", vbInformation, "Email"
    
    Exit Function

End If


pathH = strHead
pathS = strSub

Dim result As Integer
Dim displaymessage As Boolean
Dim objOutlook As Outlook.Application
Dim objOutlookMsg As Outlook.MailItem
Dim objOutlookRecip As Outlook.Recipient
Dim objOutlookAttach As Outlook.Attachment ' Create the Outlook session.


' Create the message.

Set objOutlookMsg = objOutlook.CreateItem(olMailItem)

With objOutlookMsg

' Add the To recipient(s) to the message.

If Len(Nz(pathT)) > 0 Then

    [b][red]Set objOutlookRecip = .Recipients.Add(pathT)[/red][/b]
    objOutlookRecip.Type = olTo
    
End If

' Add the CC recipient(s) to the message.

If Len(Nz(pathC)) > 0 Then

'If pathC <> "" Then

    Set objOutlookRecip = .Recipients.Add(pathC)
    objOutlookRecip.Type = olCC

End If


 ' Set the "From" field
   objOutlookMsg.SentOnBehalfOfName = ""


' Set the Subject, Body, and Importance of the message.

.Subject = (pathH)
.Body = (pathS)
.Importance = olImportanceHigh 'High importance

' Add attachments to the message.
'If Not IsMissing(AttachmentPath) Then

Set objOutlookAttach = .Attachments.Add(patha)

' Resolve each Recipient's name.

For Each objOutlookRecip In .Recipients

objOutlookRecip.Resolve

Next


    .Display


End With

Set objOutlook = Nothing


   On Error GoTo 0
   Exit Function

cmdPrint_Click_Error:

    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure cmdPrint_Click of Module Email"



End Function

could someone tell me where I am going wrong please [ponder][sadeyes]

Regards

Paul

 
Sort by date Sort by votes
I am either missing something, or I doubt this code as written ever worked. I am not even sure how the code gets as far as you show. Are you sure a chunk of code did not get deleted? You never as far as I can tell instantiate or get and Outlook application, you only declare the variable.

Code: 
'You only declare the objOutlook here, but nothing ever gets 'instantiated. Normally a getObject or createObject function is
' needed to return an application object

Dim objOutlook As Outlook.Application
Dim objOutlookMsg As Outlook.MailItem
Dim objOutlookRecip As Outlook.Recipient
Dim objOutlookAttach As Outlook.Attachment ' Create the Outlook session.
'appears as if chunk of code missing.

' Create the message.

Set objOutlookMsg = objOutlook.CreateItem(olMailItem)

'Not sure why the above line does not fail.
 
Upvote 0 Downvote
I think MajP is right here looks like 2 functions pasted together.Make sure you have all of the code. You have a few variables declared and never used.

Code: 
Variables:
displaymessage
KamMail
wnd
Res
uClickYes
strfrp
strContact
CustMail
result
Parameter:
view

You have error code but have commented the on error goto at the beginning of the function

Your DDate code can be accomplished with one line like

Code: 
DDate = Format(Now(), "dd-mm-yy")

and quite a few lines of code have been commented out you should think about getting rid of them if they are not going to be used. It will make it easier for you and anyone else to read the code.
I would also consider changing the name of the function it looks like it was taken from the on click event of a cmd button on a form originally as a sub. Drop the _Click. Just a few suggestions to clean it up a little HTH M

HTH << MaZeWorX >> "I have not failed I have only found ten thousand ways that don't work" <<Edison>>
 
Upvote 0 Downvote
Guys,

really sorry, I actually pasted the code I have been playing around with, I can assure you that this code has been used for the last 18 months.

The code does get called from a command button which runs a module that creates a PDF document from a report, it should then attach the document to the message and e-mail to the recipients.

This is the code I should have attached

Code: 
Public Function cmdPrint_Click(view As Integer)
'On Error GoTo cmdPrint_Click_Error

Dim strFilename As String
Dim strNewName As String
Dim strHead As String
Dim strSub As String
Dim DDate As String
Dim strfrp As String


strFilename = "Some Company"
strSub = " "
strOrderID = Forms![frmOrdersMain]![txtOrderNo]
strOrderBy = Forms![frmOrdersMain]![txtOrderedBy]

D = Format(Now, "dd")
m = Format(Now, "mm")
Y = Format(Now, "yy")

DDate = D & "-" & m & "-" & Y

strHead = strFilename & "  Order No_" & strOrderID & "  Dated " & DDate

strNewName = DLookup("[Path]", _
    "tblFilePaths", "[Type] = 'E-Mail'") & strFilename & "_Order No_" & strOrderID & "_" & DDate & ".pdf"

Forms![frmOrdersMain]![txtFileName] = strFilename & "_Order No_" & strOrderID & "_" & DDate & ".pdf"

Call SaveReportAsPDF("rptOrderB", strNewName)



 Dim patha, pathT, pathC, pathH, pathS, CustMail, KamMail As String

SuppMail1 = Forms!frmOrdersMain!txtEMail
SuppMail2 = Forms!frmOrdersMain!txtEMail2
patha = strNewName

strSub = "Dear Sir/Madam " & _
vbCrLf & vbCrLf & _
"Please find attached a PDF document relating to our Order No  " & strOrderID & _
vbCrLf & vbCrLf & _
"Kind regards" & _
vbCrLf & vbCrLf & _
strOrderBy

pathT = SuppMail1

pathC = SuppMail2

If IsNull(pathT) And IsNull(pathC) = True Then

    MsgBox "You Must Select A Supplier Contact To EMail The Order To", vbInformation, "Email"
    
    Exit Function

End If


pathH = strHead
pathS = strSub

Dim result As Integer
Dim displaymessage As Boolean
Dim objOutlook As Outlook.Application
Dim objOutlookMsg As Outlook.MailItem
Dim objOutlookRecip As Outlook.Recipient
Dim objOutlookAttach As Outlook.Attachment ' Create the Outlook session.

Set objOutlook = CreateObject("Outlook.Application") ' Create the message.

Set objOutlookMsg = objOutlook.CreateItem(olMailItem)

With objOutlookMsg

' Add the To recipient(s) to the message.

If Len(Nz(pathT)) > 0 Then

    Set objOutlookRecip = .Recipients.Add(pathT)
    objOutlookRecip.Type = olTo
    
End If

' Add the CC recipient(s) to the message.

If Len(Nz(pathC)) > 0 Then

'If pathC <> "" Then

    Set objOutlookRecip = .Recipients.Add(pathC)
    objOutlookRecip.Type = olCC

End If


 ' Set the "From" field
   objOutlookMsg.SentOnBehalfOfName = ""


' Set the Subject, Body, and Importance of the message.

.Subject = (pathH)
.Body = (pathS)
.Importance = olImportanceHigh 'High importance

Set objOutlookAttach = .Attachments.Add(patha)

' Resolve each Recipient's name.

For Each objOutlookRecip In .Recipients

objOutlookRecip.Resolve

Next

    .Display

End With

Set objOutlook = Nothing

   On Error GoTo 0
   Exit Function

cmdPrint_Click_Error:

    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure cmdPrint_Click of Module Email"



End Function

Regards

Paul

 
Upvote 0 Downvote
Code: 
Public Function cmdPrint_Click(view As Integer)

This function expects a parameter which is not used in the function(view)?? also how are you calling the function? It still has 5 unused variables. Also cmdPrint_Click would indicate a sub not a function

HTH << MaZeWorX >> "I have not failed I have only found ten thousand ways that don't work" <<Edison>>
 
Upvote 0 Downvote
MaZeWorX,

Thanks for replying again, i really have not explained this very well have I.

The person that originally created this in access 2003 has left the company and I have now been tasked with trying to make it run from access 2010. As I mentioned previously it is working in 2003 in spite of the mess that the code is in.

The db is used to send e-mails to various suppliers to make orders or call off from previously submitted orders. the user opens the DB and a form is presented to them where they enter all of the relevant data, once this is completed they click a command button which calls a macro ("SendE-mailManual").

the macro calls the function cmdPrint_Click(1)

This then goes away and and runs the code i have supplied previously. Following your replies I have removed some of the variables

Regards

Paul

 
Upvote 0 Downvote
I would consider replacing this

Code: 
Set objOutlookMsg = objOutlook.CreateItem(olMailItem)

with this

Code: 
Set objOutlookMsg = objOutlook.CreateItem(0)

because you cant use object constants with late binding you either define them or just pass them like above.

If you want to clean the 'function' up just let me know.

HTH M

HTH << MaZeWorX >> "I have not failed I have only found ten thousand ways that don't work" <<Edison>>
 
Upvote 0 Downvote
MazeWorx,

I really appreciate your help with this, I have tried to clean up some of the code and I have changed the name of the module. This is what I have at the moment and it works however I had to change

Code: 
Set objOutlookRecip = .Recipients.Add(pathT)
    objOutlookRecip.Type = olTo

to

Code: 
.To = pathT

otherwise i got the error


Code: 
Public Function SendMail_Man()

On Error GoTo SendMail_Man_Error

Dim strFilename, strHead, strSub, DDate As String
Dim strNewName As String
Dim patha, pathT, pathC, pathH, pathS As String

Dim objOutlook As Outlook.Application
Dim objOutlookMsg As Outlook.MailItem
Dim objOutlookRecip As Outlook.Recipient
Dim objOutlookAttach As Outlook.Attachment

strFilename = "Some Company"
strSub = " "
strOrderID = Forms![frmOrdersMain]![txtOrderNo]
strOrderBy = Forms![frmOrdersMain]![txtOrderedBy]

DDate = Format(Now(), "dd-mm-yy")

strHead = strFilename & "  Order No_" & strOrderID & "  Dated " & DDate

strNewName = DLookup("[Path]", _
    "tblFilePaths", "[Type] = 'E-Mail'") & strFilename & "_Order No_" & strOrderID & "_" & DDate & ".pdf"

Forms![frmOrdersMain]![txtFileName] = strFilename & "_Order No_" & strOrderID & "_" & DDate & ".pdf"

Call SaveReportAsPDF("rptOrderB", strNewName)

SuppMail1 = Forms!frmOrdersMain!txtEMail
SuppMail2 = Forms!frmOrdersMain!txtEMail2

patha = strNewName

strSub = "Dear Sir/Madam " & _
vbCrLf & vbCrLf & _
"Please find attached a PDF document relating to our Order No  " & strOrderID & _
vbCrLf & vbCrLf & _
"Kind regards" & _
vbCrLf & vbCrLf & _
strOrderBy

pathT = SuppMail1

pathC = SuppMail2

If IsNull(pathT) And IsNull(pathC) = True Then

    MsgBox "You Must Select A Supplier Contact To EMail The Order To", vbInformation, "Email"
    
    Exit Function

End If

pathH = strHead
pathS = strSub

On Error Resume Next
  Set objOutlook = GetObject(, "Outlook.Application")
  If Err <> 0 Then
  Set objOutlook = CreateObject("Outlook.Application")
  End If


Set objOutlookMsg = objOutlook.CreateItem(olMailItem) ' Create the message.

With objOutlookMsg

' Add the To recipient(s) to the message.

If Len(Nz(pathT)) > 0 Then

    .To = pathT
        
End If

' Add the CC recipient(s) to the message.

If Len(Nz(pathC)) > 0 Then

    .CC = pathC
    
End If

   objOutlookMsg.SentOnBehalfOfName = "" ' Set the "From" field


' Set the Subject, Body, and Importance of the message.

.Subject = (pathH)
.Body = (pathS)
.Importance = olImportanceHigh 'High importance

Set objOutlookAttach = .Attachments.Add(patha)

For Each objOutlookRecip In .Recipients ' Resolve each Recipient's name.

objOutlookRecip.Resolve

Next

    .Display

End With

Set objOutlook = Nothing

   On Error GoTo 0
   Exit Function

SendMail_Man_Error:

    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure SendMail_Man of Module Email"

End Function

any help you can give with cleaning up the process will be much appreciated

Regards

Paul

 
Upvote 0 Downvote
sorry just realized my last post was for another forum lol .. cross posting debacle Made about as much sense as me replying to him with a late binding issue with 'check your references' lol btw which library is referenced in the vbe? and sure to your request



HTH << MaZeWorX >> "I have not failed I have only found ten thousand ways that don't work" <<Edison>>
 
Upvote 0 Downvote
It might be worth you checking out my FAQ

faq705-7446

It was a nightmare switching from CDO to OOM so I've done all the hard work for you ;-)

"In complete darkness we are all the same, only our knowledge and wisdom separates us, don't let your eyes deceive you."

"If a shortcut was meant to be easy, it wouldn't be a shortcut, it would be the way!"

MIME::Lite TLS Email Encryption - Perl v0.02 beta
 
Upvote 0 Downvote
here is what i might do with your function. Actually create 2. This has only been tested in 2003. This way you can call the email function anytime without repeating the code :)

Code: 
Public Function FcnSendEmail(strTo As String, _
                             strSubject As String, _
                             strMessageBody As String, _
                             Optional strAttachmentPath As String, _
                             Optional strCC As String, _
                             Optional strBCC As String) As Boolean
    On Error Resume Next

    Set objOutlook = GetObject(, "Outlook.Application")
    If Err <> 0 Then
        Set objOutlook = CreateObject("Outlook.Application")
    End If
    Err.Clear
    On Error GoTo FcnSendEmail_Error
    Set objOutlookMsg = objOutlook.CreateItem(olMailItem)    ' Create the message.
    With objOutlookMsg
        .To = strTo
        If Len(strCC) > 0 Then    ' Add the CC recipient(s) to the message.
            .CC = strCC
        End If
        
        .SentOnBehalfOfName = ""    ' Set the From field
        .Subject = strSubject    ' Set the Subject
        .Body = strMessageBody    ' Set message body
        .Importance = olImportanceHigh    'Set importance

        If Len(strAttachmentPath) > 0 Then
            Set objOutlookAttach = .Attachments.Add(strAttachmentPath)
        End If
        If Len(strBCC) > 0 Then
            .BCC = strBCC
        End If

        For Each objOutlookRecip In .Recipients    ' Resolve each Recipient's name.
            objOutlookRecip.Resolve
        Next
        .Display
    End With
    FcnSendEmail = True
    Set objOutlook = Nothing

   On Error GoTo 0
   Exit Function

FcnSendEmail_Error:

    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure FcnSendEmail"
End Function

and your original function some what edited :) which could actually become the sub of a cmdbutton now

Code: 
Public Function SendMail_Man()

    Dim strFilename, DDate As String
    Dim strTo, strSubject, strMessageBody As String
    Dim strAttachmentPath, strCC, strBCC As String
    Dim blnSuccess As Boolean

    On Error GoTo SendMail_Man_Error

    strFilename = "Some Company"
    strOrderID = Forms![frmOrdersMain]![txtOrderNo]
    strOrderBy = Forms![frmOrdersMain]![txtOrderedBy]

    DDate = Format(Now(), "dd-mm-yy")

    strTo = Forms!frmOrdersMain!txtEMail
    strCC = Forms!frmOrdersMain!txtEMail2
    strSubject = strFilename & "  Order No_" & strOrderID & "  Dated " & DDate
    strAttachmentPath = DLookup("[Path]", _
                                "tblFilePaths", "[Type] = 'E-Mail'") & strFilename & "_Order No_" & strOrderID & "_" & DDate & ".pdf"

    strbody = "Dear Sir/Madam " & _
              vbCrLf & vbCrLf & _
              "Please find attached a PDF document relating to our Order No  " & strOrderID & _
              vbCrLf & vbCrLf & _
              "Kind regards" & _
              vbCrLf & vbCrLf & _
              strOrderBy

    Forms![frmOrdersMain]![txtFileName] = strFilename & "_Order No_" & strOrderID & "_" & DDate & ".pdf"

    If IsNull(strTo) Or strTo = "" Then
        MsgBox "You Must Select A Supplier Contact To EMail The Order To", vbInformation, "Email"
        Exit Function
    End If

    blnSuccess = SaveReportAsPDF("rptOrderB", strNewName)
    If blnSuccess = True Then
        Call FcnSendEmail(strTo, strSubject, strMessageBody, strAttachmentPath, strCC, strBCC)
    Else
        MsgBox "Failed to create Report"
        Exit Function
    End If

    On Error GoTo 0
    Exit Function

SendMail_Man_Error:

    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure SendMail_Man of Module Module3"

End Function

I haven't looked at 1DNF's code but sounds like you may want to take a peek
BTW here's the line i don't get
strFilename = "Some Company"
Click to expand...
you actually use this in the subject line??
it would indicate as stated before this function never ran or this is an ... exercise?

HTH << MaZeWorX >> "I have not failed I have only found ten thousand ways that don't work" <<Edison>>
 
Upvote 0 Downvote
1DMF,

I have checked out your FAQ but to be honest at the moment it is a little over my head. This next question I am about to ask may seem really stupid but here goes anyway.

"We have users on both 2003 and 2007/2010, would I have to create a way of using the correct wrapper based on what version of access they are using or would OOM work for all"



Regards

Paul

 
Upvote 0 Downvote
MaZeWorX,

Sorry I have not responded earlier I have been out of the office, thanks for looking at the code for me, I will look at your code in more detail and see if I can get it to work for me.

Regards

Paul

 
Upvote 0 Downvote
you may want to consider late binding for both versions

HTH << MaZeWorX >> "I have not failed I have only found ten thousand ways that don't work" <<Edison>>
 
Upvote 0 Downvote
We have users on 2003/2007/2010. I have amended the FAQ and the download to use late bindings for the OOM EmailWrapper class.

So it doesn't matter what version of Office your user have as long as it is at least 2003!

Well I say that, I haven't tested on lower versions so can't say for sure if it would work or not?





"In complete darkness we are all the same, only our knowledge and wisdom separates us, don't let your eyes deceive you."

"If a shortcut was meant to be easy, it wouldn't be a shortcut, it would be the way!"

MIME::Lite TLS Email Encryption - Perl v0.02 beta
 
Upvote 0 Downvote
1DMF,

Thanks for the reply, If I get my head round the code I will test it in 2003, 2007 & 2010 and let you know how I get on

Regards

Paul

 
Upvote 0 Downvote
MaZeWorX,

Thanks for the reply I will let you know how I get on

Regards

Paul

 
Upvote 0 Downvote
no probs, but there really isn't much to get your head round, you don't need to understand the class to use it ;-)

You simply import the class and then to send a basic email do something like this in your main code...
Code: 
' Declare and initialise EmailWrapper Object
Dim anEmail As New EmailWrapper

' Add Subject
anEmail.Subject = "This is my email subject"

' Add HTML Body
anEmail.Body = "<html><head></head><body><p>This is just some paragraph email body text</p></body></html>"

' Add Recipient
anEmail.addRecip "you@yourdomain.com"

' Send Email
anEmail.Send

' Clear object
Set anEmail = Nothing

It really is that simple, obviously there are additional options for attachments, BCC etc , but to send a simple text HTML email, the above is all you need :)

Have fun, and feel free to ask if you get stuck!

"In complete darkness we are all the same, only our knowledge and wisdom separates us, don't let your eyes deceive you."

"If a shortcut was meant to be easy, it wouldn't be a shortcut, it would be the way!"

MIME::Lite TLS Email Encryption - Perl v0.02 beta
 
Upvote 0 Downvote
1DMF,

tried using your simple example however it did not add a recipient then i noticed that there is a line in the email wrapper to set the recipients to nothing before the e-mail gets sent

Code: 
' Send email
Public Sub Send()
    
    On Error GoTo Email_Error
    
    Dim oApp As Object
    Dim l_Msg As Object
    Dim colAttach As Object
    Dim l_Attach As Object
    Dim strEntryID As String
    Dim x As Integer
    Dim oReceipt As Object
    Dim oPA As Object
       
    Const PR_ATTACH_MIME_TAG = "[URL unfurl="true"]http://schemas.microsoft.com/mapi/proptag/0x370E001E"[/URL]
    Const PR_ATTACH_CONTENT_ID = "[URL unfurl="true"]http://schemas.microsoft.com/mapi/proptag/0x3712001E"[/URL]
    Const PR_ATTACHMENT_HIDDEN = "[URL unfurl="true"]http://schemas.microsoft.com/mapi/proptag/0x7FFE000B"[/URL]
    
    ' create new Outlook MailItem
    Set oApp = CreateObject("Outlook.Application")
    Set l_Msg = oApp.CreateItem(olMailItem)
       
    With l_Msg
    
        'add recipients
        For Each eml In Recip
            Set oReceipt = .Recipients.Add(eml)
            oReceipt.Type = olTo
        Next

        'add BCC recipients
        For Each eml In BCC
            Set oReceipt = .Recipients.Add(eml)
            oReceipt.Type = olBCC
        Next

        'set email subject
        .Subject = Subject
        
        'set body  HTML
        .HTMLBody = Body
        
    End With
    
    'clear recipients
    [b][COLOR=red]Set oReceipt = Nothing[/color][/b]
        
    'check items for mime encoding
    If Items.Count > 0 Then
        
        ' attach items
        Set colAttach = l_Msg.Attachments
        For x = 1 To Items.Count
            Set l_Attach = colAttach.Add(Items.Item(x))
            Set oPA = l_Attach.PropertyAccessor
            oPA.SetProperty PR_ATTACH_MIME_TAG, ItemTypes.Item(x)
            oPA.SetProperty PR_ATTACH_CONTENT_ID, "item" & x
            oPA.SetProperty PR_ATTACHMENT_HIDDEN, True
        Next
                   
    End If
    
    l_Msg.Save
        
    ' add normal file attachments
    For Each att In Files
        l_Msg.Attachments.Add (att)
    Next
        
    ' save email
    l_Msg.Save
    
    ' check if display or send
    If DispEmail Then
        l_Msg.Display
    Else
        l_Msg.Display
    End If

Exit_Email:
    ' clean up email object
    Set l_Msg = Nothing
    Set l_Attach = Nothing
    Set oApp = Nothing
    Set oPA = Nothing
    
    Exit Sub
    
Email_Error:
    MsgBox err.Description, vbOKOnly + vbCritical, "Error: " & err.Number
    Resume Exit_Email
    
End Sub

is that right?, am i missing something?

Regards

Paul
 
Upvote 0 Downvote
hmm, I just did a test and it sent me an email using
Code: 
Function atest()

' Declare and initialise EmailWrapper Object
Dim anEmail As New EmailWrapper

' Add Subject
anEmail.Subject = "This is my email subject"

' Add HTML Body
anEmail.Body = "<html><head></head><body><p>This is just some paragraph email body text</p></body></html>"

' Add Recipient
anEmail.addRecip "me@mydomain.com"

' Send Email
anEmail.Send

' Clear object
Set anEmail = Nothing

End Function

I put that in the global code module and then just ran atest via the immedate window.

Do you have outlook open at the time?

"In complete darkness we are all the same, only our knowledge and wisdom separates us, don't let your eyes deceive you."

"If a shortcut was meant to be easy, it wouldn't be a shortcut, it would be the way!"

MIME::Lite TLS Email Encryption - Perl v0.02 beta
 
Upvote 0 Downvote
Status
Not open for further replies.

Similar threads

Moss100
  • Locked
  • Question
Code not working 1
Replies
5
Views
96
Darrylles
Darrylles
Moss100
  • Locked
  • Question
Stop user changing size of Access Application (not form)
Replies
1
Views
153
Andrzejek
Andrzejek
renigar
  • Locked
  • Question
Code to write file path to field always writes to 1st record 1
Replies
5
Views
134
dhookom
dhookom
JaineyBlue
  • Locked
  • Question
Cascading combo boxes in subform
Replies
11
Views
172
JaineyBlue
JaineyBlue
JimStrand
  • Locked
  • Question
Trying to Use Form Control as Variable in Report Control Source 2
Replies
5
Views
136
Andrzejek
Andrzejek

Part and Inventory Search

Sponsor

Back
Top