Changing file extension and move to new folder

[mydisney]

I have a vb script where I need to change file extension for all files that starts with t* and that have extension = .txt. Here is the code I have but it does not work right (It works fine when I only have .txt but then it picks up more files than I want)

Dim filesys, file, folderName, objFile, folderObj, fileColl, objRegExp, newFile
Set filesys = CreateObject("Scripting.FileSystemObject")

folderName = "c:\myfolder\myftpfolder\"
Set folderObj = filesys.GetFolder(folderName)
Set fileColl = folderObj.Files

Set objRegExp = New RegExp
objRegExp.Pattern = "t*.txt" 'looking for t*.txt (extension) match
objRegExp.IgnoreCase = True

For Each objFile In fileColl
If objRegExp.Test(objFile.Name) Then
newFile = objRegExp.Replace (objFile.Name, ".bak")
filesys.MoveFile objFile, folderName & newFile
End If
Next

 

[dm4ever]

Try changing your pattern

^t.*\.txt$

--------------------------------------------------------------------------------
dm4ever
My philosophy: K.I.S.S - Keep It Simple Stupid

 

[mydisney]

Hi dm4ever:

It did not not work, it did not change extension. Any other suggestion?

Here is the code I used:

objRegExp.Pattern = "^t.*\.txt$ "

 

[PWise]

boy do I long for the days of

c:\> ren c:\wp\doc\.....*.dat *.bak

!!!!!!!

 

[dm4ever]

I would take it in pieces. First see if the pattern is only showing files that match the criteria you're looking for. Once you confirm that, then we can start working on the rest.

--------------------------------------------------------------------------------
dm4ever
My philosophy: K.I.S.S - Keep It Simple Stupid

 

[dm4ever]

Echo out or MsgBox the output of this line
newFile = objRegExp.Replace (objFile.Name, ".bak")

I don't think it is changing the extension like you think it might.

--------------------------------------------------------------------------------
dm4ever
My philosophy: K.I.S.S - Keep It Simple Stupid

 

[mydisney]

It takes all the files in the folder with .txt extension and renames to .bak. This is good so far except I only want to have files starting with *T renamed.

 

[dm4ever]

This example shows that the pattern only shows file that start with a "T" and end with .txt

Option Explicit

Dim arrTemp : arrTemp = Array("test123.txt", "abc1.txt", "sldkrf.ber", "taaer.txt", "tadbs.exe")
Dim RegEx : Set RegEx = New RegExp
RegEx.Pattern = "^t.*\.txt$"
RegEx.IgnoreCase = True
Dim strTemp
For Each strTemp In arrTemp
	If RegEx.Test(strTemp) Then
		WScript.Echo strTemp
	End If
Next

--------------------------------------------------------------------------------
dm4ever
My philosophy: K.I.S.S - Keep It Simple Stupid

 

[tsuji]

[1]>objRegExp.Pattern = "t*.txt" 'looking for t*.txt (extension) match
[tt]objRegExp.Pattern = "^(t)(.*\.)txt$" 'looking for t*.txt (extension) match[/tt]

[2]>newFile = objRegExp.Replace(objFile.Name, ".bak")
[tt]newFile = objRegExp.Replace(objFile.Name, "$1$2bak")[/tt]

 

[mydisney]

Hi Guys:

Finally got the code to work. Here it is:

Dim filesys, file, folderName, objFile, folderObj, fileColl, objRegExp, newFile
Set filesys = CreateObject("Scripting.FileSystemObject")

folderName = "c:\travelers\fromtravelers\"
Set folderObj = filesys.GetFolder(folderName)
Set fileColl = folderObj.Files

Set objRegExp = New RegExp
objRegExp.Pattern = "^(t)(.*\.)txt$"
objRegExp.IgnoreCase = True

For Each objFile In fileColl
If objRegExp.Test(objFile.Name) Then
newFile = objRegExp.Replace(objFile.Name, "$1$2bak")
filesys.MoveFile objFile, folderName & newFile
End If
Next

Thank you all for being very supportive and have a great weeek end!!!