Change FileDateTime of a Document in VBA 1

[Karja]

Goodmorning,

Is there a way to change the 3 FileDateTimes (creation, acces, lastwritten) of a file with VBA? Any help appreciated.

Karja,

 

[PHV]

This 3 properties of the FileSystemObject.File object are read only, dot.

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ181-2886

 

[Karja]

Too bad. I must find another way. Thanks for your answer.

 

[PHV]

Have a look here:

http://msdn.microsoft.com/library/e...l/reference/objects/folderitem/modifydate.asp

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ181-2886

 

[fumei]

Too bad. I must find another way.

Would you share your need/requirement for doing this?

Gerry
My paintings and sculpture

 

[Karja]

Oh sure....
It is about sorting thing on date/time. But for some personal reasons I want to manual interfere with the sorting.

 

[PHV]

But for some personal reasons
Unfortunatly, creation and last access times are file system's stuff, not user's...

Hope This Helps, PH.
Want to get great answers to your Tek-Tips questions? Have a look at FAQ219-2884 or FAQ181-2886

 

[Karja]

Still too bad, but not a disaster

 

[Karja]

Of course there is a way with the system time that you can manipulate the filedatetime but I want to do it in code

 

[combo]

You can with API calls (API-guide, by KPD-Team):

Declare Function CreateFile Lib "kernel32" Alias "CreateFileA" (ByVal lpFileName As String, ByVal dwDesiredAccess As Long, ByVal dwShareMode As Long, ByVal lpSecurityAttributes As Long, ByVal dwCreationDisposition As Long, ByVal dwFlagsAndAttributes As Long, ByVal hTemplateFile As Long) As Long
Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Declare Function SystemTimeToFileTime Lib "kernel32" (lpSystemTime As SYSTEMTIME, lpFileTime As FILETIME) As Long
Declare Function LocalFileTimeToFileTime Lib "kernel32" (lpLocalFileTime As FILETIME, lpFileTime As FILETIME) As Long
Declare Function SetFileTime Lib "kernel32" (ByVal hFile As Long, lpCreationTime As FILETIME, lpLastAccessTime As FILETIME, lpLastWriteTime As FILETIME) As Long

Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type
Private Type SYSTEMTIME
    wYear As Integer
    wMonth As Integer
    wDayOfWeek As Integer
    wDay As Integer
    wHour As Integer
    wMinute As Integer
    wSecond As Integer
    wMilliseconds As Integer
End Type

Const GENERIC_WRITE = &H40000000
Const FILE_SHARE_WRITE = &H2
Const OPEN_EXISTING = 3

Sub abc()
Dim udtFileTime As FILETIME
Dim udtLocalFileTime As FILETIME
Dim udtSystemTime As SYSTEMTIME
    
udtSystemTime.wYear = Year(Now - 1)
udtSystemTime.wMonth = Month(Now - 1)
udtSystemTime.wDay = Day(Now - 1)
udtSystemTime.wDayOfWeek = Weekday(Now - 1)
udtSystemTime.wHour = Hour(Now)
udtSystemTime.wMinute = Minute(Now)
udtSystemTime.wSecond = Second(Now)
udtSystemTime.wMilliseconds = 0

SystemTimeToFileTime udtSystemTime, udtFileTime
LocalFileTimeToFileTime udtFileTime, udtLocalFileTime
lngHandle = CreateFile("c:\test.any", GENERIC_WRITE, FILE_SHARE_WRITE, ByVal 0&, OPEN_EXISTING, 0, 0)
SetFileTime lngHandle, udtLocalFileTime, udtLocalFileTime, udtLocalFileTime
CloseHandle lngHandle
End Sub

combo

 

[Karja]

Thank you very much, this is something I can work with. I will give you a star.

 

[combo]

Thanks, lngHandle can be used to test access (-1 - failed).
combo