CCMA 6

[tiggerbouncy]

We have created a 'time variable' which means that if there were no frontline agents available, then the call/s would queue for the back office teams for a number of seconds set in the variable. The question is, is there a way we can ensure that if the calls are queueing for the back office according to the time set in the variable that if a frontline agent became available they would get the call rather than carry on queueing for the back office.

 

[hached]

If you post a copy of your script I can take a look at it. Unless you told your script to remove the call from the original skillset it will be queued in both skills until an agent becomes available in either skillset...

 

[tiggerbouncy]

IF (DATE = gv_XmasAgreedfinishwithNL AND TIME OF DAY <> gv_xmas_eve_hours) OR
(DATE = gv_xmas_closed AND TIME OF DAY <> gv_xmas_hours) THEN
ROUTE CALL gv_nightline
END IF

IF (DATE = gv_bank_hols AND TIME OF DAY <> gv_bank_hol_hours) THEN
ROUTE CALL gv_nightline
END IF

IF (DAY OF WEEK = gv_week_day AND TIME OF DAY <> gv_week_day_hours) OR
(DAY OF WEEK = SATURDAY AND TIME OF DAY <> gv_saturday_hours) OR
(DAY OF WEEK = SUNDAY) THEN
ROUTE CALL gv_nightline
END IF

IF NOT OUT OF SERVICE Frontline_General THEN
QUEUE TO SKILLSET Frontline_General
WAIT 2
ELSE
ROUTE CALL gv_nightline
END IF

WAIT 1

IF (AGE OF CALL >= gv_shortwait_overflow AND cv_call_queued = TRUE) THEN
IF NOT OUT OF SERVICE Frontline_Overflow THEN
QUEUE TO SKILLSET Frontline_Overflow
WAIT 2
ASSIGN FALSE TO cv_call_queued
END IF
END IF

OPEN VOICE SESSION
PLAY PROMPT VOICE SEGMENT vs_main_greeting
VOICE SEGMENT vs_call_recording
END VOICE SESSION

IF (AGE OF CALL >= gv_shortwait_overflow AND cv_call_queued = TRUE) THEN
IF NOT OUT OF SERVICE Frontline_Overflow THEN
QUEUE TO SKILLSET Frontline_Overflow
WAIT 2
ASSIGN FALSE TO cv_call_queued
END IF
END IF


GIVE MUSIC 62

WAIT gv_first_hold_timer

IF (AGE OF CALL >= gv_shortwait_overflow AND cv_call_queued = TRUE) THEN
IF NOT OUT OF SERVICE Frontline_Overflow THEN
QUEUE TO SKILLSET Frontline_Overflow
WAIT 2
ASSIGN FALSE TO cv_call_queued
END IF
END IF

OPEN VOICE SESSION
PLAY PROMPT VOICE SEGMENT vs_hold_1
VOICE SEGMENT Emergency_Website
END VOICE SESSION

SECTION Loop

GIVE MUSIC 62

WAIT gv_repeat_timer

IF NOT LOGGED OUT AGENT gv_emergency_id THEN
OPEN VOICE SESSION
PLAY PROMPT VOICE SEGMENT vs_Emergency_Message
DISCONNECT
END VOICE SESSION
END IF

OPEN VOICE SESSION
PLAY PROMPT VOICE SEGMENT vs_hold_2
VOICE SEGMENT Emergency_Website
END VOICE SESSION

 

[hached]

The way your script is built your calls queue first to FrontLine General, if someone is available, great call is answered.

Once you hit the statment below and the variables are TRUE then the call queue's to your Overflow:

IF (AGE OF CALL >= gv_shortwait_overflow AND cv_call_queued = TRUE) THEN
IF NOT OUT OF SERVICE Frontline_Overflow THEN
QUEUE TO SKILLSET Frontline_Overflow
WAIT 2
ASSIGN FALSE TO cv_call_queued
END IF
END IF

At this point your calls are queued in Both Frontline & Overflow until an agent become available in either queue.

In your first post you alluded to calls only being queued to the Overflow skillset for a certain amount of time, that is not the case, the calls is queued to Overflow until it is either answered by Frontline or Overflow.

Let me know if that helps.