Changing all values of a field

[bobsmallwood]

Is there code that could be attached to a pushbutton that would change all True values of a field in a table to blank?

 

[Langley]

You could do it two ways.

The first would be to attach some query code to a button and use the changeto keyword.

var 
qVar   query
endvar
;
qVar = Query
; 
:myAlias:myTable.db  | myField              |
                     | True, changeto Blank |
;
endQuery
;
qVar.executeQBE()

The second would involve using a tCursor and a scan loop. Both should work just fine.

var
 tc   tCursor
endVar
;
tc.open(":myAlias:myTable.db")
tc.Edit()
;
scan tc:
 if tc."myField" = "True"
    then   tc."myField"  = ""
 endif
endscan
;
tc.endEdit()
tc.close()

Mac

"There are only 10 kinds of people in this world... those who understand binary and those who don't"

langley_mckelvy@cd4.co.harris.tx.us

 

[bobsmallwood]

Thank you very much. Worked like a champ!

 

[footpad]

Just for the sake of completeness...

If you're using Paradox 5.0 or later, you can also use a SQL query, as shown in the following code sample:

method pushButton(var eventInfo Event)
var
   sq     SQL
   db     Database
endVar

   db.open()
   sq = SQL

      update
         ":work:blanktst.db" t
      set
         t."Value" = null
      where
         t."Value" = True

   endSQL

   if not sq.executeSQL( db ) then
      errorShow( "Can't Blank Field",
                 "Click [>>] for details..." )
   endIf

endMethod

Please note that while QBE queries assume you're working with the local database (e.g. the filesystem of the PC you're running this from), SQL queries need a database variable.

Also, you may find it necessary to quote all table and field names in SQL queries, especially if you use spaces or SQL reserved words in your field names.

To open a Database variable against the local file system, call open with no parameters.

Hope this helps...

-- Lance