Clipboard message... removeable? 2

[Turb]

Hi all!
I have a command button, in the header of a form, in an Access 2003 database that performs copy/paste operations for me; It does this very well.
My only issue is that when I close the form after doing a copy/paste operation, I always get a "Microsoft Office Access" message: "You copied a large amount of data onto the clipboard... Do you want to save this data on the Clipboard?"
I've tried using "DoCmd.SetWarnings False" as an 'On Open' event to stop this, but it doesn't stop the message.
I guess it's not a "warning" message per se.

Can someone help?

Thanks!


- Turb

 

[Golom]

Try issuing

Clipboard.Clear

after your Paste.

 

[Turb]

Hi Golom!
Thank you for your response.
I tried your suggestion and placed Clipboard.Clear in my code here:

Private Sub COPY_REC_Click()
On Error GoTo Err_COPY_REC_Click

    DoCmd.RunCommand acCmdSelectRecord
    DoCmd.RunCommand acCmdCopy
    DoCmd.RunCommand acCmdPasteAppend
    Clipboard.Clear
    Me.SERIALNO = " "
    DoCmd.GoToRecord , , acLast
    DoCmd.GoToControl "SERIALNO"
    
Exit_COPY_REC_Click:
    Exit Sub

Err_COPY_REC_Click:
    MsgBox err.Description
    Resume Exit_COPY_REC_Click
    
End Sub

and here:

Private Sub COPY_REC_Click()
On Error GoTo Err_COPY_REC_Click

    DoCmd.RunCommand acCmdSelectRecord
    DoCmd.RunCommand acCmdCopy
    DoCmd.RunCommand acCmdPasteAppend
    Me.SERIALNO = " "
    DoCmd.GoToRecord , , acLast
    DoCmd.GoToControl "SERIALNO"
    Clipboard.Clear
    
Exit_COPY_REC_Click:
    Exit Sub

Err_COPY_REC_Click:
    MsgBox err.Description
    Resume Exit_COPY_REC_Click
    
End Sub

But in both cases Access crashes to desktop without warning when the command button is clicked.
Am I missing something?

-Turb


- Turb

 

[PWise]

Golom
Clipboard Is A VB object not a VBA object

 

[Turb]

pwise,
Thank you for the heads-up.

Do you know if there is a way to programmatically clear the clipboard from Access? Or disable the message?




- Turb

 

[PWise]

try this

 Dim objie
 Set objie = CreateObject("InternetExplorer.Application")
 objie.Navigate ("about:blank")
 objie.Document.parentwindow.clipboardData.clearData
 objie.Quit

 

[Turb]

pwise,
Thank you again, but um... where do I place this please?


- Turb

 

[PWise]

place this code in module

Public Function ClearClipboard()

Dim objie
Set objie = CreateObject("InternetExplorer.Application")
objie.Navigate ("about:blank")
objie.Document.parentwindow.clipboardData.clearData
objie.Quit

End Function

Private Sub COPY_REC_Click()
On Error GoTo Err_COPY_REC_Click

    DoCmd.RunCommand acCmdSelectRecord
    DoCmd.RunCommand acCmdCopy
    DoCmd.RunCommand acCmdPasteAppend
    ClearClipboard
    Me.SERIALNO = " "
    DoCmd.GoToRecord , , acLast
    DoCmd.GoToControl "SERIALNO"
    
    
Exit_COPY_REC_Click:
    Exit Sub

Err_COPY_REC_Click:
    MsgBox err.Description
    Resume Exit_COPY_REC_Click
    
End Sub

 

[Golom]

pwise

You're right. Sorry about that.

In a module

Public Declare Function EmptyClipboard Lib "user32" Alias "EmptyClipboard" () As Long

and in your code

Call EmptyClipBoard

 

[PWise]

Golom: Have A pink one for pointing me to a api this should faster than my approach

 

[Turb]

Golom, pwise,
Thank you both.

Golom, I created a new module called "MTClip" and placed your module code in it as written above.
Placed "EmptyClipBoard" just under "DoCmd.RunCommand acCmdPasteAppend" in my code...
No dice. Still getting the clipboard message.

So I then tried placing "Call EmptyClipBoard" into my code; same place...
Still getting the message.

I rechecked the code in "MTClip" and it seems Access has truncated the code to this when I saved the module?

Public Declare Function EmptyClipboard Lib "user32" () As Long

- Turb

 

[Golom]

Sorry ... not thinking noticibly well today ...

In a module

Declare Function CloseClipboard Lib "User32" () As Long
Declare Function OpenClipboard Lib "User32" (ByVal hwnd As Long) _
   As Long
Declare Function EmptyClipboard Lib "User32" () As Long

Public Sub ClearClipboard()
    Call OpenClipboard(0&)
    Call EmptyClipboard
    Call CloseClipboard
End Sub

Then in your code

ClearClipboard

 

[Turb]

YES! Thank you Golom! Here's another "pink one" for you my friend.


- Turb