CC6 scripting adding an option after 30 sec wait in Que

[naslan]

I'm running into a situation where management want to add an option for callers to leave a voice mail message or to continue to hold after waiting 30 sec in the Queue . I have added the Voice Segment successfully to the script but not sure how to make phone selections available when the message is playing.

The original script is below
Primary script

ASSIGN XXX TO skillset_cv
ASSIGN 1 TO priority_cv

EXECUTE SCRIPT Queue_to_Skillset
____________________________________

Secondary Script

IF (emergency_gv = TRUE) THEN
EXECUTE OOS
END IF

IF NOT LOGGED OUT AGENT emergency_agentID_gv THEN
EXECUTE OOS
END IF


/*****************************************************************/

IF NOT OUT OF SERVICE skillset_vm_cv THEN
QUEUE TO SKILLSET skillset_vm_cv BY LONGEST IDLE AGENT WITH PRIORITY priority_cv
WAIT 2
ELSE
EXECUTE OOS
END IF

GIVE CONTROLLED BROADCAST ANNOUNCEMENT access_gv
PLAY PROMPT VOICE SEGMENT first_onhold_msg_vs

GIVE MUSIC music_gv
WAIT wait1_gv



SECTION LOOP

IF NOT QUEUED THEN
IF NOT OUT OF SERVICE skillset_vm_cv THEN
QUEUE TO SKILLSET skillset_vm_cv BY LONGEST IDLE AGENT WITH PRIORITY priority_cv
WAIT 2
ELSE
EXECUTE OOS
END IF
END IF


IF (emergency_gv = TRUE) THEN
EXECUTE OOS
END IF

IF NOT LOGGED OUT AGENT emergency_agentID_gv THEN
EXECUTE OOS
END IF


GIVE CONTROLLED BROADCAST ANNOUNCEMENT access_gv
PLAY PROMPT VOICE SEGMENT first_onhold_withVM_vs

WAIT wait1_gv

EXECUTE LOOP


/*****************************************************************/
SECTION OOS

ROUTE CALL XXX_Xfer_gv

 

[WebbersasWell]

What sort of voice mail are you using, as if you are using call pilot you need to set up an SDN, then make a treatment or you could route the call to a number that is a voice mail box.

However you do it, you need to ask the users to make a choice in the script, i.e. press 1 for VM or hold to continue waiting.

Here is a sample bit of script we use,

IF (AGE OF CALL > 120 ) THEN
OPEN VOICE SESSION 767
PLAY PROMPT VOICE SEGMENT Collections_VM_Question
COLLECT 1 DIGITS INTO Collections_Mortgage_Digits
INTER DIGIT TIMER 5
END VOICE SESSION

IF Collections_Mortgage_Digits = 1 THEN
GIVE IVR 768 WITH TREATMENT COLLECTIONS_VM
END IF
END IF

Variables
Collections_Mortgage_Digits is a call variable of type DN, with a default of 0

Collections_VM_Question - Voice Segment, playing message "press 1 to leave VM otherwise continue to hold"

Collections_VM is a treatment that points to a Callpilot SDN, that plays a message and then routes to VM

Hope this helps

 

[naslan]

WebbersasWell Thank you for the respond.
I do have Call Pilot, I did create the Voice segment with the msg to press 1 for VM or continue to hold.
i did not do the other Variables you mentioned but i will.

one more thing the numbers in your example:
OPEN VOICE SESSION 767
GIVE IVR 768
What are they supposed to point to or refer to?

 

[Utreg]

The 767 refers to the configured 'Access DN' (link between Call Pilot and the Contact Center).

In your case You will find your value in the webcleint via: Script Variables, type ACD, access_gv

The value is also configurend in the Call Pilot SDN, look for 'Symposium Voice Services'.

If you have an 'IVR 768' configured depands on you call pilot ports configuration.

 

[naslan]

Thank you guys, that did it